[gentoo-commits] repo/gentoo:master commit in: net-misc/miniupnpd/

["Michał Górny" <mgorny@gentoo.org>]

commit:     1a0ec3e483cf0f483f608496b1f7bfb5656f0fbd
Author:     Michał Górny <mgorny <AT> gentoo <DOT> org>
AuthorDate: Wed Jun 26 12:34:24 2019 +0000
Commit:     Michał Górny <mgorny <AT> gentoo <DOT> org>
CommitDate: Wed Jun 26 15:47:17 2019 +0000
URL:        https://gitweb.gentoo.org/repo/gentoo.git/commit/?id=1a0ec3e4

net-misc/miniupnpd: Bump to 2.1.20190625

Signed-off-by: Michał Górny <mgorny <AT> gentoo.org>

 net-misc/miniupnpd/Manifest                      |  1 +
 net-misc/miniupnpd/miniupnpd-2.1.20190625.ebuild | 65 ++++++++++++++++++++++++
 2 files changed, 66 insertions(+)

diff --git a/net-misc/miniupnpd/Manifest b/net-misc/miniupnpd/Manifest
index 7b4daa41d1c..d75a1d6b4cd 100644
--- a/net-misc/miniupnpd/Manifest
+++ b/net-misc/miniupnpd/Manifest
@@ -1 +1,2 @@
 DIST miniupnpd-2.1.20190502.tar.gz 236052 BLAKE2B 9f2f81769d72fad2191969e0e80b4d2e70619d5674fe6b4ef9f4306e09ac4737577a2146bc04ec9960df092252abe3c9a57e32d5d893a763b85863d1c4892045 SHA512 6423cef89b5af62b6b6a120a3cd13a0e7755d609b33de8f1671f7f9160fb1b5e68b0ebd3f8b7b5758cf05a1c58b416cde253e37bc5ba0bb423c14b5fb44599f1
+DIST miniupnpd-2.1.20190625.tar.gz 240120 BLAKE2B c6cf6b549a1c0c4a411d9487a3dae348d8a37767b9590d29ea763177d876ceb6f521bb7662452e2dff813354fc52f862bcc830079b3ff8af8185de6ee2771e8f SHA512 3b9a14f24c7e753cc71b84622bfbbc0db4a5b5e0fd602ef1129b89b1c729e754c51f5c29b4bf8d1cc37a16f77b33f04cf3f3540afe1ac529105cb91f45fa92c8

diff --git a/net-misc/miniupnpd/miniupnpd-2.1.20190625.ebuild b/net-misc/miniupnpd/miniupnpd-2.1.20190625.ebuild
new file mode 100644
index 00000000000..673b340fb09
--- /dev/null
+++ b/net-misc/miniupnpd/miniupnpd-2.1.20190625.ebuild
@@ -0,0 +1,65 @@
+# Copyright 1999-2019 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=7
+
+inherit toolchain-funcs
+
+DESCRIPTION="MiniUPnP IGD Daemon"
+HOMEPAGE="http://miniupnp.free.fr/"
+SRC_URI="http://miniupnp.free.fr/files/${P}.tar.gz"
+
+LICENSE="BSD"
+SLOT="0"
+KEYWORDS="~amd64 ~arm ~x86"
+IUSE="+leasefile igd2 ipv6 pcp-peer portinuse strict"
+
+RDEPEND=">=net-firewall/iptables-1.4.6:0=[ipv6?]
+	net-libs/libnfnetlink:=
+	net-libs/libmnl:=
+	dev-libs/gmp:0=
+	sys-apps/util-linux:=
+	dev-libs/openssl:0="
+DEPEND="${RDEPEND}
+	sys-apps/lsb-release"
+
+src_prepare() {
+	default
+	mv Makefile.linux Makefile || die
+
+	# Prevent gzipping manpage.
+	sed -i -e '/gzip/d' Makefile || die
+}
+
+src_configure() {
+	local -a opts
+	opts=(
+		--vendorcfg
+		$(usex igd2 '--igd2' '')
+		$(usex ipv6 '--ipv6' '')
+		$(usex leasefile '--leasefile' '')
+		$(usex portinuse '--portinuse' '')
+		$(usex pcp-peer '--pcp-peer' '')
+		$(usex strict '--strict' '')
+	)
+
+	emake CONFIG_OPTIONS="${opts[*]}" config.h
+}
+
+src_compile() {
+	# By default, it builds a bunch of unittests that are missing wrapper
+	# scripts in the tarball
+	emake CC="$(tc-getCC)" STRIP=true miniupnpd
+}
+
+src_install() {
+	emake PREFIX="${ED}" STRIP=true install
+
+	newinitd "${FILESDIR}"/${PN}-init.d-r1 ${PN}
+	newconfd "${FILESDIR}"/${PN}-conf.d-r1 ${PN}
+}
+
+pkg_postinst() {
+	elog "Please correct the external interface in the top of the two"
+	elog "scripts in /etc/miniupnpd and edit the config file in there too"
+}