[gentoo-commits] repo/gentoo:master commit in: games-engines/scummvm/

["Lars Wendler" <polynomial-c@gentoo.org>]

commit:     f5af80ab565c07d5da0443dd2b2d137e54d9a3c8
Author:     Lars Wendler <polynomial-c <AT> gentoo <DOT> org>
AuthorDate: Fri Mar 15 22:12:32 2019 +0000
Commit:     Lars Wendler <polynomial-c <AT> gentoo <DOT> org>
CommitDate: Fri Mar 15 22:45:27 2019 +0000
URL:        https://gitweb.gentoo.org/repo/gentoo.git/commit/?id=f5af80ab

games-engines/scummvm: EAPI-7 revbump.

Package-Manager: Portage-2.3.62, Repoman-2.3.12
Signed-off-by: Lars Wendler <polynomial-c <AT> gentoo.org>

 games-engines/scummvm/scummvm-2.0.0-r1.ebuild | 110 ++++++++++++++++++++++++++
 1 file changed, 110 insertions(+)

diff --git a/games-engines/scummvm/scummvm-2.0.0-r1.ebuild b/games-engines/scummvm/scummvm-2.0.0-r1.ebuild
new file mode 100644
index 00000000000..858b3bcc36b
--- /dev/null
+++ b/games-engines/scummvm/scummvm-2.0.0-r1.ebuild
@@ -0,0 +1,110 @@
+# Copyright 1999-2019 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=7
+inherit desktop flag-o-matic toolchain-funcs xdg
+
+DESCRIPTION="Reimplementation of the SCUMM game engine used in Lucasarts adventures"
+HOMEPAGE="http://scummvm.sourceforge.net/"
+SRC_URI="http://scummvm.org/frs/scummvm/${PV}/${P}.tar.xz"
+
+LICENSE="GPL-2+ LGPL-2.1 BSD GPL-3-with-font-exception"
+SLOT="0"
+KEYWORDS="~amd64 ~ppc64 ~x86 ~x86-fbsd"
+IUSE="aac alsa debug flac fluidsynth jpeg mpeg2 mp3 opengl png theora truetype unsupported vorbis zlib"
+RESTRICT="test"  # it only looks like there's a test there #77507
+
+RDEPEND=">=media-libs/libsdl2-2.0.0[sound,joystick,video]
+	zlib? ( sys-libs/zlib:= )
+	jpeg? ( virtual/jpeg:0 )
+	png? ( media-libs/libpng:0 )
+	vorbis? (
+		media-libs/libogg
+		media-libs/libvorbis
+	)
+	theora? ( media-libs/libtheora )
+	aac? ( media-libs/faad2 )
+	alsa? ( media-libs/alsa-lib )
+	mp3? ( media-libs/libmad )
+	mpeg2? ( media-libs/libmpeg2 )
+	flac? ( media-libs/flac )
+	opengl? ( virtual/opengl )
+	truetype? ( media-libs/freetype:2 )
+	fluidsynth? ( media-sound/fluidsynth )"
+DEPEND="${RDEPEND}"
+BDEPEND="
+	app-arch/xz-utils
+	truetype? ( virtual/pkgconfig )
+	x86? ( dev-lang/nasm )
+"
+
+S="${WORKDIR}/${P/_/}"
+
+PATCHES=( "${FILESDIR}/${PN}-2.0.0-freetype_pkgconfig.patch" )
+
+src_prepare() {
+	default
+
+	# -g isn't needed for nasm here
+	sed -i \
+		-e '/NASMFLAGS/ s/-g//' \
+		configure || die
+	sed -i \
+		-e '/INSTALL.*doc/d' \
+		-e '/INSTALL.*\/pixmaps/d' \
+		-e 's/-s //' \
+		ports.mk || die
+}
+
+src_configure() {
+	use x86 && append-ldflags -Wl,-z,noexecstack
+
+	local myconf=(
+		--backend=sdl
+		--host=${CHOST}
+		--enable-verbose-build
+		--prefix="${EPREFIX}/usr"
+		--libdir="${EPREFIX}/usr/$(get_libdir)"
+		--opengl-mode=$(usex opengl auto none)
+		$(use_enable aac faad)
+		$(use_enable alsa)
+		$(use_enable debug)
+		$(use_enable !debug release-mode)
+		$(use_enable flac)
+		$(usex fluidsynth '' --disable-fluidsynth)
+		$(use_enable jpeg)
+		$(use_enable mp3 mad)
+		$(use_enable mpeg2)
+		$(use_enable png)
+		$(use_enable theora theoradec)
+		$(use_enable truetype freetype2)
+		$(usex unsupported --enable-all-engines '')
+		$(use_enable vorbis)
+		$(use_enable zlib)
+		$(use_enable x86 nasm)
+	)
+	# NOT AN AUTOCONF SCRIPT SO DONT CALL ECONF
+	SDL_CONFIG="sdl2-config" \
+	./configure "${myconf[@]}" "${EXTRA_ECONF}" || die
+}
+
+src_compile() {
+	emake AR="$(tc-getAR) cru" RANLIB="$(tc-getRANLIB)"
+}
+
+src_install() {
+	default
+	doicon -s scalable icons/scummvm.svg
+}
+
+pkg_preinst() {
+	xdg_pkg_preinst
+}
+
+pkg_postinst() {
+	xdg_pkg_postinst
+}
+
+pkg_postrm() {
+	xdg_pkg_postrm
+}