[gentoo-commits] repo/proj/guru:master commit in: dev-util/pybind11/

["Ralph Seichter" <gentoo@seichter.de>]

commit:     5aace92c7dbc6a586b1e865e68452e33e0bfc909
Author:     Bernd Waibel <waebbl <AT> gmail <DOT> com>
AuthorDate: Sat Jun 15 16:46:31 2019 +0000
Commit:     Ralph Seichter <gentoo <AT> seichter <DOT> de>
CommitDate: Sat Jun 15 16:46:31 2019 +0000
URL:        https://gitweb.gentoo.org/repo/proj/guru.git/commit/?id=5aace92c

dev-util/pybind11: bump to version 2.3.0

Package-Manager: Portage-2.3.67, Repoman-2.3.14
Signed-off-by: Bernd Waibel <waebbl <AT> gmail.com>

 dev-util/pybind11/Manifest              |  1 +
 dev-util/pybind11/pybind11-2.3.0.ebuild | 94 +++++++++++++++++++++++++++++++++
 2 files changed, 95 insertions(+)

diff --git a/dev-util/pybind11/Manifest b/dev-util/pybind11/Manifest
index 5a4fe9b..e8a8b70 100644
--- a/dev-util/pybind11/Manifest
+++ b/dev-util/pybind11/Manifest
@@ -1 +1,2 @@
 DIST pybind11-2.2.4.tar.gz 548404 BLAKE2B b56230b5a4c0f392b714ead40d414a8b587396dbeec4089f5b77141cc7c2caf135f17f680b653d2e5be8b60a19a48a716fe8e562f337650fdac76461fb982aee SHA512 6bddf5c885ff92a3e373bcedc6574dfefe8be9ebb6176c6c96d475457466c76bfb982c6df4066cb0fbead4b867f87dbc4fbc1605c80852635016f614330ce041
+DIST pybind11-2.3.0.tar.gz 564520 BLAKE2B a7c1485aa8f63a00eccd3103cf9f531a080b049be02e6182b30503ae6dd6c55fc517684ed9d92aaec244efd5f77336c68d1ea546833f7f0ae2fd7b090c19a02d SHA512 04542fe9dca2ffdb86c15698a4bbc041446a9f11970092e89a482ae0ff64c932f62fff8f437b98bdaa006c1fccabddd79f0c7e376f27daed2150b1d2f988e8aa

diff --git a/dev-util/pybind11/pybind11-2.3.0.ebuild b/dev-util/pybind11/pybind11-2.3.0.ebuild
new file mode 100644
index 0000000..6a24042
--- /dev/null
+++ b/dev-util/pybind11/pybind11-2.3.0.ebuild
@@ -0,0 +1,94 @@
+# Copyright 1999-2019 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=7
+
+# According to upstream is compatible with 2.7 and 3.x
+# However support for python3_7 needs boost with python3_7
+PYTHON_COMPAT=( python{2_7,3_{5,6}} )
+
+inherit cmake-utils python-single-r1
+
+DESCRIPTION="Seamless operability between C++11 and Python"
+HOMEPAGE="https://pybind11.readthedocs.io/en/stable/"
+SRC_URI="https://github.com/pybind/pybind11/archive/v${PV}.tar.gz -> ${P}.tar.gz"
+LICENSE="BSD"
+
+SLOT="0"
+KEYWORDS="~amd64 ~x86"
+
+IUSE="doc test"
+
+RESTRICT="!test? ( test )"
+
+DEPEND="
+	${PYTHON_DEP}
+	doc? (
+		dev-python/breathe[${PYTHON_USEDEP}]
+		dev-python/sphinx[${PYTHON_USEDEP}]
+	)
+	test? (
+		dev-cpp/catch:0
+		dev-libs/boost:=[python,${PYTHON_USEDEP}]
+		dev-python/numpy[${PYTHON_USEDEP}]
+		dev-python/pytest[${PYTHON_USEDEP}]
+		sci-libs/scipy[${PYTHON_USEDEP}]
+	)
+"
+
+RDEPEND="
+	${PYTHON_DEP}
+	dev-cpp/eigen:3
+	sys-apps/texinfo
+	sys-devel/gettext[cxx]
+	virtual/man
+"
+
+REQUIRED_USE="${PYTHON_REQUIRED_USE}"
+
+DOCS=( README.md CONTRIBUTING.md ISSUE_TEMPLATE.md )
+
+pkg_setup() {
+	python-single-r1_pkg_setup
+}
+
+src_configure() {
+	mycmakeargs=(
+		-DPYBIND11_INSTALL=ON
+		-DPYBIND11_TEST=$(usex test)
+	)
+
+	cmake-utils_src_configure
+}
+
+src_compile() {
+	cmake-utils_src_compile
+
+	# documentation is not covered by cmake, but has it's own makefile
+	# using sphinx
+	if use doc; then
+		pushd "${S}"/docs || die
+		emake info man html
+		popd || die
+	fi
+}
+
+src_test() {
+	cmake-utils_src_test
+	pushd "${BUILD_DIR}" || die
+	eninja check
+	popd || die
+}
+
+src_install() {
+	cmake-utils_src_install
+
+	if use doc; then
+		local HTML_DOCS=( "${S}"/docs/.build/html/. )
+		einstalldocs
+
+		# install man and info pages
+		doman "${S}"/docs/.build/man/pybind11.1
+		doinfo "${S}"/docs/.build/texinfo/pybind11.info
+	fi
+}