[gentoo-commits] repo/gentoo:master commit in: profiles/features/selinux/, gnome-base/gnome-panel/

[gentoo-commits] repo/gentoo:master commit in: profiles/features/selinux/, gnome-base/gnome-panel/

[Mart Raudsepp]

commit:     d49854d742675fd12c23f9f7c720400b5e440fe2
Author:     Mart Raudsepp <leio <AT> gentoo <DOT> org>
AuthorDate: Fri Jun 21 21:47:20 2019 +0000
Commit:     Mart Raudsepp <leio <AT> gentoo <DOT> org>
CommitDate: Fri Jun 21 21:54:25 2019 +0000
URL:        https://gitweb.gentoo.org/repo/gentoo.git/commit/?id=d49854d7

gnome-base/gnome-panel: add 3.32.0 for GNOME Flashback session

Bug: https://bugs.gentoo.org/680326
Package-Manager: Portage-2.3.62, Repoman-2.3.12
Signed-off-by: Mart Raudsepp <leio <AT> gentoo.org>

 gnome-base/gnome-panel/Manifest                  |  1 +
 gnome-base/gnome-panel/gnome-panel-3.32.0.ebuild | 70 ++++++++++++++++++++++++
 gnome-base/gnome-panel/metadata.xml              |  8 +++
 profiles/features/selinux/package.mask           |  1 +
 4 files changed, 80 insertions(+)

diff --git a/gnome-base/gnome-panel/Manifest b/gnome-base/gnome-panel/Manifest
new file mode 100644
index 00000000000..b2d2f065129
--- /dev/null
+++ b/gnome-base/gnome-panel/Manifest
@@ -0,0 +1 @@
+DIST gnome-panel-3.32.0.tar.xz 3073664 BLAKE2B 90960646bb6a7d455e295203b0ae9af8fb2313d3f69c54907f5b975bcf2102667aac693c0e32912538015a48d784bfad45335df6df060dcebfeb04486955d850 SHA512 afbb5d61d024250bc6532ddcb2817067bb4e5f243a0d0f27efcaa9b1c2da8ab6c98e014e3a852ccb93d64aba8da51254d0e811f5eecc927cfc18c72e7c324e42

diff --git a/gnome-base/gnome-panel/gnome-panel-3.32.0.ebuild b/gnome-base/gnome-panel/gnome-panel-3.32.0.ebuild
new file mode 100644
index 00000000000..5f1bb00fd17
--- /dev/null
+++ b/gnome-base/gnome-panel/gnome-panel-3.32.0.ebuild
@@ -0,0 +1,70 @@
+# Copyright 1999-2019 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=6
+inherit eapi7-ver gnome2
+
+DESCRIPTION="The GNOME Flashback Panel"
+HOMEPAGE="https://gitlab.gnome.org/GNOME/gnome-panel/"
+
+LICENSE="GPL-2+ FDL-1.1 LGPL-2.1+"
+SLOT="0"
+IUSE="eds elogind systemd"
+REQUIRED_USE="^^ ( elogind systemd )"
+KEYWORDS="~amd64"
+
+RDEPEND="
+	>=gnome-base/gnome-desktop-2.91.0:3=
+	>=x11-libs/gdk-pixbuf-2.26.0:2
+	>=x11-libs/pango-1.15.4
+	>=dev-libs/glib-2.45.3:2
+	>=x11-libs/gtk+-3.22.0:3[X]
+	>=x11-libs/libwnck-3.4.6:3
+	>=gnome-base/gnome-menus-3.7.90:3
+	eds? ( >=gnome-extra/evolution-data-server-3.5.3:= )
+	elogind? ( >=sys-auth/elogind-230 )
+	systemd? ( >=sys-apps/systemd-230:= )
+	>=x11-libs/cairo-1.0.0[X,glib]
+	>=dev-libs/libgweather-3.28.0:2=
+	>=gnome-base/dconf-0.13.4
+	>=x11-libs/libXrandr-1.3.0
+	gnome-base/gdm
+	x11-libs/libX11
+	sys-auth/polkit
+	x11-libs/libXi
+"
+DEPEND="${RDEPEND}
+	app-text/docbook-xml-dtd:4.1.2
+	dev-util/gdbus-codegen
+	dev-util/glib-utils
+	>=dev-util/gtk-doc-am-1.25
+	dev-util/itstool
+	>=sys-devel/gettext-0.19.8
+	virtual/pkgconfig
+	x11-base/xorg-proto
+" # yelp-tools and autoconf-archive for eautoreconf
+
+src_configure() {
+	local myconf=(
+		--disable-static
+		$(use_enable eds)
+	)
+
+	# Below elogind MENU_* pkg-config calls need to match up with what upstream has
+	# each version (libsystemd replaced with libelogind). Explicit per-version die
+	# to force a manual recheck. Only update the explicit version if the
+	# "PKG_CHECK_MODULES([MENU], ...)" block did not change; otherwise adjust
+	# elogind conditional block below accordingly first.
+	if ver_test ${PV} -ne 3.32.0; then
+		die "Maintainer has not checked over packages MENU pkg-config deps for elogind support"
+	fi
+
+	if use elogind; then
+		myconf+=(
+			MENU_CFLAGS=`pkg-config --cflags gdm gio-unix-2.0 gtk+-3.0 libgnome-menu-3.0 libelogind 2>/dev/null`
+			MENU_LIBS=`pkg-config --libs gdm gio-unix-2.0 gtk+-3.0 libgnome-menu-3.0 libelogind 2>/dev/null`
+		)
+	fi
+
+	gnome2_src_configure "${myconf[@]}"
+}

diff --git a/gnome-base/gnome-panel/metadata.xml b/gnome-base/gnome-panel/metadata.xml
new file mode 100644
index 00000000000..39980802b1d
--- /dev/null
+++ b/gnome-base/gnome-panel/metadata.xml
@@ -0,0 +1,8 @@
+<?xml version="1.0" encoding="UTF-8"?>
+<!DOCTYPE pkgmetadata SYSTEM "http://www.gentoo.org/dtd/metadata.dtd">
+<pkgmetadata>
+<maintainer type="project">
+	<email>gnome@gentoo.org</email>
+	<name>Gentoo GNOME Desktop</name>
+</maintainer>
+</pkgmetadata>

diff --git a/profiles/features/selinux/package.mask b/profiles/features/selinux/package.mask
index 84625d6e236..185fbc24c1b 100644
--- a/profiles/features/selinux/package.mask
+++ b/profiles/features/selinux/package.mask
@@ -22,6 +22,7 @@ gnome-base/gdm
 gnome-base/gnome
 gnome-base/gnome-extra-apps
 gnome-base/gnome-light
+gnome-base/gnome-panel
 gnome-base/gnome-shell
 gnome-extra/chrome-gnome-shell
 gnome-extra/gnome-logs