[gentoo-commits] repo/gentoo:master commit in: app-misc/ckb/

["Andreas Sturmlechner" <asturm@gentoo.org>]

commit:     671e16c02dd58afb6bd8f41ab9f33a2b8f1f0466
Author:     Andreas Sturmlechner <asturm <AT> gentoo <DOT> org>
AuthorDate: Mon Apr 22 09:47:30 2019 +0000
Commit:     Andreas Sturmlechner <asturm <AT> gentoo <DOT> org>
CommitDate: Mon Apr 22 10:41:21 2019 +0000
URL:        https://gitweb.gentoo.org/repo/gentoo.git/commit/?id=671e16c0

app-misc/ckb: EAPI-7 bump, missing desktop.eclass, missing DEPENDs

Package-Manager: Portage-2.3.64, Repoman-2.3.12
Signed-off-by: Andreas Sturmlechner <asturm <AT> gentoo.org>

 app-misc/ckb/ckb-0.2.9-r1.ebuild | 53 ++++++++++++++++++++++++++++++++++++++++
 1 file changed, 53 insertions(+)

diff --git a/app-misc/ckb/ckb-0.2.9-r1.ebuild b/app-misc/ckb/ckb-0.2.9-r1.ebuild
new file mode 100644
index 00000000000..a0d3d2a09f0
--- /dev/null
+++ b/app-misc/ckb/ckb-0.2.9-r1.ebuild
@@ -0,0 +1,53 @@
+# Copyright 1999-2019 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=7
+
+inherit desktop qmake-utils systemd
+
+DESCRIPTION="Corsair K65/K70/K95 Driver"
+HOMEPAGE="https://github.com/ckb-next/ckb-next"
+SRC_URI="https://github.com/ckb-next/ckb-next/archive/v${PV}.tar.gz -> ${P}.tar.gz"
+
+LICENSE="GPL-2"
+SLOT="0"
+KEYWORDS="~amd64"
+IUSE=""
+
+DEPEND="
+	>=dev-libs/quazip-0.7.2[qt5(+)]
+	dev-qt/qtcore:5
+	dev-qt/qtgui:5
+	dev-qt/qtnetwork:5
+	dev-qt/qtwidgets:5
+	virtual/libudev:=
+	x11-libs/libX11
+"
+RDEPEND="${DEPEND}"
+
+DOCS=( README.md BUILD.md DAEMON.md )
+
+S="${WORKDIR}/${PN}-next-${PV}"
+
+src_prepare() {
+	default
+	sed -i -e "s/-Werror=all//" src/ckb-daemon/ckb-daemon.pro || die
+	sed -i -e "/quazip/d" -e "s/^.*QUAZIP_STATIC/LIBS += -lquazip5/" src/ckb/ckb.pro || die
+	sed -i -e "s#/usr/lib#/usr/libexec#" src/ckb/animscript.cpp || die
+}
+
+src_configure() {
+	eqmake5
+}
+
+src_install() {
+	dobin bin/ckb bin/ckb-daemon
+	dodir /usr/bin/ckb-animations
+	exeinto /usr/libexec/ckb-animations
+	doexe bin/ckb-animations/*
+
+	newinitd "${FILESDIR}"/ckb.initd ckb-daemon
+	domenu usr/ckb.desktop
+	doicon usr/ckb.png
+	systemd_dounit service/systemd/ckb-daemon.service
+}