[gentoo-commits] repo/gentoo:master commit in: net-misc/miniupnpd/

["Michał Górny" <mgorny@gentoo.org>]

commit:     0eecbfaebbcf3f438e428c97b113f1abcd66670e
Author:     Michał Górny <mgorny <AT> gentoo <DOT> org>
AuthorDate: Fri Apr  5 05:15:21 2019 +0000
Commit:     Michał Górny <mgorny <AT> gentoo <DOT> org>
CommitDate: Fri Apr  5 05:15:21 2019 +0000
URL:        https://gitweb.gentoo.org/repo/gentoo.git/commit/?id=0eecbfae

net-misc/miniupnpd: Bump to 2.1.20190403

Signed-off-by: Michał Górny <mgorny <AT> gentoo.org>

 net-misc/miniupnpd/Manifest                      |  1 +
 net-misc/miniupnpd/miniupnpd-2.1.20190403.ebuild | 65 ++++++++++++++++++++++++
 2 files changed, 66 insertions(+)

diff --git a/net-misc/miniupnpd/Manifest b/net-misc/miniupnpd/Manifest
index 8bb0d316b83..54d2f7c35f9 100644
--- a/net-misc/miniupnpd/Manifest
+++ b/net-misc/miniupnpd/Manifest
@@ -1 +1,2 @@
 DIST miniupnpd-2.1.20190210.tar.gz 235093 BLAKE2B d86b4a73ebfe6b5f3665b92624e7eac36718fffea058c0e7d2cb4af2c0871534c7f7ec56ade6c3cb2e13215a77971173259f912efd61a37e41d0f2f0a4596e5c SHA512 d664d5f61a0e2e71086aa520cb91af9f7f9b8b34268a76d570bbca271d86eab4976655a1fec1d21be80a93e357a0cb185281037604a0cfc00e4944d8e8b6f664
+DIST miniupnpd-2.1.20190403.tar.gz 235909 BLAKE2B 121aa74d1337dbdaec280edd13a688c42c7af49e1f6d44cac94701e878fe554adb8b878ac2c075391124cee14b5c01d57987024fadf95e4508ed3b3047bad543 SHA512 63fbd09d769c7a8ffba92cd5724bc04e4553085b95405daa905ac77f95d2fbcf1852fd8ff7171e2fe39aac7ac76ebae87142fe5dc2e57932c89d8d98d472034b

diff --git a/net-misc/miniupnpd/miniupnpd-2.1.20190403.ebuild b/net-misc/miniupnpd/miniupnpd-2.1.20190403.ebuild
new file mode 100644
index 00000000000..673b340fb09
--- /dev/null
+++ b/net-misc/miniupnpd/miniupnpd-2.1.20190403.ebuild
@@ -0,0 +1,65 @@
+# Copyright 1999-2019 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=7
+
+inherit toolchain-funcs
+
+DESCRIPTION="MiniUPnP IGD Daemon"
+HOMEPAGE="http://miniupnp.free.fr/"
+SRC_URI="http://miniupnp.free.fr/files/${P}.tar.gz"
+
+LICENSE="BSD"
+SLOT="0"
+KEYWORDS="~amd64 ~arm ~x86"
+IUSE="+leasefile igd2 ipv6 pcp-peer portinuse strict"
+
+RDEPEND=">=net-firewall/iptables-1.4.6:0=[ipv6?]
+	net-libs/libnfnetlink:=
+	net-libs/libmnl:=
+	dev-libs/gmp:0=
+	sys-apps/util-linux:=
+	dev-libs/openssl:0="
+DEPEND="${RDEPEND}
+	sys-apps/lsb-release"
+
+src_prepare() {
+	default
+	mv Makefile.linux Makefile || die
+
+	# Prevent gzipping manpage.
+	sed -i -e '/gzip/d' Makefile || die
+}
+
+src_configure() {
+	local -a opts
+	opts=(
+		--vendorcfg
+		$(usex igd2 '--igd2' '')
+		$(usex ipv6 '--ipv6' '')
+		$(usex leasefile '--leasefile' '')
+		$(usex portinuse '--portinuse' '')
+		$(usex pcp-peer '--pcp-peer' '')
+		$(usex strict '--strict' '')
+	)
+
+	emake CONFIG_OPTIONS="${opts[*]}" config.h
+}
+
+src_compile() {
+	# By default, it builds a bunch of unittests that are missing wrapper
+	# scripts in the tarball
+	emake CC="$(tc-getCC)" STRIP=true miniupnpd
+}
+
+src_install() {
+	emake PREFIX="${ED}" STRIP=true install
+
+	newinitd "${FILESDIR}"/${PN}-init.d-r1 ${PN}
+	newconfd "${FILESDIR}"/${PN}-conf.d-r1 ${PN}
+}
+
+pkg_postinst() {
+	elog "Please correct the external interface in the top of the two"
+	elog "scripts in /etc/miniupnpd and edit the config file in there too"
+}