[gentoo-commits] repo/gentoo:master commit in: media-sound/qmmp/

["Andreas Sturmlechner" <asturm@gentoo.org>]

commit:     7a1a0fa0ea07bdb2dcc520888b9fada67b0da907
Author:     Andreas Sturmlechner <asturm <AT> gentoo <DOT> org>
AuthorDate: Sun May  5 19:06:15 2019 +0000
Commit:     Andreas Sturmlechner <asturm <AT> gentoo <DOT> org>
CommitDate: Wed May  8 17:03:33 2019 +0000
URL:        https://gitweb.gentoo.org/repo/gentoo.git/commit/?id=7a1a0fa0

media-sound/qmmp: 1.3.2 version bump

Package-Manager: Portage-2.3.66, Repoman-2.3.12
Signed-off-by: Andreas Sturmlechner <asturm <AT> gentoo.org>

 media-sound/qmmp/Manifest          |   1 +
 media-sound/qmmp/qmmp-1.3.2.ebuild | 168 +++++++++++++++++++++++++++++++++++++
 2 files changed, 169 insertions(+)

diff --git a/media-sound/qmmp/Manifest b/media-sound/qmmp/Manifest
index e64dab77584..cb91ce18e3e 100644
--- a/media-sound/qmmp/Manifest
+++ b/media-sound/qmmp/Manifest
@@ -1,3 +1,4 @@
 DIST qmmp-1.2.6.tar.bz2 1181291 BLAKE2B fb039d8abcc0e2c6e2e1aa64c603f1f8b81858c48332eaa480d9d71e77958af52352772394fe5c22be653fcb01bc2acc44011e5cf30ab38863f2a2deca6c0ef2 SHA512 c816f530a7b4dabfbe327f4c726c3412c8c22bc9713a288df0f0b405d9831f4958be01b3f9abd35818e54f03e5568eb79cec85bf154ac9ed8075c0bf3fd5a442
 DIST qmmp-1.3.0.tar.bz2 1220426 BLAKE2B 0a64b36876ed672c380c097897aa69f6d44f9d5fc7fdc2006ece63c91438fc72f3df67cf4c63d17dab526d8e67c45593b035df0e1ccfc1c179824807637aa812 SHA512 e91dc40ca8e96c1a5527ca73443e192bb8f2198a449f46911894b0e2779011766b2c6fd3b1786d2fbe3d87ccc7ee6b987ece0a3260144981bb74b96b3b7c3bb3
 DIST qmmp-1.3.1.tar.bz2 1221322 BLAKE2B ab0a4ecf5746926f2778a99d076f2756883621a4962f8f78a57d5eacb9977def9e8c3d186576715735763d991e6ee88d1ecd6f02e601a4b302ccd7ddf4176866 SHA512 936928bbe058253dc8cf95fb17b5ba840b3b51240d68ed9fefe4f09fd918d0908d1fc7ec816b7b08386c3da72fe78da73316e36b1b52018017d2a23fd8275556
+DIST qmmp-1.3.2.tar.bz2 1221919 BLAKE2B 3081aa6b3ef4712ea064d5bb23e9ac7da5e102fde820c378438c13723bd007fe8e79ac351b0ad01ca0aa22c50f6b6773965ce418742cf1386d2ae1d7ba7b1758 SHA512 5c68d87650abf10d03dc8638df73a6694e470af1121a936bb983bcbcea04d95616ad8a55d87e8874b51b7424a890dad2c5353afe65db7029f6513a382e2144e4

