[gentoo-commits] repo/gentoo:master commit in: dev-python/flask-babel/

["Louis Sautier" <sbraz@gentoo.org>]

commit:     17fb1ba9f4bda1d4ccbb99049d57f80cd4a031e5
Author:     Louis Sautier <sbraz <AT> gentoo <DOT> org>
AuthorDate: Thu Jul 18 11:59:33 2019 +0000
Commit:     Louis Sautier <sbraz <AT> gentoo <DOT> org>
CommitDate: Thu Jul 18 12:03:07 2019 +0000
URL:        https://gitweb.gentoo.org/repo/gentoo.git/commit/?id=17fb1ba9

dev-python/flask-babel: add Py3.7, fix doc deps, minor fixes

Stop overriding the flask theme and depend on it instead.

Package-Manager: Portage-2.3.69, Repoman-2.3.16
Signed-off-by: Louis Sautier <sbraz <AT> gentoo.org>

 .../flask-babel/flask-babel-0.11.2-r2.ebuild       | 55 ++++++++++++++++++++++
 1 file changed, 55 insertions(+)

diff --git a/dev-python/flask-babel/flask-babel-0.11.2-r2.ebuild b/dev-python/flask-babel/flask-babel-0.11.2-r2.ebuild
new file mode 100644
index 00000000000..194980cc413
--- /dev/null
+++ b/dev-python/flask-babel/flask-babel-0.11.2-r2.ebuild
@@ -0,0 +1,55 @@
+# Copyright 1999-2019 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=7
+PYTHON_COMPAT=( pypy{,3} python{2_7,3_{5,6,7}} )
+
+inherit distutils-r1
+
+MY_PN="Flask-Babel"
+MY_P="${MY_PN}-${PV}"
+
+DESCRIPTION="i18n and l10n support for Flask based on Babel and pytz"
+HOMEPAGE="https://pythonhosted.org/Flask-Babel/"
+SRC_URI="mirror://pypi/${MY_PN:0:1}/${MY_PN}/${MY_P}.tar.gz"
+
+LICENSE="BSD"
+SLOT="0"
+KEYWORDS="~amd64 ~x86"
+IUSE="doc test"
+
+RDEPEND="
+	dev-python/Babel[${PYTHON_USEDEP}]
+	dev-python/flask[${PYTHON_USEDEP}]
+	dev-python/pytz[${PYTHON_USEDEP}]
+	>=dev-python/jinja-2.5[${PYTHON_USEDEP}]
+"
+BDEPEND="
+	dev-python/setuptools[${PYTHON_USEDEP}]
+	doc? (
+		dev-python/flask-sphinx-themes[${PYTHON_USEDEP}]
+		dev-python/sphinx[${PYTHON_USEDEP}]
+	)
+	test? (
+		${RDEPEND}
+		dev-python/nose[${PYTHON_USEDEP}]
+	)
+"
+
+S="${WORKDIR}/${MY_P}"
+
+python_prepare_all() {
+	sed -i -e "s/, 'sphinx.ext.intersphinx'//" docs/conf.py || die
+	distutils-r1_python_prepare_all
+}
+
+python_compile_all() {
+	if use doc; then
+		sphinx-build docs docs/_build/html || die
+		HTML_DOCS=( docs/_build/html/. )
+	fi
+}
+
+python_test() {
+	nosetests -v || die "Tests failed under ${EPYTHON}"
+}