[gentoo-commits] repo/gentoo:master commit in: dev-python/wtforms/

["Louis Sautier" <sbraz@gentoo.org>]

commit:     a6f761625eaa1df9f3a78f0895da93927438a046
Author:     Louis Sautier <sbraz <AT> gentoo <DOT> org>
AuthorDate: Mon Jul 15 12:58:59 2019 +0000
Commit:     Louis Sautier <sbraz <AT> gentoo <DOT> org>
CommitDate: Mon Jul 15 13:13:15 2019 +0000
URL:        https://gitweb.gentoo.org/repo/gentoo.git/commit/?id=a6f76162

dev-python/wtforms: bump to 2.2.1, add PyPy3+Py3.7, fix tests

Package-Manager: Portage-2.3.69, Repoman-2.3.16
Signed-off-by: Louis Sautier <sbraz <AT> gentoo.org>

 dev-python/wtforms/Manifest             |  1 +
 dev-python/wtforms/wtforms-2.2.1.ebuild | 59 +++++++++++++++++++++++++++++++++
 2 files changed, 60 insertions(+)

diff --git a/dev-python/wtforms/Manifest b/dev-python/wtforms/Manifest
index 5dc5becebe9..4aa469b0b0b 100644
--- a/dev-python/wtforms/Manifest
+++ b/dev-python/wtforms/Manifest
@@ -1 +1,2 @@
 DIST WTForms-2.1.zip 553644 BLAKE2B 0db0c1d9b3249ad43ad5aa4da597fab3bca38f87eb636768b867365495a30d5f4d4a1def16c9965bfd4bce8ed28ffc7601b3b352af74208086feb7b54ab3de07 SHA512 2bdac0a35eca465021df9fb37dc0acd87bf487c6158b782d48870e9d5aab6ed3eb635af89bb38b9e8419688185f7c7b7875e68f7435d94bca8b074b2dddb12a0
+DIST WTForms-2.2.1.tar.gz 156904 BLAKE2B bec7c526f72b264888f7be45ba15d2bc4d194b09adc8ca5806cfc04cd1671663c851b7f1c99c602bb3e13d14a38733be61613058e46481bcea59901ac1f5b6b2 SHA512 06478790a8a4bf728e5436edaa63c7c0e596f71d63b273e1f296f9255d9fa3e31a7bfa95971c214a8cea684034ac3c77b05371f4b4e14da9d9ef2c5afadabde0

diff --git a/dev-python/wtforms/wtforms-2.2.1.ebuild b/dev-python/wtforms/wtforms-2.2.1.ebuild
new file mode 100644
index 00000000000..54abdefa4a6
--- /dev/null
+++ b/dev-python/wtforms/wtforms-2.2.1.ebuild
@@ -0,0 +1,59 @@
+# Copyright 1999-2019 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=7
+
+PYTHON_COMPAT=( pypy{,3} python{2_7,3_{5,6,7}} )
+
+inherit distutils-r1
+
+MY_PN="WTForms"
+MY_P="${MY_PN}-${PV}"
+
+DESCRIPTION="Flexible forms validation and rendering library for python web development"
+HOMEPAGE="https://wtforms.readthedocs.io/"
+SRC_URI="mirror://pypi/${MY_PN:0:1}/${MY_PN}/${MY_P}.tar.gz"
+
+LICENSE="BSD"
+SLOT="0"
+KEYWORDS="~amd64 ~x86"
+IUSE="doc test"
+
+S="${WORKDIR}/${MY_P}"
+
+BDEPEND="
+	dev-python/setuptools[${PYTHON_USEDEP}]
+	doc? ( >=dev-python/sphinx-0.6[${PYTHON_USEDEP}] )
+	test? (
+		dev-python/Babel[${PYTHON_USEDEP}]
+		dev-python/python-dateutil[${PYTHON_USEDEP}]
+		dev-python/sqlalchemy[${PYTHON_USEDEP}]
+		dev-python/webob[${PYTHON_USEDEP}]
+	)
+"
+
+python_prepare_all() {
+	# Extension-tests are written for an older version of Django
+	# Disable pep8 even when it is installed
+	sed \
+		-e "s|'ext_django.tests', ||" \
+		-e "/import pep8/d" \
+		-e "s|has_pep8 = True|has_pep8 = False|" \
+		-i tests/runtests.py || die
+	distutils-r1_python_prepare_all
+}
+
+python_compile_all() {
+	if use doc; then
+		emake -C docs html
+		HTML_DOCS=( docs/_build/html/. )
+	fi
+}
+
+python_test() {
+	"${EPYTHON}" tests/runtests.py -v || die
+}
+
+python_install_all() {
+	distutils-r1_python_install_all
+}