diff --git a/media-sound/qmmp/qmmp-1.3.2.ebuild b/media-sound/qmmp/qmmp-1.3.2.ebuild
new file mode 100644
index 00000000000..611727b19b0
--- /dev/null
+++ b/media-sound/qmmp/qmmp-1.3.2.ebuild
@@ -0,0 +1,168 @@
+# Copyright 1999-2019 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=7
+
+inherit cmake-utils xdg-utils
+[[ ${PV} = 9999 ]] && inherit subversion
+
+DESCRIPTION="Qt5-based audio player with winamp/xmms skins support"
+HOMEPAGE="http://qmmp.ylsoftware.com"
+if [[ ${PV} != 9999 ]]; then
+	SRC_URI="http://qmmp.ylsoftware.com/files/${P}.tar.bz2
+		mirror://sourceforge/${PN}-dev/files/${P}.tar.bz2"
+	KEYWORDS="~amd64 ~x86"
+else
+	QMMP_DEV_BRANCH="1.2"
+	ESVN_REPO_URI="svn://svn.code.sf.net/p/${PN}-dev/code/branches/${PN}-${QMMP_DEV_BRANCH}"
+fi
+
+LICENSE="GPL-2"
+SLOT="0"
+# KEYWORDS further up
+IUSE="aac +alsa analyzer archive bs2b cdda cover crossfade cue curl +dbus enca ffmpeg flac game
+gnome jack ladspa libav lyrics +mad midi mms modplug mplayer musepack notifier opus oss projectm
+pulseaudio qsui qtmedia scrobbler shout sid sndfile soxr stereo tray udisks +vorbis wavpack"
+
+REQUIRED_USE="
+	gnome? ( dbus )
+	shout? ( soxr vorbis )
+	udisks? ( dbus )
+"
+
+RDEPEND="
+	dev-qt/qtcore:5
+	dev-qt/qtgui:5
+	dev-qt/qtnetwork:5
+	dev-qt/qtsql:5
+	dev-qt/qtwidgets:5
+	dev-qt/qtx11extras:5
+	media-libs/taglib
+	x11-libs/libX11
+	aac? ( media-libs/faad2 )
+	alsa? ( media-libs/alsa-lib )
+	archive? ( app-arch/libarchive )
+	bs2b? ( media-libs/libbs2b )
+	cdda? (
+		dev-libs/libcdio:=
+		dev-libs/libcdio-paranoia
+	)
+	cue? ( media-libs/libcue )
+	curl? ( net-misc/curl )
+	dbus? ( dev-qt/qtdbus:5 )
+	enca? ( app-i18n/enca )
+	ffmpeg? (
+		!libav? ( media-video/ffmpeg:= )
+		libav? ( media-video/libav:= )
+	)
+	flac? ( media-libs/flac )
+	game? ( media-libs/game-music-emu )
+	jack? (
+		media-libs/libsamplerate
+		media-sound/jack-audio-connection-kit
+	)
+	ladspa? ( media-libs/ladspa-cmt )
+	mad? ( || (
+		media-libs/libmad
+		media-sound/mpg123
+	) )
+	midi? ( media-sound/wildmidi )
+	mms? ( media-libs/libmms )
+	modplug? ( >=media-libs/libmodplug-0.8.4 )
+	mplayer? ( media-video/mplayer )
+	musepack? ( >=media-sound/musepack-tools-444 )
+	opus? ( media-libs/opusfile )
+	projectm? (
+		dev-qt/qtgui:5[-gles2]
+		dev-qt/qtopengl:5
+		media-libs/libprojectm
+	)
+	pulseaudio? ( >=media-sound/pulseaudio-0.9.9 )
+	qtmedia? ( dev-qt/qtmultimedia:5 )
+	scrobbler? ( net-misc/curl )
+	shout? ( media-libs/libshout )
+	sid? ( >=media-libs/libsidplayfp-1.1.0 )
+	sndfile? ( media-libs/libsndfile )
+	soxr? ( media-libs/soxr )
+	udisks? ( sys-fs/udisks:2 )
+	vorbis? (
+		media-libs/libogg
+		media-libs/libvorbis
+	)
+	wavpack? ( media-sound/wavpack )
+"
+DEPEND="${RDEPEND}
+	dev-qt/linguist-tools:5
+"
+
+DOCS=( AUTHORS ChangeLog README )
+
+src_prepare() {
+	if has_version dev-libs/libcdio-paranoia; then
+		sed -i \
+			-e 's:cdio/cdda.h:cdio/paranoia/cdda.h:' \
+			src/plugins/Input/cdaudio/decoder_cdaudio.cpp || die
+	fi
+
+	cmake-utils_src_prepare
+}
+
+src_configure() {
+	local mycmakeargs=(
+		-DUSE_AAC="$(usex aac)"
+		-DUSE_ALSA="$(usex alsa)"
+		-DUSE_ANALYZER="$(usex analyzer)"
+		-DUSE_ARCHIVE="$(usex archive)"
+		-DUSE_BS2B="$(usex bs2b)"
+		-DUSE_CDA="$(usex cdda)"
+		-DUSE_COVER="$(usex cover)"
+		-DUSE_CROSSFADE="$(usex crossfade)"
+		-DUSE_CUE="$(usex cue)"
+		-DUSE_CURL="$(usex curl)"
+		-DUSE_KDENOTIFY="$(usex dbus)"
+		-DUSE_MPRIS="$(usex dbus)"
+		-DUSE_ENCA="$(usex enca)"
+		-DUSE_FFMPEG="$(usex ffmpeg)"
+		-DUSE_FILEWRITER="$(usex vorbis)"
+		-DUSE_FLAC="$(usex flac)"
+		-DUSE_GME="$(usex game)"
+		-DUSE_GNOMEHOTKEY="$(usex gnome)"
+		-DUSE_HAL=OFF
+		-DUSE_JACK="$(usex jack)"
+		-DUSE_LADSPA="$(usex ladspa)"
+		-DUSE_LYRICS="$(usex lyrics)"
+		-DUSE_MAD="$(usex mad)"
+		-DUSE_MIDI="$(usex midi)"
+		-DUSE_MMS="$(usex mms)"
+		-DUSE_MODPLUG="$(usex modplug)"
+		-DUSE_MPLAYER="$(usex mplayer)"
+		-DUSE_MPC="$(usex musepack)"
+		-DUSE_NOTIFIER="$(usex notifier)"
+		-DUSE_OPUS="$(usex opus)"
+		-DUSE_OSS="$(usex oss)"
+		-DUSE_PROJECTM="$(usex projectm)"
+		-DUSE_PULSE="$(usex pulseaudio)"
+		-DUSE_QSUI="$(usex qsui)"
+		-DUSE_QTMULTIMEDIA="$(usex qtmedia)"
+		-DUSE_SCROBBLER="$(usex scrobbler)"
+		-DUSE_SHOUT="$(usex shout)"
+		-DUSE_SID="$(usex sid)"
+		-DUSE_SNDFILE="$(usex sndfile)"
+		-DUSE_SOXR="$(usex soxr)"
+		-DUSE_STEREO="$(usex stereo)"
+		-DUSE_STATICON="$(usex tray)"
+		-DUSE_UDISKS2="$(usex udisks)"
+		-DUSE_VORBIS="$(usex vorbis)"
+		-DUSE_WAVPACK="$(usex wavpack)"
+	)
+
+	cmake-utils_src_configure
+}
+
+pkg_postinst() {
+	xdg_desktop_database_update
+}
+
+pkg_postrm() {
+	xdg_desktop_database_update
+}