From mboxrd@z Thu Jan  1 00:00:00 1970
Return-Path: <gentoo-commits+bounces-1099569-garchives=archives.gentoo.org@lists.gentoo.org>
Received: from lists.gentoo.org (pigeon.gentoo.org [208.92.234.80])
	(using TLSv1.2 with cipher ECDHE-RSA-AES256-GCM-SHA384 (256/256 bits))
	(No client certificate requested)
	by finch.gentoo.org (Postfix) with ESMTPS id 67E9C138334
	for <garchives@archives.gentoo.org>; Sun, 14 Jul 2019 20:03:26 +0000 (UTC)
Received: from pigeon.gentoo.org (localhost [127.0.0.1])
	by pigeon.gentoo.org (Postfix) with SMTP id 7E2FFE0934;
	Sun, 14 Jul 2019 20:03:25 +0000 (UTC)
Received: from smtp.gentoo.org (mail.gentoo.org [IPv6:2001:470:ea4a:1:5054:ff:fec7:86e4])
	(using TLSv1.2 with cipher ECDHE-RSA-AES128-GCM-SHA256 (128/128 bits))
	(No client certificate requested)
	by pigeon.gentoo.org (Postfix) with ESMTPS id 3854AE0934
	for <gentoo-commits@lists.gentoo.org>; Sun, 14 Jul 2019 20:03:25 +0000 (UTC)
Received: from oystercatcher.gentoo.org (unknown [IPv6:2a01:4f8:202:4333:225:90ff:fed9:fc84])
	(using TLSv1.2 with cipher ECDHE-RSA-AES128-GCM-SHA256 (128/128 bits))
	(No client certificate requested)
	by smtp.gentoo.org (Postfix) with ESMTPS id 73EF9347B97
	for <gentoo-commits@lists.gentoo.org>; Sun, 14 Jul 2019 20:03:23 +0000 (UTC)
Received: from localhost.localdomain (localhost [IPv6:::1])
	by oystercatcher.gentoo.org (Postfix) with ESMTP id 383294D3
	for <gentoo-commits@lists.gentoo.org>; Sun, 14 Jul 2019 20:03:21 +0000 (UTC)
From: "David Seifert" <soap@gentoo.org>
To: gentoo-commits@lists.gentoo.org
Content-Transfer-Encoding: 8bit
Content-type: text/plain; charset=UTF-8
Reply-To: gentoo-dev@lists.gentoo.org, "David Seifert" <soap@gentoo.org>
Message-ID: <1563134582.78f521e8b51fdb8a37a1a11e05f9a9d870927ff9.soap@gentoo>
Subject: [gentoo-commits] repo/gentoo:master commit in: app-office/lyx/
X-VCS-Repository: repo/gentoo
X-VCS-Files: app-office/lyx/Manifest app-office/lyx/lyx-2.3.3.ebuild
X-VCS-Directories: app-office/lyx/
X-VCS-Committer: soap
X-VCS-Committer-Name: David Seifert
X-VCS-Revision: 78f521e8b51fdb8a37a1a11e05f9a9d870927ff9
X-VCS-Branch: master
Date: Sun, 14 Jul 2019 20:03:21 +0000 (UTC)
Precedence: bulk
List-Post: <mailto:gentoo-commits@lists.gentoo.org>
List-Help: <mailto:gentoo-commits+help@lists.gentoo.org>
List-Unsubscribe: <mailto:gentoo-commits+unsubscribe@lists.gentoo.org>
List-Subscribe: <mailto:gentoo-commits+subscribe@lists.gentoo.org>
List-Id: Gentoo Linux mail <gentoo-commits.gentoo.org>
X-BeenThere: gentoo-commits@lists.gentoo.org
X-Auto-Response-Suppress: DR, RN, NRN, OOF, AutoReply
X-Archives-Salt: fd161879-1d1c-41a2-886a-54baa81e0a12
X-Archives-Hash: 7994eda911d8741531e8585a4218b053

commit:     78f521e8b51fdb8a37a1a11e05f9a9d870927ff9
Author:     David Seifert <soap <AT> gentoo <DOT> org>
AuthorDate: Sun Jul 14 20:02:13 2019 +0000
Commit:     David Seifert <soap <AT> gentoo <DOT> org>
CommitDate: Sun Jul 14 20:03:02 2019 +0000
URL:        https://gitweb.gentoo.org/repo/gentoo.git/commit/?id=78f521e8

