[gentoo-commits] repo/gentoo:master commit in: dev-python/jaraco-logging/

["Louis Sautier" <sbraz@gentoo.org>]

commit:     d528c4bfb9d0b293619dbe0918dffe171f29aaee
Author:     Louis Sautier <sbraz <AT> gentoo <DOT> org>
AuthorDate: Tue Jul  2 13:59:33 2019 +0000
Commit:     Louis Sautier <sbraz <AT> gentoo <DOT> org>
CommitDate: Tue Jul  2 14:02:58 2019 +0000
URL:        https://gitweb.gentoo.org/repo/gentoo.git/commit/?id=d528c4bf

dev-python/jaraco-logging: bump to 2.0, switches to pkgutil

Package-Manager: Portage-2.3.67, Repoman-2.3.16
Signed-off-by: Louis Sautier <sbraz <AT> gentoo.org>

 dev-python/jaraco-logging/Manifest                 |  1 +
 .../jaraco-logging/jaraco-logging-2.0.ebuild       | 60 ++++++++++++++++++++++
 2 files changed, 61 insertions(+)

diff --git a/dev-python/jaraco-logging/Manifest b/dev-python/jaraco-logging/Manifest
index a868354b9a8..74af9db8ac6 100644
--- a/dev-python/jaraco-logging/Manifest
+++ b/dev-python/jaraco-logging/Manifest
@@ -1,2 +1,3 @@
 DIST jaraco.logging-1.5.2.tar.gz 7135 BLAKE2B 5235566df80008270f2f28101ab5df1d7fbc1446f138eb4cb851c9bb464b741c0ebb8528d3502130b5c557f30214ec27ce1ea563e09e78776e22d37811da21b5 SHA512 3299adc9c9ca6113198cddbc34147afe1bf453edee16a2d6bfcce64e63deeaff7f87beb74ff44f092435f3433a921b19167fb45778dce444512807357bce1661
 DIST jaraco.logging-1.5.tar.gz 5707 BLAKE2B 853d2747ab92754de4480871355180a33a7a6cbf69fc3d32ba489ecac27dc55ad92d94bfb84e411ee13400d82d162ea400be1027c3002f317a97e00b849484ec SHA512 18f267bd0c764f38ff5223d4fd6e08d7d9fa568691db285155d7b955c71439474fd84edd61b20d57f6eac77394d4b3ddf9b35d8e6ba08a2db5dd4b2ada6e0d68
+DIST jaraco.logging-2.0.tar.gz 10356 BLAKE2B a7522fa9895784a68c8c0af265ad5a82ba27f69e90a17ba18b4a579e1ca5785ad11b7718273adb33661e45e780876b885b581af1b4518ef5322c077ed76242ba SHA512 9262575c3071f78ded2284ebef3a1a80c8ffd60addecf9b215db04471672bd892f6c6bd06a84f9a82e872adf31d45d4eb3faa2884815fcce608840821f49954e

diff --git a/dev-python/jaraco-logging/jaraco-logging-2.0.ebuild b/dev-python/jaraco-logging/jaraco-logging-2.0.ebuild
new file mode 100644
index 00000000000..392aac0a28e
--- /dev/null
+++ b/dev-python/jaraco-logging/jaraco-logging-2.0.ebuild
@@ -0,0 +1,60 @@
+# Copyright 1999-2019 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=7
+
+PYTHON_COMPAT=( pypy3 python{2_7,3_{5,6,7}} )
+
+inherit distutils-r1
+
+MY_PN="${PN/-/.}"
+DESCRIPTION="Additional facilities to supplement Python's stdlib logging module"
+HOMEPAGE="https://github.com/jaraco/jaraco.logging"
+SRC_URI="mirror://pypi/${PN:0:1}/${MY_PN}/${MY_PN}-${PV}.tar.gz"
+
+LICENSE="MIT"
+SLOT="0"
+KEYWORDS="~amd64 ~x86"
+IUSE="doc test"
+
+RDEPEND="
+	>=dev-python/namespace-jaraco-2[${PYTHON_USEDEP}]
+	dev-python/six[${PYTHON_USEDEP}]
+	dev-python/tempora[${PYTHON_USEDEP}]
+"
+DEPEND="
+	dev-python/setuptools[${PYTHON_USEDEP}]
+	>=dev-python/setuptools_scm-1.15.0[${PYTHON_USEDEP}]
+	doc? (
+		>=dev-python/jaraco-packaging-3.2[${PYTHON_USEDEP}]
+		>=dev-python/rst-linker-1.9[${PYTHON_USEDEP}]
+		dev-python/sphinx[${PYTHON_USEDEP}]
+	)
+	test? (
+		${RDEPEND}
+		>=dev-python/pytest-2.8[${PYTHON_USEDEP}]
+	)
+"
+
+S="${WORKDIR}/${MY_PN}-${PV}"
+
+python_compile_all() {
+	if use doc; then
+		cd docs || die
+		sphinx-build . _build/html || die
+		HTML_DOCS=( docs/_build/html/. )
+	fi
+}
+
+python_test() {
+	# Override pytest options to skip flake8
+	PYTHONPATH=. pytest -v --override-ini="addopts=--doctest-modules" \
+		|| die "tests failed with ${EPYTHON}"
+}
+
+# https://wiki.gentoo.org/wiki/Project:Python/Namespace_packages#File_collisions_between_pkgutil-style_packages
+python_install() {
+	rm "${BUILD_DIR}"/lib/jaraco/__init__.py || die
+	# note: eclass may default to --skip-build in the future
+	distutils-r1_python_install --skip-build
+}