[gentoo-commits] repo/gentoo:master commit in: net-libs/libpsl/

["Lars Wendler" <polynomial-c@gentoo.org>]

commit:     7aebbbc9c4f3e51af7ab3fb435c503c0cf26738d
Author:     Lars Wendler <polynomial-c <AT> gentoo <DOT> org>
AuthorDate: Mon Mar 18 16:20:23 2019 +0000
Commit:     Lars Wendler <polynomial-c <AT> gentoo <DOT> org>
CommitDate: Mon Mar 18 16:20:42 2019 +0000
URL:        https://gitweb.gentoo.org/repo/gentoo.git/commit/?id=7aebbbc9

net-libs/libpsl: Initial commit

Package-Manager: Portage-2.3.62, Repoman-2.3.12
Signed-off-by: Lars Wendler <polynomial-c <AT> gentoo.org>

 net-libs/libpsl/Manifest             |  1 +
 net-libs/libpsl/libpsl-0.20.2.ebuild | 67 ++++++++++++++++++++++++++++++++++++
 net-libs/libpsl/metadata.xml         | 14 ++++++++
 3 files changed, 82 insertions(+)

diff --git a/net-libs/libpsl/Manifest b/net-libs/libpsl/Manifest
new file mode 100644
index 00000000000..e9fbf64bcb0
--- /dev/null
+++ b/net-libs/libpsl/Manifest
@@ -0,0 +1 @@
+DIST libpsl-0.20.2.tar.gz 9228099 BLAKE2B d53b8a036ba557704c4d3a498b35fd25e3dfc466d5161040d02b7d8d47af2138cce2bdbb8203fca0591408440f1b4cfab776fe0d2ecd68959f426d903cab08d4 SHA512 fa9f6f7f0447d9fe00f5dfca5262c56ff26217eea44d0f7fc1e5d982224c41874e753f0aa06dd9e5d7d03d4f04e3dacd4f36034cc8dd0fc6e2c28b49a23e62fe

diff --git a/net-libs/libpsl/libpsl-0.20.2.ebuild b/net-libs/libpsl/libpsl-0.20.2.ebuild
new file mode 100644
index 00000000000..4873768c063
--- /dev/null
+++ b/net-libs/libpsl/libpsl-0.20.2.ebuild
@@ -0,0 +1,67 @@
+# Copyright 1999-2019 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=7
+
+DESCRIPTION="C library for the Public Suffix List"
+HOMEPAGE="https://github.com/rockdaboot/libpsl"
+SRC_URI="https://github.com/rockdaboot/${PN}/releases/download/${P}/${P}.tar.gz"
+LICENSE="MIT"
+SLOT="0"
+
+KEYWORDS="~amd64 ~x86"
+IUSE="icu +idn +man"
+
+REQUIRED_USE="^^ ( icu idn )"
+
+RDEPEND="
+	icu? ( dev-libs/icu:= )
+	idn? (
+		dev-libs/libunistring
+		net-dns/libidn2:=
+	)
+"
+
+DEPEND="
+	${RDEPEND}
+"
+BDEPEND="
+	dev-util/gtk-doc
+	sys-devel/gettext
+	virtual/pkgconfig
+	man? ( dev-libs/libxslt )
+"
+
+src_configure() {
+	local myeconfargs=(
+		--enable-ubsan
+		--disable-asan
+		--disable-cfi
+		$(use_enable man)
+	)
+
+	if use icu || use idn ; then
+		if use icu ; then
+			myeconfargs+=(
+				--enable-builtin=libicu
+				--enable-runtime=libicu
+			)
+		fi
+		if use idn ; then
+			myeconfargs+=(
+				--enable-builtin=libidn2
+				--enable-runtime=libidn2
+			)
+		fi
+	else
+		myeconfargs+=( --disable-runtime )
+	fi
+
+	econf "${myeconfargs[@]}"
+}
+
+src_install() {
+	default
+
+	find "${ED}" \( -name "*.a" -o -name "*.la" \) -delete || die
+}

diff --git a/net-libs/libpsl/metadata.xml b/net-libs/libpsl/metadata.xml
new file mode 100644
index 00000000000..93c95ae3fa8
--- /dev/null
+++ b/net-libs/libpsl/metadata.xml
@@ -0,0 +1,14 @@
+<?xml version="1.0" encoding="UTF-8"?>
+<!DOCTYPE pkgmetadata SYSTEM "http://www.gentoo.org/dtd/metadata.dtd">
+<pkgmetadata>
+  <maintainer type="person">
+    <email>polynomial-c@gentoo.org</email>
+    <name>Lars Wendler</name>
+  </maintainer>
+  <upstream>
+    <remote-id type="github">rockdaboot/libpsl</remote-id>
+  </upstream>
+  <use>
+    <flag name="man">Build man-pages</flag>
+  </use>
+</pkgmetadata>