app-office/lyx: Version bump to 2.3.3

Bug: https://bugs.gentoo.org/684360
Closes: https://bugs.gentoo.org/667718
Package-Manager: Portage-2.3.69, Repoman-2.3.16
Signed-off-by: David Seifert <soap <AT> gentoo.org>

 app-office/lyx/Manifest         |   1 +
 app-office/lyx/lyx-2.3.3.ebuild | 176 ++++++++++++++++++++++++++++++++++++++++
 2 files changed, 177 insertions(+)

diff --git a/app-office/lyx/Manifest b/app-office/lyx/Manifest
index 0665f4ecf0a..8e43ccfa565 100644
--- a/app-office/lyx/Manifest
+++ b/app-office/lyx/Manifest
@@ -1 +1,2 @@
 DIST lyx-2.3.0.tar.xz 15676680 BLAKE2B 4b09f4c3979f51a8b30825c07fe3b24f080bfc8f42d54e94809e342087b683ca24edcb835994583b28d5b9c13868736f850d6c88b229e2d7f6f6bc0fd64c722c SHA512 77366d365f600069564b6d508ba2169744bbc7bc4dc9cb7e9d5f44941796dd7a027ca9ad08f5a67fd6863cbd1f6308ce5233b6e8685ebc6cf78ed19eef84ccb5
+DIST lyx-2.3.3.tar.xz 15998188 BLAKE2B 491732d1e567dfc8372a7dc7810cfc46cbe7e3b6a67637f772adddcff96225e174fe8c3db4c7f9e663cf3423da8b4bf08f67679874c9aaf556973ad46159a6cc SHA512 7b42df9da9f2906f626d568222e559bb921d003674d70c805657488180856a77143b2a3d073686116c95034e84fe8f58ee1ff8a74d47a40bd5fda7564335a0c3

