From mboxrd@z Thu Jan 1 00:00:00 1970
Return-Path: <gentoo-commits+bounces-1092946-garchives=archives.gentoo.org@lists.gentoo.org>
Received: from lists.gentoo.org (pigeon.gentoo.org [208.92.234.80])
(using TLSv1.2 with cipher ECDHE-RSA-AES256-GCM-SHA384 (256/256 bits))
(No client certificate requested)
by finch.gentoo.org (Postfix) with ESMTPS id 73E5A138334
for <garchives@archives.gentoo.org>; Sun, 26 May 2019 09:19:00 +0000 (UTC)
Received: from pigeon.gentoo.org (localhost [127.0.0.1])
by pigeon.gentoo.org (Postfix) with SMTP id 66C98E07B3;
Sun, 26 May 2019 09:18:59 +0000 (UTC)
Received: from smtp.gentoo.org (dev.gentoo.org [IPv6:2001:470:ea4a:1:5054:ff:fec7:86e4])
(using TLSv1.2 with cipher ECDHE-RSA-AES128-GCM-SHA256 (128/128 bits))
(No client certificate requested)
by pigeon.gentoo.org (Postfix) with ESMTPS id 3B0A4E07B3
for <gentoo-commits@lists.gentoo.org>; Sun, 26 May 2019 09:18:58 +0000 (UTC)
Received: from oystercatcher.gentoo.org (unknown [IPv6:2a01:4f8:202:4333:225:90ff:fed9:fc84])
(using TLSv1.2 with cipher ECDHE-RSA-AES128-GCM-SHA256 (128/128 bits))
(No client certificate requested)
by smtp.gentoo.org (Postfix) with ESMTPS id 765B9345001
for <gentoo-commits@lists.gentoo.org>; Sun, 26 May 2019 09:18:57 +0000 (UTC)
Received: from localhost.localdomain (localhost [IPv6:::1])
by oystercatcher.gentoo.org (Postfix) with ESMTP id B11E359F
for <gentoo-commits@lists.gentoo.org>; Sun, 26 May 2019 09:18:55 +0000 (UTC)
From: "Andreas Sturmlechner" <asturm@gentoo.org>
To: gentoo-commits@lists.gentoo.org
Content-Transfer-Encoding: 8bit
Content-type: text/plain; charset=UTF-8
Reply-To: gentoo-dev@lists.gentoo.org, "Andreas Sturmlechner" <asturm@gentoo.org>
Message-ID: <1558862322.b4528a4db4ecb6a925e5c7d8a3fa4fc7620fd5a7.asturm@gentoo>
Subject: [gentoo-commits] repo/gentoo:master commit in: app-text/poppler/
X-VCS-Repository: repo/gentoo
X-VCS-Files: app-text/poppler/Manifest app-text/poppler/poppler-0.77.0.ebuild
X-VCS-Directories: app-text/poppler/
X-VCS-Committer: asturm
X-VCS-Committer-Name: Andreas Sturmlechner
X-VCS-Revision: b4528a4db4ecb6a925e5c7d8a3fa4fc7620fd5a7
X-VCS-Branch: master
Date: Sun, 26 May 2019 09:18:55 +0000 (UTC)
Precedence: bulk
List-Post: <mailto:gentoo-commits@lists.gentoo.org>
List-Help: <mailto:gentoo-commits+help@lists.gentoo.org>
List-Unsubscribe: <mailto:gentoo-commits+unsubscribe@lists.gentoo.org>
List-Subscribe: <mailto:gentoo-commits+subscribe@lists.gentoo.org>
List-Id: Gentoo Linux mail <gentoo-commits.gentoo.org>
X-BeenThere: gentoo-commits@lists.gentoo.org
X-Auto-Response-Suppress: DR, RN, NRN, OOF, AutoReply
X-Archives-Salt: 607c5d5b-0fa0-41ff-9fc6-478e159c5c6f
X-Archives-Hash: 38b6a4e9c61c0141619ec6f56da42ae3
commit: b4528a4db4ecb6a925e5c7d8a3fa4fc7620fd5a7
Author: Andreas Sturmlechner <asturm <AT> gentoo <DOT> org>
AuthorDate: Sat May 25 22:12:24 2019 +0000
Commit: Andreas Sturmlechner <asturm <AT> gentoo <DOT> org>
CommitDate: Sun May 26 09:18:42 2019 +0000
URL: https://gitweb.gentoo.org/repo/gentoo.git/commit/?id=b4528a4d
app-text/poppler: 0.77.0 version bump
Package-Manager: Portage-2.3.66, Repoman-2.3.12
Signed-off-by: Andreas Sturmlechner <asturm <AT> gentoo.org>
app-text/poppler/Manifest | 1 +
app-text/poppler/poppler-0.77.0.ebuild | 127 +++++++++++++++++++++++++++++++++
2 files changed, 128 insertions(+)
diff --git a/app-text/poppler/Manifest b/app-text/poppler/Manifest
index 50847da3eec..4b01c655f14 100644
--- a/app-text/poppler/Manifest
+++ b/app-text/poppler/Manifest
@@ -1,2 +1,3 @@
DIST poppler-0.74.0.tar.xz 1514044 BLAKE2B af3821d5a5c68a3f2541cd9468fd7318ad0182cda66cea068dc42208fef6c2af78a401e50a6a5906cdc943de7339620937ddc6f69f0d8d1b15082aabc6cc3482 SHA512 4e48e2ffb559863ee693930db3b8594fd7e60e4b4ca3cdeb198faf90a6f4dbb5e102461492a12058221bc1218fe7e17c9085afb9e7956ae4bf26c11674315e66
DIST poppler-0.76.1.tar.xz 1531548 BLAKE2B edbd9c1be99aadf4f14608a1e0dc58a2fed351b10e18aa3c006f4e54cf0f2082deaded9c67a0181bb0f012bcbc550f1208e8a632df9cbe26261b735ca44cde60 SHA512 e4af2785948ecc89c105ab00269b0072b33feea25224e5beb158d515b1de789f979084bed2d4260c9659382cf437c25c0baf2444f5b4fbbba5c58afeb707b7ac
+DIST poppler-0.77.0.tar.xz 1533068 BLAKE2B 9ce7db05bd9d0131f643096b84058e67ba416b34497af5e97c9b6f404131fc72c29ac05e60b77477d16e586df73b306e4a01c113be7ede0cf3956240db889a7f SHA512 7c82cf584541fcbfa7cecdb06be9c4ba6d03479fc248377b874afeab561eac24015915eee566edc35fafe785b9f381f492c1789c070e67a2c1b344879c156040
diff --git a/app-text/poppler/poppler-0.77.0.ebuild b/app-text/poppler/poppler-0.77.0.ebuild
new file mode 100644
index 00000000000..929d23b313b
--- /dev/null
+++ b/app-text/poppler/poppler-0.77.0.ebuild
@@ -0,0 +1,127 @@
+# Copyright 1999-2019 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=7
+
+inherit cmake-utils flag-o-matic toolchain-funcs xdg-utils
+
+if [[ ${PV} == *9999* ]] ; then
+ inherit git-r3
+ EGIT_REPO_URI="https://anongit.freedesktop.org/git/poppler/poppler.git"
+ SLOT="0/9999"
+else
+ SRC_URI="https://poppler.freedesktop.org/${P}.tar.xz"
+ KEYWORDS="~alpha ~amd64 ~arm ~arm64 ~hppa ~ia64 ~mips ~ppc ~ppc64 ~s390 ~sh ~sparc ~x86 ~amd64-fbsd ~x86-fbsd ~amd64-linux ~x86-linux ~ppc-macos ~x64-macos ~x86-macos ~sparc-solaris ~sparc64-solaris ~x64-solaris ~x86-solaris"
+ SLOT="0/88" # CHECK THIS WHEN BUMPING!!! SUBSLOT IS libpoppler.so SOVERSION
+fi
+
+DESCRIPTION="PDF rendering library based on the xpdf-3.0 code base"
+HOMEPAGE="https://poppler.freedesktop.org/"
+
+LICENSE="GPL-2"
+IUSE="cairo cjk curl cxx debug doc +introspection +jpeg +jpeg2k +lcms nss png qt5 tiff +utils"
+
+# No test data provided
+RESTRICT="test"
+
+BDEPEND="
+ dev-util/glib-utils
+ virtual/pkgconfig
+"
+DEPEND="
+ media-libs/fontconfig
+ media-libs/freetype
+ sys-libs/zlib
+ cairo? (
+ dev-libs/glib:2
+ x11-libs/cairo
+ introspection? ( dev-libs/gobject-introspection:= )
+ )
+ curl? ( net-misc/curl )
+ jpeg? ( virtual/jpeg:0 )
+ jpeg2k? ( >=media-libs/openjpeg-2.3.0-r1:2= )
+ lcms? ( media-libs/lcms:2 )
+ nss? ( >=dev-libs/nss-3.19:0 )
+ png? ( media-libs/libpng:0= )
+ qt5? (
+ dev-qt/qtcore:5
+ dev-qt/qtgui:5
+ dev-qt/qtxml:5
+ )
+ tiff? ( media-libs/tiff:0 )
+"
+RDEPEND="${DEPEND}
+ cjk? ( app-text/poppler-data )
+"
+
+DOCS=( AUTHORS NEWS README README-XPDF )
+
+PATCHES=(
+ "${FILESDIR}/${PN}-0.60.1-qt5-dependencies.patch"
+ "${FILESDIR}/${PN}-0.28.1-fix-multilib-configuration.patch"
+ "${FILESDIR}/${PN}-0.71.0-respect-cflags.patch"
+ "${FILESDIR}/${PN}-0.61.0-respect-cflags.patch"
+ "${FILESDIR}/${PN}-0.57.0-disable-internal-jpx.patch"
+)
+
+src_prepare() {
+ cmake-utils_src_prepare
+
+ # Clang doesn't grok this flag, the configure nicely tests that, but
+ # cmake just uses it, so remove it if we use clang
+ if [[ ${CC} == clang ]] ; then
+ sed -e 's/-fno-check-new//' -i cmake/modules/PopplerMacros.cmake || die
+ fi
+
+ if ! grep -Fq 'cmake_policy(SET CMP0002 OLD)' CMakeLists.txt ; then
+ sed -e '/^cmake_minimum_required/acmake_policy(SET CMP0002 OLD)' \
+ -i CMakeLists.txt || die
+ else
+ einfo "policy(SET CMP0002 OLD) - workaround can be removed"
+ fi
+
+ # we need to up the C++ version, bug #622526, #643278
+ append-cxxflags -std=c++11
+}
+
+src_configure() {
+ xdg_environment_reset
+ local mycmakeargs=(
+ -DBUILD_GTK_TESTS=OFF
+ -DBUILD_QT5_TESTS=OFF
+ -DBUILD_CPP_TESTS=OFF
+ -DENABLE_SPLASH=ON
+ -DENABLE_ZLIB=ON
+ -DENABLE_ZLIB_UNCOMPRESS=OFF
+ -DENABLE_UNSTABLE_API_ABI_HEADERS=ON
+ -DSPLASH_CMYK=OFF
+ -DUSE_FIXEDPOINT=OFF
+ -DUSE_FLOAT=OFF
+ -DWITH_Cairo=$(usex cairo)
+ -DENABLE_LIBCURL=$(usex curl)
+ -DENABLE_CPP=$(usex cxx)
+ -DWITH_JPEG=$(usex jpeg)
+ -DENABLE_DCTDECODER=$(usex jpeg libjpeg none)
+ -DENABLE_LIBOPENJPEG=$(usex jpeg2k openjpeg2 none)
+ -DENABLE_CMS=$(usex lcms lcms2 none)
+ -DWITH_NSS3=$(usex nss)
+ -DWITH_PNG=$(usex png)
+ $(cmake-utils_use_find_package qt5 Qt5Core)
+ -DWITH_TIFF=$(usex tiff)
+ -DENABLE_UTILS=$(usex utils)
+ )
+ use cairo && mycmakeargs+=( -DWITH_GObjectIntrospection=$(usex introspection) )
+
+ cmake-utils_src_configure
+}
+
+src_install() {
+ cmake-utils_src_install
+
+ # live version doesn't provide html documentation
+ if use cairo && use doc && [[ ${PV} != *9999* ]]; then
+ # For now install gtk-doc there
+ insinto /usr/share/gtk-doc/html/poppler
+ doins -r "${S}"/glib/reference/html/*
+ fi
+}