[gentoo-commits] repo/proj/libressl:master commit in: dev-qt/qtnetwork/

["Stefan Strogin" <stefan.strogin@gmail.com>]

commit:     7d74943a95d64012d973fb65510c4d70a3f463f3
Author:     Stefan Strogin <stefan.strogin <AT> gmail <DOT> com>
AuthorDate: Sun Mar 17 18:45:04 2019 +0000
Commit:     Stefan Strogin <stefan.strogin <AT> gmail <DOT> com>
CommitDate: Sun Mar 17 18:45:04 2019 +0000
URL:        https://gitweb.gentoo.org/repo/proj/libressl.git/commit/?id=7d74943a

dev-qt/qtnetwork: bump version to 5.12.2

Bug: https://bugs.gentoo.org/562050
Package-Manager: Portage-2.3.62, Repoman-2.3.12
Signed-off-by: Stefan Strogin <stefan.strogin <AT> gmail.com>

 dev-qt/qtnetwork/Manifest                |  1 +
 dev-qt/qtnetwork/qtnetwork-5.12.2.ebuild | 67 ++++++++++++++++++++++++++++++++
 2 files changed, 68 insertions(+)

diff --git a/dev-qt/qtnetwork/Manifest b/dev-qt/qtnetwork/Manifest
index 95f102a..2f5ac74 100644
--- a/dev-qt/qtnetwork/Manifest
+++ b/dev-qt/qtnetwork/Manifest
@@ -1,2 +1,3 @@
 DIST qtbase-everywhere-src-5.11.3.tar.xz 46997676 BLAKE2B a70089be5530dec0eedcd5ba990140b375261dea5c85ea7d1dbb5b0bd09ee23edbb4917851127686b5f3cac6969a284eb91ab075ebe53326e69e99e81b257da0 SHA512 93865e41c994211456a575b085c2e7491b7975a1c3b4deb48e9616b51104eb990c1fcfd53d5fb2146ba22457cb134e6254e9077ba73c8b4c4b4d1d525e66fb65
 DIST qtbase-everywhere-src-5.12.1.tar.xz 48239912 BLAKE2B 99a92c2134a20d5f52a1ae69e5d248f12e4668308f894ead17927a778558b4fcd598f5f5208527a77e20550d7eb77502253cae91ad19f61ff422a1ff52e84060 SHA512 51494d8947ae16ab7aee22aca156035718f5a700737547de59b4d61d3919c00f4de858111c8928a66c0385604623d847d231892d964d53924a8c97b6e2bedf25
+DIST qtbase-everywhere-src-5.12.2.tar.xz 48364464 BLAKE2B 1743fc3e233ab5c204c4c88db61ede946fbb967ed69c47709ee071bf1b911ef79a6581ff9db6e6bdabb15202196614fbdce32521750e41898906100ae5259960 SHA512 6752ecc096f8baf8e14e56f0d1f139e8a0d75967ab61bf1734ad5f4f4609a7cc707ab080f5f85f2230bbbb1454a0669be60a14d57d9a93aef553ce6f85f71613

diff --git a/dev-qt/qtnetwork/qtnetwork-5.12.2.ebuild b/dev-qt/qtnetwork/qtnetwork-5.12.2.ebuild
new file mode 100644
index 0000000..e5d9d4f
--- /dev/null
+++ b/dev-qt/qtnetwork/qtnetwork-5.12.2.ebuild
@@ -0,0 +1,67 @@
+# Copyright 1999-2019 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=6
+QT5_MODULE="qtbase"
+inherit qt5-build
+
+DESCRIPTION="Network abstraction library for the Qt5 framework"
+
+if [[ ${QT5_BUILD_TYPE} == release ]]; then
+	KEYWORDS="~amd64 ~arm ~arm64 ~hppa ~ppc ~ppc64 ~sparc ~x86 ~amd64-fbsd"
+fi
+
+IUSE="bindist connman libproxy libressl networkmanager sctp +ssl"
+
+DEPEND="
+	~dev-qt/qtcore-${PV}
+	sys-libs/zlib:=
+	connman? ( ~dev-qt/qtdbus-${PV} )
+	libproxy? ( net-libs/libproxy )
+	networkmanager? ( ~dev-qt/qtdbus-${PV} )
+	sctp? ( kernel_linux? ( net-misc/lksctp-tools ) )
+	ssl? (
+		!libressl? ( dev-libs/openssl:0=[bindist=] )
+		libressl? ( dev-libs/libressl:0= )
+	)
+"
+RDEPEND="${DEPEND}
+	connman? ( net-misc/connman )
+	networkmanager? ( net-misc/networkmanager )
+"
+
+PATCHES=(
+	"${FILESDIR}"/${PN}-5.12.1-libressl.patch
+)
+
+QT5_TARGET_SUBDIRS=(
+	src/network
+	src/plugins/bearer/generic
+)
+
+QT5_GENTOO_CONFIG=(
+	libproxy:libproxy:
+	ssl::SSL
+	ssl::OPENSSL
+	ssl:openssl-linked:LINKED_OPENSSL
+)
+
+QT5_GENTOO_PRIVATE_CONFIG=(
+	:network
+)
+
+pkg_setup() {
+	use connman && QT5_TARGET_SUBDIRS+=(src/plugins/bearer/connman)
+	use networkmanager && QT5_TARGET_SUBDIRS+=(src/plugins/bearer/networkmanager)
+}
+
+src_configure() {
+	local myconf=(
+		$(usex connman -dbus-linked '')
+		$(qt_use libproxy)
+		$(usex networkmanager -dbus-linked '')
+		$(qt_use sctp)
+		$(usex ssl -openssl-linked '')
+	)
+	qt5-build_src_configure
+}