[gentoo-commits] repo/gentoo:master commit in: app-text/pinfo/

["Jeroen Roovers" <jer@gentoo.org>]

commit:     02bb742670d3141621b46bb67a2112b4ad1d6cbc
Author:     Jeroen Roovers <jer <AT> gentoo <DOT> org>
AuthorDate: Sun Apr 21 17:27:42 2019 +0000
Commit:     Jeroen Roovers <jer <AT> gentoo <DOT> org>
CommitDate: Sun Apr 21 17:28:06 2019 +0000
URL:        https://gitweb.gentoo.org/repo/gentoo.git/commit/?id=02bb7426

app-text/pinfo: Add live ebuild

Package-Manager: Portage-2.3.64, Repoman-2.3.12
Signed-off-by: Jeroen Roovers <jer <AT> gentoo.org>

 app-text/pinfo/pinfo-99999.ebuild | 49 +++++++++++++++++++++++++++++++++++++++
 1 file changed, 49 insertions(+)

diff --git a/app-text/pinfo/pinfo-99999.ebuild b/app-text/pinfo/pinfo-99999.ebuild
new file mode 100644
index 00000000000..961b78a24b4
--- /dev/null
+++ b/app-text/pinfo/pinfo-99999.ebuild
@@ -0,0 +1,49 @@
+# Copyright 1999-2019 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=7
+inherit autotools flag-o-matic git-r3
+
+DESCRIPTION="Hypertext info and man viewer based on (n)curses"
+HOMEPAGE="https://github.com/baszoetekouw/pinfo"
+EGIT_REPO_URI="${HOMEPAGE}"
+
+LICENSE="GPL-2"
+SLOT="0"
+KEYWORDS=""
+IUSE="nls readline"
+
+RDEPEND="
+	sys-libs/ncurses:0=
+	sys-libs/readline:0=
+	nls? ( virtual/libintl )
+"
+
+DEPEND="
+	${RDEPEND}
+	sys-apps/texinfo
+	sys-devel/bison
+	virtual/pkgconfig
+	nls? ( sys-devel/gettext )
+"
+PATCHES=(
+	"${FILESDIR}"/${PN}-0.6.9-GROFF_NO_SGR.patch
+	"${FILESDIR}"/${PN}-0.6.9-lzma-xz.patch
+)
+
+src_prepare() {
+	default
+	eautoreconf
+}
+
+src_configure() {
+	append-cflags -D_BSD_SOURCE -D_DEFAULT_SOURCE # sbrk()
+
+	econf \
+		$(use_with readline) \
+		$(use_enable nls)
+}
+
+src_install() {
+	emake DESTDIR="${D}" sysconfdir="${EPREFIX}/etc" install
+}