[gentoo-commits] repo/gentoo:master commit in: net-misc/miniupnpd/

["Michał Górny" <mgorny@gentoo.org>]

commit:     c7c323c7dd48bcfdb65c692fbdc61d9919e3eca6
Author:     Michał Górny <mgorny <AT> gentoo <DOT> org>
AuthorDate: Fri May  3 06:52:24 2019 +0000
Commit:     Michał Górny <mgorny <AT> gentoo <DOT> org>
CommitDate: Fri May  3 07:15:37 2019 +0000
URL:        https://gitweb.gentoo.org/repo/gentoo.git/commit/?id=c7c323c7

net-misc/miniupnpd: Bump to 2.1.20190502

Signed-off-by: Michał Górny <mgorny <AT> gentoo.org>

 net-misc/miniupnpd/Manifest                      |  1 +
 net-misc/miniupnpd/miniupnpd-2.1.20190502.ebuild | 65 ++++++++++++++++++++++++
 2 files changed, 66 insertions(+)

diff --git a/net-misc/miniupnpd/Manifest b/net-misc/miniupnpd/Manifest
index c66ad667a8e..906d0cee55b 100644
--- a/net-misc/miniupnpd/Manifest
+++ b/net-misc/miniupnpd/Manifest
@@ -1 +1,2 @@
 DIST miniupnpd-2.1.20190408.tar.gz 235989 BLAKE2B cdfb4fe23a136d9a3e0cc91c174fc4f0ee0a3e136305a2ea6d21c358287f67d34009b37ba8870bef86e53d056e441b45e19a89939e72485051245b5d40b384ff SHA512 f812660c1f626f1fdbcaabd6636125cc18f1306bb4a3a29dae45c06017c97c681e3e056d602fe5444962ecc1aec4d39d9c203621bb11a3aa1f57cda6dc4f19de
+DIST miniupnpd-2.1.20190502.tar.gz 236052 BLAKE2B 9f2f81769d72fad2191969e0e80b4d2e70619d5674fe6b4ef9f4306e09ac4737577a2146bc04ec9960df092252abe3c9a57e32d5d893a763b85863d1c4892045 SHA512 6423cef89b5af62b6b6a120a3cd13a0e7755d609b33de8f1671f7f9160fb1b5e68b0ebd3f8b7b5758cf05a1c58b416cde253e37bc5ba0bb423c14b5fb44599f1

diff --git a/net-misc/miniupnpd/miniupnpd-2.1.20190502.ebuild b/net-misc/miniupnpd/miniupnpd-2.1.20190502.ebuild
new file mode 100644
index 00000000000..673b340fb09
--- /dev/null
+++ b/net-misc/miniupnpd/miniupnpd-2.1.20190502.ebuild
@@ -0,0 +1,65 @@
+# Copyright 1999-2019 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=7
+
+inherit toolchain-funcs
+
+DESCRIPTION="MiniUPnP IGD Daemon"
+HOMEPAGE="http://miniupnp.free.fr/"
+SRC_URI="http://miniupnp.free.fr/files/${P}.tar.gz"
+
+LICENSE="BSD"
+SLOT="0"
+KEYWORDS="~amd64 ~arm ~x86"
+IUSE="+leasefile igd2 ipv6 pcp-peer portinuse strict"
+
+RDEPEND=">=net-firewall/iptables-1.4.6:0=[ipv6?]
+	net-libs/libnfnetlink:=
+	net-libs/libmnl:=
+	dev-libs/gmp:0=
+	sys-apps/util-linux:=
+	dev-libs/openssl:0="
+DEPEND="${RDEPEND}
+	sys-apps/lsb-release"
+
+src_prepare() {
+	default
+	mv Makefile.linux Makefile || die
+
+	# Prevent gzipping manpage.
+	sed -i -e '/gzip/d' Makefile || die
+}
+
+src_configure() {
+	local -a opts
+	opts=(
+		--vendorcfg
+		$(usex igd2 '--igd2' '')
+		$(usex ipv6 '--ipv6' '')
+		$(usex leasefile '--leasefile' '')
+		$(usex portinuse '--portinuse' '')
+		$(usex pcp-peer '--pcp-peer' '')
+		$(usex strict '--strict' '')
+	)
+
+	emake CONFIG_OPTIONS="${opts[*]}" config.h
+}
+
+src_compile() {
+	# By default, it builds a bunch of unittests that are missing wrapper
+	# scripts in the tarball
+	emake CC="$(tc-getCC)" STRIP=true miniupnpd
+}
+
+src_install() {
+	emake PREFIX="${ED}" STRIP=true install
+
+	newinitd "${FILESDIR}"/${PN}-init.d-r1 ${PN}
+	newconfd "${FILESDIR}"/${PN}-conf.d-r1 ${PN}
+}
+
+pkg_postinst() {
+	elog "Please correct the external interface in the top of the two"
+	elog "scripts in /etc/miniupnpd and edit the config file in there too"
+}