[gentoo-commits] repo/gentoo:master commit in: app-text/libmwaw/

["Andreas Sturmlechner" <asturm@gentoo.org>]

commit:     964576cc2996298f8c4f547b103925503f3626b1
Author:     Andreas Sturmlechner <asturm <AT> gentoo <DOT> org>
AuthorDate: Mon Apr 22 10:59:25 2019 +0000
Commit:     Andreas Sturmlechner <asturm <AT> gentoo <DOT> org>
CommitDate: Mon Apr 22 16:33:43 2019 +0000
URL:        https://gitweb.gentoo.org/repo/gentoo.git/commit/?id=964576cc

app-text/libmwaw: 0.3.15 version bump

Package-Manager: Portage-2.3.64, Repoman-2.3.12
Signed-off-by: Andreas Sturmlechner <asturm <AT> gentoo.org>

 app-text/libmwaw/Manifest              |  1 +
 app-text/libmwaw/libmwaw-0.3.15.ebuild | 52 ++++++++++++++++++++++++++++++++++
 2 files changed, 53 insertions(+)

diff --git a/app-text/libmwaw/Manifest b/app-text/libmwaw/Manifest
index 9bcbbf81b78..1e862f10591 100644
--- a/app-text/libmwaw/Manifest
+++ b/app-text/libmwaw/Manifest
@@ -1 +1,2 @@
 DIST libmwaw-0.3.14.tar.xz 1276240 BLAKE2B 34a5b118064dcac37834c83b2b5a61303f3e2eb70e41322845ff7661a5494c0b85db0bb07c6bf1f357c2027cab1c515eade58bb6b4fdf845a81d4d079a414b98 SHA512 6893a7a8a72765a66973a94bc7de8b3b6061aa85fd9cca5e73cb2a4024cbe81f0c030df0b6383f24835643259c361efda5527813bb84a1b08d0089d509215888
+DIST libmwaw-0.3.15.tar.xz 1289744 BLAKE2B 9aed923542e795904761e4969299785906aa65c735541788d91eb41e80420ac6c6df4df5e0cfa156c71d4e100c601e5e984de10c6a5f66eebe6ffb5f0374cc1d SHA512 0b2443fc6bc9da9247f7585743424df440f89317af989018d8b972864bf91e3c5cd78c39094a45d9de8114906b2b2a93f68ddb967af8565e4b499f643d86e682

diff --git a/app-text/libmwaw/libmwaw-0.3.15.ebuild b/app-text/libmwaw/libmwaw-0.3.15.ebuild
new file mode 100644
index 00000000000..cc207bd575b
--- /dev/null
+++ b/app-text/libmwaw/libmwaw-0.3.15.ebuild
@@ -0,0 +1,52 @@
+# Copyright 1999-2019 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=7
+
+if [[ ${PV} = 9999 ]]; then
+	EGIT_REPO_URI="https://git.code.sf.net/p/libmwaw/libmwaw"
+	inherit autotools git-r3
+else
+	SRC_URI="mirror://sourceforge/${PN}/${P}.tar.xz"
+	KEYWORDS="~amd64 ~arm ~arm64 ~ppc64 ~x86"
+fi
+
+DESCRIPTION="Library parsing many pre-OSX MAC text formats"
+HOMEPAGE="https://sourceforge.net/p/libmwaw/wiki/Home/"
+
+LICENSE="LGPL-2.1"
+SLOT="0"
+IUSE="doc static-libs tools"
+
+BDEPEND="
+	sys-devel/libtool
+	virtual/pkgconfig
+	doc? ( app-doc/doxygen )
+"
+DEPEND="
+	dev-libs/librevenge
+	sys-libs/zlib
+"
+RDEPEND="${DEPEND}"
+
+src_prepare() {
+	default
+	[[ ${PV} == 9999 ]] && eautoreconf
+}
+
+src_configure() {
+	# zip is hard enabled as the zlib is dep on the rdeps anyway
+	local myeconfargs=(
+		--enable-zip
+		--disable-werror
+		$(use_with doc docs)
+		$(use_enable static-libs static)
+		$(use_enable tools)
+	)
+	econf "${myeconfargs[@]}"
+}
+
+src_install() {
+	default
+	find "${D}" -name '*.la' -delete || die
+}