[gentoo-commits] repo/gentoo:master commit in: dev-libs/openobex/

["Andrew Savchenko" <bircoph@gentoo.org>]

commit:     b65c3d9897a06a4d70a9f4b58f2ec506374f0f86
Author:     Andrew Savchenko <bircoph <AT> gentoo <DOT> org>
AuthorDate: Fri Mar 22 11:09:01 2019 +0000
Commit:     Andrew Savchenko <bircoph <AT> gentoo <DOT> org>
CommitDate: Fri Mar 22 11:24:00 2019 +0000
URL:        https://gitweb.gentoo.org/repo/gentoo.git/commit/?id=b65c3d98

dev-libs/openobex: qa fixes

1. Fix QA for unused cmake variable with USE="-usb".
2. Update to EAPI 7.

Closes: https://bugs.gentoo.org/677898
Package-Manager: Portage-2.3.62, Repoman-2.3.12
Signed-off-by: Andrew Savchenko <bircoph <AT> gentoo.org>

 dev-libs/openobex/openobex-1.7.2-r2.ebuild | 43 ++++++++++++++++++++++++++++++
 1 file changed, 43 insertions(+)

diff --git a/dev-libs/openobex/openobex-1.7.2-r2.ebuild b/dev-libs/openobex/openobex-1.7.2-r2.ebuild
new file mode 100644
index 00000000000..ab1632e42d3
--- /dev/null
+++ b/dev-libs/openobex/openobex-1.7.2-r2.ebuild
@@ -0,0 +1,43 @@
+# Copyright 1999-2019 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=7
+
+inherit cmake-utils udev
+
+DESCRIPTION="Implementation of the OBEX protocol used for transferring data to mobile devices"
+HOMEPAGE="https://sourceforge.net/projects/openobex/"
+SRC_URI="mirror://sourceforge/${PN}/${PV}/${P}-Source.tar.gz"
+
+LICENSE="GPL-2 LGPL-2.1"
+SLOT="0/2"
+KEYWORDS="~amd64 ~arm ~hppa ~ppc ~ppc64 ~sparc ~x86"
+IUSE="bluetooth doc irda usb"
+
+BDEPEND="
+	doc? ( app-doc/doxygen )
+	virtual/pkgconfig
+"
+DEPEND="
+	bluetooth? ( net-wireless/bluez:= )
+	usb? ( virtual/libusb:= )
+"
+RDEPEND="${DEPEND}"
+
+S="${WORKDIR}/${P}-Source"
+
+PATCHES=( "${FILESDIR}/${P}-version.h.patch" )
+DOCS=( AUTHORS ChangeLog README UPGRADING.txt )
+
+src_configure() {
+	local mycmakeargs=(
+		-DBUILD_DOCUMENTATION=$(usex doc)
+		-DOPENOBEX_BLUETOOTH=$(usex bluetooth)
+		-DOPENOBEX_IRDA=$(usex irda)
+		-DOPENOBEX_USB=$(usex usb)
+		-DCMAKE_INSTALL_DOCDIR="${EPREFIX}/usr/share/doc/${PF}"
+	)
+	use usb && mycmakeargs+=( -DCMAKE_INSTALL_UDEVRULESDIR="$(get_udevdir)/rules.d" )
+
+	cmake-utils_src_configure
+}