[gentoo-commits] repo/gentoo:master commit in: sci-libs/libgeotiff/

["Andreas Sturmlechner" <asturm@gentoo.org>]

commit:     87e21d26aa928c01dddfcf6f2bc17a5c9844c62d
Author:     Andreas Sturmlechner <asturm <AT> gentoo <DOT> org>
AuthorDate: Fri May 24 18:41:57 2019 +0000
Commit:     Andreas Sturmlechner <asturm <AT> gentoo <DOT> org>
CommitDate: Fri May 24 19:25:45 2019 +0000
URL:        https://gitweb.gentoo.org/repo/gentoo.git/commit/?id=87e21d26

sci-libs/libgeotiff: EAPI-7 bump, missing subslot, fix >=proj-6 DEPEND

Fix HOMEPAGE
Sort DEPENDs

Closes: https://bugs.gentoo.org/685476
Package-Manager: Portage-2.3.66, Repoman-2.3.12
Signed-off-by: Andreas Sturmlechner <asturm <AT> gentoo.org>

 sci-libs/libgeotiff/libgeotiff-1.5.1-r1.ebuild | 58 ++++++++++++++++++++++++++
 1 file changed, 58 insertions(+)

diff --git a/sci-libs/libgeotiff/libgeotiff-1.5.1-r1.ebuild b/sci-libs/libgeotiff/libgeotiff-1.5.1-r1.ebuild
new file mode 100644
index 00000000000..7696605edc4
--- /dev/null
+++ b/sci-libs/libgeotiff/libgeotiff-1.5.1-r1.ebuild
@@ -0,0 +1,58 @@
+# Copyright 1999-2019 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=7
+
+inherit autotools
+
+DESCRIPTION="Library for reading TIFF files with embedded tags for geographic information"
+HOMEPAGE="https://trac.osgeo.org/geotiff/ https://github.com/OSGeo/libgeotiff"
+SRC_URI="https://download.osgeo.org/geotiff/${PN}/${P}.tar.gz"
+
+LICENSE="GPL-2"
+SLOT="0/5"
+KEYWORDS="~amd64 ~arm ~arm64 ~ia64 ~ppc ~ppc64 ~x86 ~amd64-linux ~x86-linux ~ppc-macos ~x64-macos ~x86-macos"
+IUSE="debug doc static-libs"
+
+BDEPEND="
+	doc? ( app-doc/doxygen )
+"
+DEPEND="
+	>=media-libs/tiff-3.9.1:0
+	>=sci-libs/proj-6.0.0
+	sys-libs/zlib
+	virtual/jpeg:=
+"
+RDEPEND="${DEPEND}"
+
+src_prepare() {
+	default
+	sed -e "s:-O3::g" -i configure.ac || die
+	eautoreconf
+}
+
+src_configure() {
+	econf \
+		--enable-debug=$(usex debug) \
+		$(use_enable static-libs static) \
+		--with-jpeg="${EPREFIX}"/usr/ \
+		--with-zip="${EPREFIX}"/usr/
+
+}
+
+src_compile() {
+	default
+
+	if use doc; then
+		mkdir -p docs/api || die
+		cp "${FILESDIR}"/Doxyfile Doxyfile || die
+		doxygen -u Doxyfile || die "updating doxygen config failed"
+		doxygen Doxyfile || die "docs generation failed"
+	fi
+}
+
+src_install() {
+	use doc && local HTML_DOCS=( docs/api/. )
+	default
+	find "${D}" -name '*.la' -type f -delete || die
+}