[gentoo-commits] repo/gentoo:master commit in: x11-misc/xwallpaper/

["Georgy Yakovlev" <gyakovlev@gentoo.org>]

commit:     9aa0128035404a4b6fd7875a8f1aaa4180d97beb
Author:     Georgy Yakovlev <gyakovlev <AT> gentoo <DOT> org>
AuthorDate: Fri Jul 19 06:52:37 2019 +0000
Commit:     Georgy Yakovlev <gyakovlev <AT> gentoo <DOT> org>
CommitDate: Fri Jul 19 06:52:37 2019 +0000
URL:        https://gitweb.gentoo.org/repo/gentoo.git/commit/?id=9aa01280

x11-misc/xwallpaper: revbump 0.6.2, adjust libjpeg dependency

Bug: https://bugs.gentoo.org/689512
Package-Manager: Portage-2.3.69, Repoman-2.3.16
Signed-off-by: Georgy Yakovlev <gyakovlev <AT> gentoo.org>

 x11-misc/xwallpaper/xwallpaper-0.6.2-r1.ebuild | 50 ++++++++++++++++++++++++++
 1 file changed, 50 insertions(+)

diff --git a/x11-misc/xwallpaper/xwallpaper-0.6.2-r1.ebuild b/x11-misc/xwallpaper/xwallpaper-0.6.2-r1.ebuild
new file mode 100644
index 00000000000..1fd0759173f
--- /dev/null
+++ b/x11-misc/xwallpaper/xwallpaper-0.6.2-r1.ebuild
@@ -0,0 +1,50 @@
+# Copyright 1999-2019 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=7
+
+inherit autotools
+
+DESCRIPTION="Wallpaper setting utility for X"
+HOMEPAGE="https://github.com/stoeckmann/xwallpaper"
+
+if [ ${PV} == "9999" ] ; then
+	inherit git-r3
+	EGIT_REPO_URI="https://github.com/stoeckmann/${PN}.git"
+else
+	SRC_URI="https://github.com/stoeckmann/${PN}/releases/download/v${PV}/${P}.tar.xz"
+	KEYWORDS="~amd64 ~x86"
+fi
+
+LICENSE="ISC"
+SLOT="0"
+IUSE="jpeg png seccomp xpm"
+
+RDEPEND="
+	x11-libs/pixman
+	x11-libs/xcb-util
+	x11-libs/xcb-util-image
+	jpeg? ( media-libs/libjpeg-turbo:= )
+	png? ( media-libs/libpng:0= )
+	seccomp? ( >=sys-libs/libseccomp-2.3.1:0= )
+	xpm? ( x11-libs/libXpm )"
+
+DEPEND="${RDEPEND}
+	virtual/pkgconfig
+"
+
+src_prepare() {
+	default
+	eautoreconf
+}
+src_configure() {
+	local myconf=(
+		$(use_with jpeg)
+		$(use_with png)
+		$(use_with seccomp)
+		$(use_with xpm)
+		--with-randr
+		--with-zshcompletiondir="${EPREFIX}/usr/share/zsh/site-functions"
+	)
+	econf "${myconf[@]}"
+}