[gentoo-commits] repo/gentoo:master commit in: media-sound/lmms/

["Lars Wendler" <polynomial-c@gentoo.org>]

commit:     77aeb49478eccf4be3fbdf10a79b5dca20a10d19
Author:     Lars Wendler <polynomial-c <AT> gentoo <DOT> org>
AuthorDate: Tue Jun 11 10:54:45 2019 +0000
Commit:     Lars Wendler <polynomial-c <AT> gentoo <DOT> org>
CommitDate: Tue Jun 11 11:11:51 2019 +0000
URL:        https://gitweb.gentoo.org/repo/gentoo.git/commit/?id=77aeb494

media-sound/lmms: Bump to version 1.2.0

Package-Manager: Portage-2.3.67, Repoman-2.3.14
Signed-off-by: Lars Wendler <polynomial-c <AT> gentoo.org>

 media-sound/lmms/Manifest          |   1 +
 media-sound/lmms/lmms-1.2.0.ebuild | 106 +++++++++++++++++++++++++++++++++++++
 2 files changed, 107 insertions(+)

diff --git a/media-sound/lmms/Manifest b/media-sound/lmms/Manifest
index 6f79232bd4c..08e455dc2c9 100644
--- a/media-sound/lmms/Manifest
+++ b/media-sound/lmms/Manifest
@@ -1 +1,2 @@
+DIST lmms-1.2.0.tar.xz 14541000 BLAKE2B f53206c2a78104d250fd7eda06ea1c646ad40c2db66baa9ed333213900e33bcab5312c95d5864636930be1b798ac1a79754035e3aec3a3772976aefb80dd8191 SHA512 7d3476fbcbda49d75efee4161f6478656e38a517b6a3b24740ea354e223fba51210f45ff74b46fd1ac73fc6e65409226088b12e29558c91eb818da58734ab6cf
 DIST lmms-1.2.0_rc8.tar.xz 14318692 BLAKE2B 972404ab6ce517c748aad21528d5891af5d12c47d38a18f802fb3a5dfc5d6f3ee91cce14a6ff267341c06c9607328b018e1b612f7f0f550372a35038749a7bb3 SHA512 b8fb9c505d9f5e7854767bcd223c8578d4977e59d7bf64993fe0b57e00d1de87f8e77366c3195d8ea429eb3dd44c641e3dbecf27e64609e892a4453ab17d7343

diff --git a/media-sound/lmms/lmms-1.2.0.ebuild b/media-sound/lmms/lmms-1.2.0.ebuild
new file mode 100644
index 00000000000..d5f82bfff2a
--- /dev/null
+++ b/media-sound/lmms/lmms-1.2.0.ebuild
@@ -0,0 +1,106 @@
+# Copyright 1999-2019 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=7
+
+# The order is important here! Both, cmake-utils and xdg define src_prepare.
+# We need the one from cmake-utils
+inherit xdg cmake-utils
+
+DESCRIPTION="Cross-platform music production software"
+HOMEPAGE="https://lmms.io"
+if [[ ${PV} == "9999" ]]; then
+	EGIT_REPO_URI="https://github.com/LMMS/lmms.git"
+	inherit git-r3
+else
+	SRC_URI="https://github.com/LMMS/lmms/releases/download/v${PV/_/-}/${PN}_${PV/_/-}.tar.xz -> ${P}.tar.xz"
+	KEYWORDS="~amd64 ~x86"
+	S="${WORKDIR}/${P/_/-}"
+fi
+
+LICENSE="GPL-2 LGPL-2"
+SLOT="0"
+
+IUSE="alsa debug fluidsynth jack libgig mp3 ogg portaudio pulseaudio sdl soundio stk vst"
+
+COMMON_DEPEND="
+	dev-qt/qtcore:5
+	dev-qt/qtgui:5
+	dev-qt/qtwidgets:5
+	dev-qt/qtxml:5
+	>=media-libs/libsamplerate-0.1.8
+	>=media-libs/libsndfile-1.0.11
+	sci-libs/fftw:3.0
+	sys-libs/zlib
+	>=x11-libs/fltk-1.3.0_rc3:1
+	alsa? ( media-libs/alsa-lib )
+	fluidsynth? ( media-sound/fluidsynth )
+	jack? ( virtual/jack )
+	libgig? ( media-libs/libgig )
+	mp3? ( media-sound/lame )
+	ogg? (
+		media-libs/libogg
+		media-libs/libvorbis
+	)
+	portaudio? ( >=media-libs/portaudio-19_pre )
+	pulseaudio? ( media-sound/pulseaudio )
+	sdl? (
+		media-libs/libsdl
+		>=media-libs/sdl-sound-1.0.1
+	)
+	soundio? ( media-libs/libsoundio )
+	stk? ( media-libs/stk )
+	vst? ( virtual/wine )
+"
+DEPEND="${COMMON_DEPEND}
+	dev-qt/qtx11extras:5
+"
+BDEPEND="
+	dev-qt/linguist-tools:5
+"
+RDEPEND="${COMMON_DEPEND}
+	media-libs/ladspa-cmt
+	media-plugins/calf
+	media-plugins/caps-plugins
+	media-plugins/swh-plugins
+	media-plugins/tap-plugins
+"
+
+DOCS=( README.md doc/AUTHORS )
+
+src_configure() {
+	local mycmakeargs+=(
+		-DUSE_WERROR=FALSE
+		-DWANT_CAPS=FALSE
+		-DWANT_TAP=FALSE
+		-DWANT_SWH=FALSE
+		-DWANT_CMT=FALSE
+		-DWANT_CALF=FALSE
+		-DWANT_QT5=TRUE
+		-DWANT_ALSA=$(usex alsa)
+		-DWANT_JACK=$(usex jack)
+		-DWANT_GIG=$(usex libgig)
+		-DWANT_MP3LAME=$(usex mp3)
+		-DWANT_OGGVORBIS=$(usex ogg)
+		-DWANT_PORTAUDIO=$(usex portaudio)
+		-DWANT_PULSEAUDIO=$(usex pulseaudio)
+		-DWANT_SDL=$(usex sdl)
+		-DWANT_SOUNDIO=$(usex soundio)
+		-DWANT_STK=$(usex stk)
+		-DWANT_VST=$(usex vst)
+		-DWANT_SF2=$(usex fluidsynth)
+	)
+	cmake-utils_src_configure
+}
+
+pkg_preinst() {
+	xdg_pkg_preinst
+}
+
+pkg_postinst() {
+	xdg_pkg_postinst
+}
+
+pkg_postrm() {
+	xdg_pkg_postrm
+}