[gentoo-commits] repo/gentoo:master commit in: sys-auth/ykpers/

["Lars Wendler" <polynomial-c@gentoo.org>]

commit:     82a86ba7b8a7e4395cb979869b11c85dcfdcc01c
Author:     Lars Wendler <polynomial-c <AT> gentoo <DOT> org>
AuthorDate: Thu May 16 08:31:15 2019 +0000
Commit:     Lars Wendler <polynomial-c <AT> gentoo <DOT> org>
CommitDate: Thu May 16 08:32:29 2019 +0000
URL:        https://gitweb.gentoo.org/repo/gentoo.git/commit/?id=82a86ba7

sys-auth/ykpers: Added elogind USE flag.

Bumped ebuild to EAPI-7

Closes: https://bugs.gentoo.org/686014
Package-Manager: Portage-2.3.66, Repoman-2.3.12
Signed-off-by: Lars Wendler <polynomial-c <AT> gentoo.org>

 sys-auth/ykpers/ykpers-1.19.3.ebuild | 32 ++++++++++++++++++++++----------
 1 file changed, 22 insertions(+), 10 deletions(-)

diff --git a/sys-auth/ykpers/ykpers-1.19.3.ebuild b/sys-auth/ykpers/ykpers-1.19.3.ebuild
index 1996fb57cb4..a014641d7eb 100644
--- a/sys-auth/ykpers/ykpers-1.19.3.ebuild
+++ b/sys-auth/ykpers/ykpers-1.19.3.ebuild
@@ -1,7 +1,7 @@
 # Copyright 1999-2019 Gentoo Authors
 # Distributed under the terms of the GNU General Public License v2
 
-EAPI=6
+EAPI=7
 
 inherit autotools udev
 
@@ -12,17 +12,21 @@ HOMEPAGE="https://github.com/Yubico/yubikey-personalization"
 KEYWORDS="~amd64 ~x86"
 SLOT="0"
 LICENSE="BSD-2"
-IUSE="static-libs consolekit"
+IUSE="consolekit elogind static-libs"
 
-RDEPEND="
+DEPEND="
 	dev-libs/json-c:=
 	>=sys-auth/libyubikey-1.6
 	virtual/libusb:1"
-DEPEND="${RDEPEND}
+BDEPEND="
 	app-text/asciidoc
 	virtual/pkgconfig"
-RDEPEND="${RDEPEND}
-	consolekit? ( sys-auth/consolekit[acl] )"
+RDEPEND="${DEPEND}
+	consolekit? ( sys-auth/consolekit[acl] )
+	elogind? ( sys-auth/elogind[acl] )
+"
+
+REQUIRED_USE="^^ ( consolekit elogind )"
 
 S="${WORKDIR}/yubikey-personalization-${PV}"
 
@@ -31,18 +35,26 @@ DOCS=( doc/. AUTHORS NEWS README )
 src_prepare() {
 	default
 	eautoreconf
+
+	if use elogind ; then
+		sed '/TEST==/d' -i 70-yubikey.rules || die
+	fi
 }
 
 src_configure() {
-	econf \
-		--libdir=/usr/$(get_libdir) \
-		--localstatedir=/var \
+	local myeconfargs=(
+		--libdir=/usr/$(get_libdir)
+		--localstatedir=/var
 		$(use_enable static-libs static)
+	)
+	econf "${myeconfargs[@]}"
 }
 
 src_install() {
 	default
-	use consolekit && udev_dorules *.rules
+	if use consolekit || use elogind ; then
+		udev_dorules *.rules
+	fi
 
 	find "${D}" -name '*.la' -delete || die
 }