From mboxrd@z Thu Jan  1 00:00:00 1970
Return-Path: <gentoo-commits+bounces-1081543-garchives=archives.gentoo.org@lists.gentoo.org>
Received: from lists.gentoo.org (pigeon.gentoo.org [208.92.234.80])
	(using TLSv1.2 with cipher ECDHE-RSA-AES256-GCM-SHA384 (256/256 bits))
	(No client certificate requested)
	by finch.gentoo.org (Postfix) with ESMTPS id 71804138334
	for <garchives@archives.gentoo.org>; Sat,  6 Apr 2019 20:34:45 +0000 (UTC)
Received: from pigeon.gentoo.org (localhost [127.0.0.1])
	by pigeon.gentoo.org (Postfix) with SMTP id 5FEACE0891;
	Sat,  6 Apr 2019 20:34:42 +0000 (UTC)
Received: from smtp.gentoo.org (smtp.gentoo.org [140.211.166.183])
	(using TLSv1.2 with cipher ECDHE-RSA-AES128-GCM-SHA256 (128/128 bits))
	(No client certificate requested)
	by pigeon.gentoo.org (Postfix) with ESMTPS id 23BDCE0891
	for <gentoo-commits@lists.gentoo.org>; Sat,  6 Apr 2019 20:34:42 +0000 (UTC)
Received: from oystercatcher.gentoo.org (unknown [IPv6:2a01:4f8:202:4333:225:90ff:fed9:fc84])
	(using TLSv1.2 with cipher ECDHE-RSA-AES128-GCM-SHA256 (128/128 bits))
	(No client certificate requested)
	by smtp.gentoo.org (Postfix) with ESMTPS id C24FA335D0D
	for <gentoo-commits@lists.gentoo.org>; Sat,  6 Apr 2019 20:34:40 +0000 (UTC)
Received: from localhost.localdomain (localhost [IPv6:::1])
	by oystercatcher.gentoo.org (Postfix) with ESMTP id B230459A
	for <gentoo-commits@lists.gentoo.org>; Sat,  6 Apr 2019 20:34:36 +0000 (UTC)
From: "Andreas Sturmlechner" <asturm@gentoo.org>
To: gentoo-commits@lists.gentoo.org
Content-Transfer-Encoding: 8bit
Content-type: text/plain; charset=UTF-8
Reply-To: gentoo-dev@lists.gentoo.org, "Andreas Sturmlechner" <asturm@gentoo.org>
Message-ID: <1554582537.14862339c3b72e18d39b1567eda637081ef9aa94.asturm@gentoo>
Subject: [gentoo-commits] repo/gentoo:master commit in: media-video/obs-studio/
X-VCS-Repository: repo/gentoo
X-VCS-Files: media-video/obs-studio/Manifest media-video/obs-studio/obs-studio-23.1.0.ebuild
X-VCS-Directories: media-video/obs-studio/
X-VCS-Committer: asturm
X-VCS-Committer-Name: Andreas Sturmlechner
X-VCS-Revision: 14862339c3b72e18d39b1567eda637081ef9aa94
X-VCS-Branch: master
Date: Sat,  6 Apr 2019 20:34:36 +0000 (UTC)
Precedence: bulk
List-Post: <mailto:gentoo-commits@lists.gentoo.org>
List-Help: <mailto:gentoo-commits+help@lists.gentoo.org>
List-Unsubscribe: <mailto:gentoo-commits+unsubscribe@lists.gentoo.org>
List-Subscribe: <mailto:gentoo-commits+subscribe@lists.gentoo.org>
List-Id: Gentoo Linux mail <gentoo-commits.gentoo.org>
X-BeenThere: gentoo-commits@lists.gentoo.org
X-Auto-Response-Suppress: DR, RN, NRN, OOF, AutoReply
X-Archives-Salt: 6c893609-93c9-4e15-87ec-3705800c4571
X-Archives-Hash: b553777de189e65d80576ee49ef77a31

commit:     14862339c3b72e18d39b1567eda637081ef9aa94
Author:     Jimi Huotari <chiitoo <AT> gentoo <DOT> org>
AuthorDate: Fri Mar  8 21:11:30 2019 +0000
Commit:     Andreas Sturmlechner <asturm <AT> gentoo <DOT> org>
CommitDate: Sat Apr  6 20:28:57 2019 +0000
URL:        https://gitweb.gentoo.org/repo/gentoo.git/commit/?id=14862339

media-video/obs-studio: version bump to 23.1.0

Closes: https://bugs.gentoo.org/681100
Package-Manager: Portage-2.3.62, Repoman-2.3.12
Signed-off-by: Jimi Huotari <chiitoo <AT> gentoo.org>
Signed-off-by: Andreas Sturmlechner <asturm <AT> gentoo.org>

 media-video/obs-studio/Manifest                 |   1 +
 media-video/obs-studio/obs-studio-23.1.0.ebuild | 129 ++++++++++++++++++++++++
 2 files changed, 130 insertions(+)

diff --git a/media-video/obs-studio/Manifest b/media-video/obs-studio/Manifest
index 4e440484dd9..2c408bddf18 100644
--- a/media-video/obs-studio/Manifest
+++ b/media-video/obs-studio/Manifest
@@ -1 +1,2 @@
 DIST obs-studio-23.0.1.tar.gz 6223214 BLAKE2B c3b65ad9134aefc36a3fa33b8d185a1ee76f76c10edd30d5ad8a7af86605c4e7b3b8d83c5570203d926655131f7c20f4ef11dcbf55c7af745efc2b68d4933c54 SHA512 6877d4bf635a9769d634683a85075a5fe3a5de1fcc83882647dfbc379a897eee05b69c2159e290ff73f53aa7c03027ea4ea15e1169de57c2c50f4e504eff410f
