[gentoo-commits] repo/gentoo:master commit in: xfce-base/thunar/

["Michał Górny" <mgorny@gentoo.org>]

commit:     e1d15e270de559f3c9addd42bcb6e7804a50d373
Author:     Michał Górny <mgorny <AT> gentoo <DOT> org>
AuthorDate: Sat Jul 20 04:59:30 2019 +0000
Commit:     Michał Górny <mgorny <AT> gentoo <DOT> org>
CommitDate: Sat Jul 20 05:26:04 2019 +0000
URL:        https://gitweb.gentoo.org/repo/gentoo.git/commit/?id=e1d15e27

xfce-base/thunar: Bump to 1.8.8

Signed-off-by: Michał Górny <mgorny <AT> gentoo.org>

 xfce-base/thunar/Manifest            |  1 +
 xfce-base/thunar/thunar-1.8.8.ebuild | 76 ++++++++++++++++++++++++++++++++++++
 2 files changed, 77 insertions(+)

diff --git a/xfce-base/thunar/Manifest b/xfce-base/thunar/Manifest
index 7b9ca55c1f2..09212a20862 100644
--- a/xfce-base/thunar/Manifest
+++ b/xfce-base/thunar/Manifest
@@ -1,3 +1,4 @@
 DIST Thunar-1.6.16.tar.bz2 1977562 BLAKE2B efad6b45a64c5c80bff3d829207a1a0b45b4b48ab168c38bbcd263445a16dc230b0c5ea7515b65d686cbf256d294bcced19b248c252478a6a1cecb393d71a7f6 SHA512 6c7b8b88e01762e606bfd9e3848a98ae5825ff431f0686dd7bbcb987e448aa4c20d7cca3fb6b7c5d5dfde91ae6f8a16e674769d168f6f875e2efe519f4cdfd1b
 DIST Thunar-1.6.17.tar.bz2 1995398 BLAKE2B c6bc0ebc29cdf8b0d3d184fd5b5019bb6f4caa4e43e16237325ae938e95c077198801e7f0d5210c458e316e0c7f35aa735f8e5bca61372c3cb2f5cf40b78c59a SHA512 2ace85994af51e1651b1e58c4436b5d4a986e75ef56f85c765e7dad8698681a73e009feafff0c9e056153b13c37b915a43529451960a209ae7e0bc23544492b8
 DIST Thunar-1.8.7.tar.bz2 2326995 BLAKE2B 2eceeedabc66ced9ced70089b2ce66932a2223f4c4f6a6ae624199c00552d3d0fbb98f1c67bb0408d99d4167172698ecc9d020117d7c5fd41363b543b768ef69 SHA512 d4faf28857ee7c29c799bec9c5d7c639596b213f2aeb1089125d074083a4a13e91425cf3f35c63ce313330ee9ef070653a868a1a4526dc443a5d603bd9dec588
+DIST Thunar-1.8.8.tar.bz2 2333563 BLAKE2B be9903ea0d468982d45fa702fcb792150f3c757992f6a561d0a8747b18aec0f9794432c33ad42477f7e0753a83439eba19bea6afc184d15f7170c561d74b19e3 SHA512 364ca63169e01e8d7fe26c300ec7a6b8fd6734a364c9d0dd8943caf9ba08d6721ffdcef4905f9fdabca0da74503b8cbc4995ce271b7a5f787ae4b96b87f6bf96

diff --git a/xfce-base/thunar/thunar-1.8.8.ebuild b/xfce-base/thunar/thunar-1.8.8.ebuild
new file mode 100644
index 00000000000..453b5153905
--- /dev/null
+++ b/xfce-base/thunar/thunar-1.8.8.ebuild
@@ -0,0 +1,76 @@
+# Copyright 1999-2019 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=7
+inherit xdg-utils
+
+MY_P=${P^}
+
+DESCRIPTION="File manager for the Xfce desktop environment"
+HOMEPAGE="https://www.xfce.org/projects/ https://docs.xfce.org/xfce/thunar/start"
+SRC_URI="https://archive.xfce.org/src/xfce/${PN}/${PV%.*}/${MY_P}.tar.bz2"
+
+LICENSE="GPL-2+ LGPL-2+"
+SLOT="0/3"
+KEYWORDS="~alpha ~amd64 ~arm ~arm64 ~ia64 ~mips ~ppc ~ppc64 ~sparc ~x86 ~x86-fbsd ~amd64-linux ~x86-linux ~x86-solaris"
+IUSE="exif introspection libnotify pcre test +trash-panel-plugin udisks"
+
+GVFS_DEPEND=">=gnome-base/gvfs-1.18.3"
+COMMON_DEPEND=">=dev-lang/perl-5.6
+	>=dev-libs/glib-2.42:=
+	>=x11-libs/gdk-pixbuf-2.14:=
+	>=x11-libs/gtk+-3.22:3=
+	>=xfce-base/exo-0.12:=
+	>=xfce-base/libxfce4ui-4.12:=
+	>=xfce-base/libxfce4util-4.12:=
+	>=xfce-base/xfconf-4.12:=
+	exif? ( >=media-libs/libexif-0.6.19:= )
+	introspection? ( dev-libs/gobject-introspection:= )
+	libnotify? ( >=x11-libs/libnotify-0.7:= )
+	pcre? ( >=dev-libs/libpcre-6:= )
+	trash-panel-plugin? ( >=xfce-base/xfce4-panel-4.10:= )
+	udisks? ( virtual/libgudev:= )"
+RDEPEND="${COMMON_DEPEND}
+	>=dev-util/desktop-file-utils-0.20-r1
+	x11-misc/shared-mime-info
+	trash-panel-plugin? ( ${GVFS_DEPEND} )
+	udisks? (
+		virtual/udev
+		${GVFS_DEPEND}[udisks,udev]
+		)"
+DEPEND="${COMMON_DEPEND}
+	dev-util/intltool
+	sys-devel/gettext
+	virtual/pkgconfig"
+
+S=${WORKDIR}/${MY_P}
+
+DOCS=( AUTHORS ChangeLog FAQ HACKING NEWS README THANKS TODO )
+
+src_configure() {
+	local myconf=(
+		$(use_enable introspection)
+		$(use_enable udisks gudev)
+		$(use_enable libnotify notifications)
+		$(use_enable exif)
+		$(use_enable pcre)
+		$(use_enable trash-panel-plugin tpa-plugin)
+	)
+
+	econf "${myconf[@]}"
+}
+
+src_install() {
+	default
+	find "${D}" -name '*.la' -delete || die
+}
+
+pkg_postinst() {
+	xdg_desktop_database_update
+	xdg_icon_cache_update
+}
+
+pkg_postrm() {
+	xdg_desktop_database_update
+	xdg_icon_cache_update
+}