[gentoo-commits] repo/gentoo:master commit in: dev-db/pgbouncer/

["Aaron W. Swenson" <titanofold@gentoo.org>]

commit:     653a5109e1016920aa790099a3f56bca8cd9216b
Author:     Aaron W. Swenson <titanofold <AT> gentoo <DOT> org>
AuthorDate: Thu Jul  4 12:00:47 2019 +0000
Commit:     Aaron W. Swenson <titanofold <AT> gentoo <DOT> org>
CommitDate: Thu Jul  4 12:01:06 2019 +0000
URL:        https://gitweb.gentoo.org/repo/gentoo.git/commit/?id=653a5109

dev-db/pgbouncer: Bump to 1.10.0

Package-Manager: Portage-2.3.66, Repoman-2.3.11
Signed-off-by: Aaron W. Swenson <titanofold <AT> gentoo.org>

 dev-db/pgbouncer/Manifest                |  1 +
 dev-db/pgbouncer/pgbouncer-1.10.0.ebuild | 86 ++++++++++++++++++++++++++++++++
 2 files changed, 87 insertions(+)

diff --git a/dev-db/pgbouncer/Manifest b/dev-db/pgbouncer/Manifest
index 11cc6304a31..8336f7b1320 100644
--- a/dev-db/pgbouncer/Manifest
+++ b/dev-db/pgbouncer/Manifest
@@ -1 +1,2 @@
+DIST pgbouncer-1.10.0.tar.gz 480571 BLAKE2B a0c1dadc48f38cfe0ba2641791b4734da84cfe6674198bb2a8014bc92543850e909d7b4649b99e78d58febaa0f89f62b6694f6333b1111cbd62ff2f22741984d SHA512 8ec9f102b57ca5f92fb689588ec090056ac29f21825400ec67bca413fe076ad50e0b491e65c4cfebc488cc245eb3c88c36db2ee0ba1cb737f35404be0983dd1d
 DIST pgbouncer-1.9.0.tar.gz 469300 BLAKE2B 466f171a49ec9ce9be9a9d3208780cfbff956da7c74ec4332c7104ea537cb47a5cfdc0d80bbd96d233769b6f430f1ad99b623caefa2dc93af7ba336dd0f49514 SHA512 b127f4cb60ca5cdf339da76727918f0a3797a3e0a89f8ed6fdcaa80f3391d2c5bb51e19731915775210c0e5070dd611ee2e410c9a947624e45b5cf11aecdacf9

diff --git a/dev-db/pgbouncer/pgbouncer-1.10.0.ebuild b/dev-db/pgbouncer/pgbouncer-1.10.0.ebuild
new file mode 100644
index 00000000000..caae5f40fcf
--- /dev/null
+++ b/dev-db/pgbouncer/pgbouncer-1.10.0.ebuild
@@ -0,0 +1,86 @@
+# Copyright 1999-2019 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=7
+
+inherit user
+
+DESCRIPTION="Lightweight connection pooler for PostgreSQL"
+HOMEPAGE="https://pgbouncer.github.io"
+SRC_URI="https://pgbouncer.github.io/downloads/files/${PV}/${P}.tar.gz"
+LICENSE="BSD"
+SLOT="0"
+KEYWORDS="~amd64 ~x86"
+IUSE="+c-ares debug doc pam ssl -udns"
+
+# At-most-one-of, one can be enabled but not both
+REQUIRED_USE="?? ( c-ares udns )"
+
+RDEPEND="
+	>=dev-libs/libevent-2.0
+	>=sys-libs/glibc-2.10
+	c-ares? ( >=net-dns/c-ares-1.10 )
+	ssl? ( >=dev-libs/openssl-1.0.1:=[-bindist] )
+	udns? ( >=net-libs/udns-0.1 )
+"
+
+DEPEND="${RDEPEND}"
+
+pkg_setup() {
+	enewgroup postgres 70
+	enewuser postgres 70 /bin/bash /var/lib/postgresql postgres
+
+	enewuser pgbouncer -1 -1 -1 postgres
+}
+
+src_prepare() {
+	eapply "${FILESDIR}/pgbouncer-1.8-dirs.patch"
+
+	default
+}
+
+src_configure() {
+	# --enable-debug is only used to disable stripping
+	econf \
+		--docdir=/usr/share/doc/${PF} \
+		--enable-debug \
+		$(use_with c-ares cares) \
+		$(use_enable debug cassert) \
+		$(use_with pam) \
+		$(use_with ssl openssl) \
+		$(use_with udns)
+}
+
+src_test() {
+	cd "${S}/test"
+	emake
+}
+
+src_install() {
+	emake DESTDIR="${D}" install
+
+	dodoc AUTHORS
+	use doc && dodoc doc/*.rst
+
+	newconfd "${FILESDIR}/${PN}.confd-r1" "${PN}"
+	newinitd "${FILESDIR}/${PN}.initd-r2" "${PN}"
+
+	insinto /etc
+	doins etc/pgbouncer.ini
+
+	insinto /etc/logrotate.d
+	newins "${FILESDIR}/logrotate" pgbouncer
+}
+
+pkg_postinst() {
+	if [[ -z ${REPLACING_VERSIONS} ]] ; then
+		einfo "Please read the config.txt for Configuration Directives"
+		einfo
+		einfo "For Administration Commands, see:"
+		einfo "    man pgbouncer"
+		einfo
+		einfo "By default, PgBouncer does not have access to any database."
+		einfo "GRANT the permissions needed for your application and make sure that it"
+		einfo "exists in PgBouncer's auth_file."
+	fi
+}