diff --git a/app-office/lyx/lyx-2.3.3.ebuild b/app-office/lyx/lyx-2.3.3.ebuild
new file mode 100644
index 00000000000..3054f51d728
--- /dev/null
+++ b/app-office/lyx/lyx-2.3.3.ebuild
@@ -0,0 +1,176 @@
+# Copyright 1999-2019 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=6
+
+PYTHON_COMPAT=( python2_7 )
+
+MY_P="${P/_}"
+inherit desktop flag-o-matic font python-single-r1 qmake-utils toolchain-funcs xdg-utils
+
+DESCRIPTION="WYSIWYM frontend for LaTeX, DocBook, etc."
+HOMEPAGE="https://www.lyx.org/"
+SRC_URI="ftp://ftp.lyx.org/pub/lyx/stable/2.3.x/${MY_P}.tar.xz
+	ftp://ftp.lyx.org/pub/lyx/devel/lyx-2.3/${MY_P}/${MY_P}.tar.xz"
+
+LICENSE="GPL-2"
+SLOT="0"
+KEYWORDS="~amd64 ~hppa ~ppc ~ppc64 ~sparc ~x86 ~x64-macos ~x86-macos"
+IUSE="aspell cups debug docbook dia dot enchant gnumeric html +hunspell +latex monolithic-build nls rcs rtf subversion svg l10n_he"
+REQUIRED_USE="${PYTHON_REQUIRED_USE}"
+
+RDEPEND="${PYTHON_DEPS}
+	app-text/mythes
+	dev-libs/boost:=
+	dev-qt/qtcore:5
+	dev-qt/qtgui:5
+	dev-qt/qtsvg:5
+	dev-qt/qtwidgets:5
+	dev-qt/qtx11extras:5
+	dev-texlive/texlive-fontsextra
+	sys-apps/file
+	sys-libs/zlib
+	virtual/imagemagick-tools[png,svg?]
+	aspell? ( app-text/aspell )
+	cups? ( net-print/cups )
+	dia? ( app-office/dia )
+	docbook? ( app-text/sgmltools-lite )
+	dot? ( media-gfx/graphviz )
+	enchant? ( app-text/enchant )
+	gnumeric? ( app-office/gnumeric )
+	html? ( dev-tex/html2latex )
+	hunspell? ( app-text/hunspell )
+	l10n_he? ( dev-tex/culmus-latex )
+	latex? (
+		app-text/dvipng
+		app-text/ghostscript-gpl
+		app-text/ps2eps
+		app-text/texlive
+		dev-tex/chktex
+		dev-tex/dvipost
+		dev-texlive/texlive-fontsrecommended
+		dev-texlive/texlive-latexextra
+		dev-texlive/texlive-mathscience
+		dev-texlive/texlive-pictures
+		dev-texlive/texlive-plaingeneric
+		|| (
+			dev-tex/hevea
+			dev-tex/latex2html
+			dev-tex/tex4ht[java]
+			dev-tex/tth
+		)
+	)
+	rcs? ( dev-vcs/rcs )
+	rtf? (
+		app-text/unrtf
+		dev-tex/html2latex
+		dev-tex/latex2rtf
+	)
+	subversion? ( dev-vcs/subversion )
+	svg? ( || ( gnome-base/librsvg media-gfx/inkscape ) )
+"
+DEPEND="${RDEPEND}
+	virtual/pkgconfig
+	dev-qt/qtconcurrent:5
+	nls? ( sys-devel/gettext )
+"
+
+DOCS=( ANNOUNCE NEWS README RELEASE-NOTES UPGRADING )
+
+PATCHES=( "${FILESDIR}"/${PN}-2.3.0-python.patch )
+
+S="${WORKDIR}/${MY_P}"
+
+FONT_S="${S}/lib/fonts"
+FONT_SUFFIX="ttf"
+
+pkg_setup() {
+	python-single-r1_pkg_setup
+	font_pkg_setup
+}
+
+src_prepare() {
+	default
+	sed "s:python -tt:${EPYTHON} -tt:g" -i lib/configure.py || die
+}
+
+src_configure() {
+	tc-export CXX
+	#bug 221921
+	export VARTEXFONTS="${T}"/fonts
+
+	econf \
+		$(use_with aspell) \
+		$(use_enable debug) \
+		$(use_with enchant) \
+		$(use_with hunspell) \
+		$(use_enable monolithic-build) \
+		$(use_enable nls) \
+		--enable-qt5 \
+		--with-qt-dir=$(qt5_get_libdir)/qt5 \
+		--disable-stdlib-debug \
+		--without-included-boost \
+		--with-packaging=posix
+}
+
+src_install() {
+	default
+
+	if use l10n_he ; then
+		echo "\bind_file cua" > "${T}"/hebrew.bind || die
+		echo "\bind \"F12\" \"language hebrew\"" >> "${T}"/hebrew.bind || die
+
+		insinto /usr/share/lyx/bind
+		doins "${T}"/hebrew.bind
+	fi
+
+	newicon -s 32 "development/Win32/packaging/icons/lyx_32x32.png" ${PN}.png
+	doicon -s 48 "lib/images/lyx.png"
+	doicon -s scalable "lib/images/lyx.svg"
+
+	# fix for bug 91108
+	if use latex ; then
+		dosym ../../../lyx/tex /usr/share/texmf-site/tex/latex/lyx
+	fi
+
+	# fonts needed for proper math display, see also bug #15629
+	font_src_install
+
+	python_fix_shebang "${ED}"/usr/share/${PN}
+
+	if use hunspell ; then
+		dosym ../myspell /usr/share/lyx/dicts
+		dosym ../myspell /usr/share/lyx/thes
+	fi
+}
+
+pkg_postinst() {
+	font_pkg_postinst
+	xdg_icon_cache_update
+	xdg_desktop_database_update
+
+	# fix for bug 91108
+	if use latex ; then
+		texhash
+	fi
+
+	# instructions for RTL support. See also bug 168331.
+	if use l10n_he || has he ${LINGUAS} || has ar ${LINGUAS} ; then
+		elog
+		elog "Enabling RTL support in LyX:"
+		elog "If you intend to use a RTL language (such as Hebrew or Arabic)"
+		elog "You must enable RTL support in LyX. To do so start LyX and go to"
+		elog "Tools->Preferences->Language settings->Language"
+		elog "and make sure the \"Right-to-left language support\" is checked"
+		elog
+	fi
+}
+
+pkg_postrm() {
+	xdg_icon_cache_update
+	xdg_desktop_database_update
+
+	if use latex ; then
+		texhash
+	fi
+}