[gentoo-commits] repo/gentoo:master commit in: sci-libs/dcmtk/

["Joonas Niilola" <juippis@gentoo.org>]

commit:     1c0a96eebf56ee5850e74d3eddde572eb7df6557
Author:     Horea Christian <chr <AT> chymera <DOT> eu>
AuthorDate: Thu May 16 21:20:20 2019 +0000
Commit:     Joonas Niilola <juippis <AT> gentoo <DOT> org>
CommitDate: Thu Aug  8 03:14:26 2019 +0000
URL:        https://gitweb.gentoo.org/repo/gentoo.git/commit/?id=1c0a96ee

sci-libs/dcmtk: version bump 3.6.4

Package-Manager: Portage-2.3.66, Repoman-2.3.12
Signed-off-by: Horea Christian <chr <AT> chymera.eu>
Closes: https://github.com/gentoo/gentoo/pull/12024
Signed-off-by: Joonas Niilola <juippis <AT> gentoo.org>

 sci-libs/dcmtk/Manifest           |  1 +
 sci-libs/dcmtk/dcmtk-3.6.4.ebuild | 86 +++++++++++++++++++++++++++++++++++++++
 2 files changed, 87 insertions(+)

diff --git a/sci-libs/dcmtk/Manifest b/sci-libs/dcmtk/Manifest
index fd3e552a864..85301030809 100644
--- a/sci-libs/dcmtk/Manifest
+++ b/sci-libs/dcmtk/Manifest
@@ -1 +1,2 @@
 DIST dcmtk-3.6.3.tar.gz 6269785 BLAKE2B 8f0797840fa5ab4ffb60e46f65b16739d3ed0cb7591b20cbfba81a59de97344a663f73bed8fc7f349a99accc46fd2fde3cff021861bde6f07957a433a4db67a3 SHA512 5b907422d2d80e417ae8239e159d1300da4ed8db7e92cee619cc1d37116165e8824f8a9103605e07a95b1bffe94bbd2d5e05125f068281d241e8e78755d0b5e8
+DIST dcmtk-3.6.4.tar.gz 6402734 BLAKE2B 2d362789e7819089b7da46a9601fa5d53b8e8aab1ac7d30bf1180b3da0645d015a177c97188dc9255c6962a9d7246cf287b20824a78fbe9612b9bc277e68d294 SHA512 735f85d04410437a5163b154f43c8a299aff7a8f810605ce6c5027ae4569ff1323a69f70a2603805cec9d826a31166fd904bb53c3edc1137bfc41ba2902c2261

diff --git a/sci-libs/dcmtk/dcmtk-3.6.4.ebuild b/sci-libs/dcmtk/dcmtk-3.6.4.ebuild
new file mode 100644
index 00000000000..4678a05c1f3
--- /dev/null
+++ b/sci-libs/dcmtk/dcmtk-3.6.4.ebuild
@@ -0,0 +1,86 @@
+# Copyright 1999-2019 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=7
+
+inherit cmake-utils
+
+DESCRIPTION="The DICOM Toolkit"
+HOMEPAGE="https://dicom.offis.de/dcmtk.php.en"
+SRC_URI="http://dicom.offis.de/download/dcmtk/release/${P}.tar.gz"
+
+LICENSE="OFFIS"
+KEYWORDS="~amd64 ~arm ~x86"
+SLOT="0"
+IUSE="doc png ssl tcpd tiff +threads xml zlib"
+
+RDEPEND="
+	dev-libs/icu:=
+	virtual/jpeg:0
+	png? ( media-libs/libpng:* )
+	ssl? ( dev-libs/openssl:0= )
+	tcpd? ( sys-apps/tcp-wrappers )
+	tiff? ( media-libs/tiff:0 )
+	xml? ( dev-libs/libxml2:2 )
+	zlib? ( sys-libs/zlib )"
+DEPEND="${RDEPEND}
+	media-gfx/graphviz
+	doc? ( app-doc/doxygen )"
+
+src_prepare() {
+	cmake-utils_src_prepare
+
+	sed -e "s:share/doc/dcmtk:&-${PV}:" \
+		-e "s:DIR \"/:DIR \"/usr/:" \
+		-e "s:usr/etc:etc:" \
+		-e "s:/lib\":/$(get_libdir)\":" \
+		-e "s:COPYRIGHT::" \
+		-i CMakeLists.txt || die
+	sed -e 's:${CMAKE_INSTALL_PREFIX}/::' \
+		-i dcmwlm/data/CMakeLists.txt doxygen/CMakeLists.txt || die
+	# Temporary workaround: docs are not built with CMake
+	sed -i -e '/include/d' doxygen/Makefile.in || die
+
+	# fix -D deprecation warnings
+	sed -i -e "s|_BSD_SOURCE|_DEFAULT_SOURCE|g" \
+		"${S}"/config/configure.in \
+		"${S}"/CMakeLists.txt || die
+}
+
+src_configure() {
+	local mycmakeargs=(
+		-DBUILD_SHARED_LIBS=ON
+		-DDCMTK_WITH_ICU=ON
+		-DDCMTK_WITH_TIFF=$(usex tiff)
+		-DDCMTK_WITH_PNG=$(usex png)
+		-DDCMTK_WITH_XML=$(usex xml)
+		-DDCMTK_WITH_ZLIB=$(usex zlib)
+		-DDCMTK_WITH_OPENSSL=$(usex ssl)
+		-DDCMTK_WITH_DOXYGEN=$(usex doc)
+		-DDCMTK_WITH_THREADS=$(usex threads)
+	)
+
+	cmake-utils_src_configure
+
+	if use doc; then
+		cd "${S}"/doxygen || die
+		econf
+	fi
+}
+
+src_compile() {
+	cmake-utils_src_compile
+
+	if use doc; then
+		emake -C "${S}"/doxygen
+	fi
+}
+
+src_install() {
+	doman doxygen/manpages/man1/*
+
+	if use doc; then
+		local HTML_DOCS=( "${S}"/doxygen/htmldocs/. )
+	fi
+	cmake-utils_src_install
+}