[gentoo-commits] repo/gentoo:master commit in: app-text/xchm/

["Jeroen Roovers" <jer@gentoo.org>]

commit:     8ba3f9b925a7f38e9aefcb22833c7a68a26261f6
Author:     Jeroen Roovers <jer <AT> gentoo <DOT> org>
AuthorDate: Sat Apr  6 08:49:01 2019 +0000
Commit:     Jeroen Roovers <jer <AT> gentoo <DOT> org>
CommitDate: Sat Apr  6 08:49:43 2019 +0000
URL:        https://gitweb.gentoo.org/repo/gentoo.git/commit/?id=8ba3f9b9

app-text/xchm: Add live ebuild

Package-Manager: Portage-2.3.62, Repoman-2.3.12
Signed-off-by: Jeroen Roovers <jer <AT> gentoo.org>

 app-text/xchm/xchm-9999.ebuild | 58 ++++++++++++++++++++++++++++++++++++++++++
 1 file changed, 58 insertions(+)

diff --git a/app-text/xchm/xchm-9999.ebuild b/app-text/xchm/xchm-9999.ebuild
new file mode 100644
index 00000000000..ff28fc53413
--- /dev/null
+++ b/app-text/xchm/xchm-9999.ebuild
@@ -0,0 +1,58 @@
+# Copyright 1999-2019 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=6
+WX_GTK_VER="3.0-gtk3"
+
+inherit autotools git-r3 wxwidgets xdg-utils
+
+DESCRIPTION="Utility for viewing Compiled HTML Help (CHM) files"
+HOMEPAGE="https://github.com/rzvncj/xCHM/"
+EGIT_REPO_URI="${HOMEPAGE}"
+
+LICENSE="GPL-2"
+SLOT="0"
+KEYWORDS=""
+IUSE="nls"
+
+DEPEND="
+	>=dev-libs/chmlib-0.36
+	x11-libs/wxGTK:${WX_GTK_VER}[X]
+"
+RDEPEND="
+	${DEPEND}
+"
+
+src_prepare() {
+	setup-wxwidgets
+	default
+	eautoreconf
+}
+
+src_configure() {
+	econf $(use_enable nls)
+}
+
+src_install() {
+	emake DESTDIR="${D}" install
+
+	dodoc AUTHORS README ChangeLog
+
+	cp "${D}"/usr/share/pixmaps/xchm-32.xpm "${D}"/usr/share/pixmaps/xchm.xpm
+	rm -f "${D}"/usr/share/pixmaps/xchm-*.xpm
+	rm -f "${D}"/usr/share/pixmaps/xchmdoc*.xpm
+
+	domenu "${FILESDIR}"/xchm.desktop
+	insinto /usr/share/mime/packages
+	doins "${FILESDIR}"/xchm.xml
+}
+
+pkg_postinst() {
+	xdg_desktop_database_update
+	xdg_mimeinfo_database_update
+}
+
+pkg_postrm() {
+	xdg_desktop_database_update
+	xdg_mimeinfo_database_update
+}