+DIST obs-studio-23.1.0.tar.gz 6192139 BLAKE2B 8c85d21f68b0dc799a8fdfce3ff94d837d0e02bfa55606eec9985d2c2d1c3d9ae78664ba8b17f393abb197f1595fa0f78f314fe474883a81166d9c6a0967682c SHA512 ab4f71430ae314774afbba8b8e39c4eb35ab147d49d6d33b188e7a820b1198ccbb6005fad111502834652b5261b88d07c075094a8303ea7294da3171e8e015bb

diff --git a/media-video/obs-studio/obs-studio-23.1.0.ebuild b/media-video/obs-studio/obs-studio-23.1.0.ebuild
new file mode 100644
index 00000000000..6ee58e5d0a1
--- /dev/null
+++ b/media-video/obs-studio/obs-studio-23.1.0.ebuild
@@ -0,0 +1,129 @@
+# Copyright 1999-2019 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=7
+
+PYTHON_COMPAT=( python{3_5,3_6,3_7} )
+
+inherit cmake-utils python-single-r1 xdg-utils
+
+if [[ ${PV} == *9999 ]]; then
+	inherit git-r3
+	EGIT_REPO_URI="https://github.com/obsproject/obs-studio.git"
+	EGIT_SUBMODULES=()
+else
+	SRC_URI="https://github.com/obsproject/${PN}/archive/${PV}.tar.gz -> ${P}.tar.gz"
+	KEYWORDS="~amd64 ~x86"
+fi
+
+DESCRIPTION="Software for Recording and Streaming Live Video Content"
+HOMEPAGE="https://obsproject.com"
+
+LICENSE="GPL-2"
+SLOT="0"
+IUSE="+alsa fdk imagemagick jack luajit nvenc pulseaudio python speex truetype v4l"
+REQUIRED_USE="python? ( ${PYTHON_REQUIRED_USE} )"
+
+BDEPEND="
+	luajit? ( dev-lang/swig )
+	python? ( dev-lang/swig )
+"
+DEPEND="
+	>=dev-libs/jansson-2.5
+	dev-qt/qtcore:5
+	dev-qt/qtdeclarative:5
+	dev-qt/qtgui:5
+	dev-qt/qtmultimedia:5
+	dev-qt/qtnetwork:5
+	dev-qt/qtquickcontrols:5
+	dev-qt/qtsql:5
+	dev-qt/qttest:5
+	dev-qt/qtwidgets:5
+	dev-qt/qtx11extras:5
+	media-video/ffmpeg:=[x264]
+	net-misc/curl
+	x11-libs/libXcomposite
+	x11-libs/libXinerama
+	x11-libs/libXrandr
+	alsa? ( media-libs/alsa-lib )
+	fdk? ( media-libs/fdk-aac:= )
+	imagemagick? ( media-gfx/imagemagick:= )
+	jack? ( virtual/jack )
+	luajit? ( dev-lang/luajit:2 )
+	nvenc? (
+		|| (
+			<media-video/ffmpeg-4[nvenc]
+			>=media-video/ffmpeg-4[video_cards_nvidia]
+		)
+	)
+	pulseaudio? ( media-sound/pulseaudio )
+	python? ( ${PYTHON_DEPS} )
+	speex? ( media-libs/speexdsp )
+	truetype? (
+		media-libs/fontconfig
+		media-libs/freetype
+	)
+	v4l? ( media-libs/libv4l )
+"
+RDEPEND="${DEPEND}"
+
+CMAKE_REMOVE_MODULES_LIST=( FindFreetype )
+
+pkg_setup() {
+	use python && python-single-r1_pkg_setup
+}
+
+src_configure() {
+	local libdir=$(get_libdir)
+	local mycmakeargs=(
+		-DDISABLE_ALSA=$(usex !alsa)
+		-DDISABLE_FREETYPE=$(usex !truetype)
+		-DDISABLE_JACK=$(usex !jack)
+		-DDISABLE_LIBFDK=$(usex !fdk)
+		-DDISABLE_PULSEAUDIO=$(usex !pulseaudio)
+		-DDISABLE_SPEEXDSP=$(usex !speex)
+		-DDISABLE_V4L2=$(usex !v4l)
+		-DLIBOBS_PREFER_IMAGEMAGICK=$(usex imagemagick)
+		-DOBS_MULTIARCH_SUFFIX=${libdir#lib}
+		-DOBS_VERSION_OVERRIDE=${PV}
+		-DUNIX_STRUCTURE=1
+	)
+
+	if use luajit || use python; then
+		mycmakeargs+=(
+			-DDISABLE_LUA=$(usex !luajit)
+			-DDISABLE_PYTHON=$(usex !python)
+			-DENABLE_SCRIPTING=yes
+		)
+	else
+		mycmakeargs+=( -DENABLE_SCRIPTING=no )
+	fi
+
+	cmake-utils_src_configure
+}
+
+pkg_postinst() {
+	xdg_icon_cache_update
+
+	if ! use alsa && ! use pulseaudio; then
+		elog
+		elog "For the audio capture features to be available,"
+		elog "either the 'alsa' or the 'pulseaudio' USE-flag needs to"
+		elog "be enabled."
+		elog
+	fi
+
+	if ! has_version "sys-apps/dbus"; then
+		elog
+		elog "The 'sys-apps/dbus' package is not installed, but"
+		elog "could be used for disabling hibernating, screensaving,"
+		elog "and sleeping.  Where it is not installed,"
+		elog "'xdg-screensaver reset' is used instead"
+		elog "(if 'x11-misc/xdg-utils' is installed)."
+		elog
+	fi
+}
+
+pkg_postrm() {
+	xdg_icon_cache_update
+}