[gentoo-commits] repo/gentoo:master commit in: app-editors/gedit-plugins/

["Mart Raudsepp" <leio@gentoo.org>]

commit:     79b3d877458c6d55e7d0077e6dfeaf2b0ee003ea
Author:     Mart Raudsepp <leio <AT> gentoo <DOT> org>
AuthorDate: Wed Mar 13 21:57:28 2019 +0000
Commit:     Mart Raudsepp <leio <AT> gentoo <DOT> org>
CommitDate: Wed Mar 13 23:20:38 2019 +0000
URL:        https://gitweb.gentoo.org/repo/gentoo.git/commit/?id=79b3d877

app-editors/gedit-plugins: bump to 3.30.1

Package-Manager: Portage-2.3.52, Repoman-2.3.12
Signed-off-by: Mart Raudsepp <leio <AT> gentoo.org>

 app-editors/gedit-plugins/Manifest                 |  1 +
 .../gedit-plugins/gedit-plugins-3.30.1.ebuild      | 94 ++++++++++++++++++++++
 2 files changed, 95 insertions(+)

diff --git a/app-editors/gedit-plugins/Manifest b/app-editors/gedit-plugins/Manifest
index e12d4ce674f..7a3fdc56475 100644
--- a/app-editors/gedit-plugins/Manifest
+++ b/app-editors/gedit-plugins/Manifest
@@ -1 +1,2 @@
 DIST gedit-plugins-3.28.1.tar.xz 1350468 BLAKE2B 4fd50ad7358581f5e27f0c3a7e127d4e2c0e7189c039daee1d8d7ddf7062846e1aebb634b3edd998c9a7c11840c71f56fe4eeca78ea2e91ae18db814e4fd79e5 SHA512 6258c627cd3fa2948375c30e87061375c0d09ce2c70301c2d10a403e6075d1df09e928a2d95b72f6d7950a31a720af645fff2f7f59a281d2999948beb56c1dc9
+DIST gedit-plugins-3.30.1.tar.xz 1354644 BLAKE2B ee42fb2fe47c9219442e0bbdaf21a14a834b8bc38558713ccf0ad384814812fd71f4d318624b4d2c149b26d304203a2b954ef49c3299877f4d067ae181bfe1d5 SHA512 0e777779288b51015d7ab539bf896a00d5226560f2cc2211daf777da87824eed858255318c421524933a540135e4bfdcc294ba7ed89f680a35aa48f7279cbc94

diff --git a/app-editors/gedit-plugins/gedit-plugins-3.30.1.ebuild b/app-editors/gedit-plugins/gedit-plugins-3.30.1.ebuild
new file mode 100644
index 00000000000..ee5dd1d5d9d
--- /dev/null
+++ b/app-editors/gedit-plugins/gedit-plugins-3.30.1.ebuild
@@ -0,0 +1,94 @@
+# Copyright 1999-2019 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI="6"
+GNOME2_LA_PUNT="yes" # plugins are dlopened
+PYTHON_COMPAT=( python3_{4,5,6} )
+PYTHON_REQ_USE="xml"
+VALA_MIN_API_VERSION="0.28"
+
+inherit eutils gnome2 multilib python-single-r1 vala
+
+DESCRIPTION="Official plugins for gedit"
+HOMEPAGE="https://wiki.gnome.org/Apps/Gedit/ShippedPlugins"
+
+LICENSE="GPL-2+"
+KEYWORDS="~amd64 ~x86"
+SLOT="0"
+
+IUSE_plugins="charmap git terminal vala"
+IUSE="+python ${IUSE_plugins}"
+# python-single-r1 would request disabling PYTHON_TARGETS on libpeas
+REQUIRED_USE="
+	charmap? ( python )
+	git? ( python )
+	python? ( ${PYTHON_REQUIRED_USE} )
+	terminal? ( python )
+"
+
+RDEPEND="
+	>=app-editors/gedit-3.16
+	>=dev-libs/glib-2.32:2
+	>=dev-libs/libpeas-1.7.0[gtk]
+	>=x11-libs/gtk+-3.9:3
+	>=x11-libs/gtksourceview-3.21.3:3.0
+	python? (
+		${PYTHON_DEPS}
+		>=app-editors/gedit-3.16[introspection,python,${PYTHON_USEDEP}]
+		dev-libs/libpeas[python,${PYTHON_USEDEP}]
+		>=dev-python/dbus-python-0.82[${PYTHON_USEDEP}]
+		dev-python/pycairo[${PYTHON_USEDEP}]
+		dev-python/pygobject:3[cairo,${PYTHON_USEDEP}]
+		>=x11-libs/gtk+-3.9:3[introspection]
+		>=x11-libs/gtksourceview-3.14:3.0[introspection]
+		x11-libs/pango[introspection]
+		x11-libs/gdk-pixbuf:2[introspection]
+	)
+	charmap? ( >=gnome-extra/gucharmap-3:2.90[introspection] )
+	git? ( >=dev-libs/libgit2-glib-0.0.6 )
+	terminal? ( >=x11-libs/vte-0.52:2.91[introspection] )
+	vala? ( $(vala_depend) )
+" # vte-0.52+ for feed_child API compatibility
+DEPEND="${RDEPEND}
+	>=dev-util/intltool-0.50.2
+	dev-util/itstool
+	>=sys-devel/gettext-0.17
+	virtual/pkgconfig
+"
+
+pkg_setup() {
+	use python && [[ ${MERGE_TYPE} != binary ]] && python-single-r1_pkg_setup
+}
+
+src_prepare() {
+	use vala && vala_src_prepare
+	gnome2_src_prepare
+}
+
+src_configure() {
+	gnome2_src_configure \
+		$(use_enable python) \
+		$(use_enable vala)
+}
+
+src_install() {
+	gnome2_src_install
+
+	# FIXME: crazy !!!
+	if use python; then
+		find "${ED}"/usr/share/gedit -name "*.py*" -delete || die
+		find "${ED}"/usr/share/gedit -type d -empty -delete || die
+	fi
+
+	# FIXME: upstream made this automagic...
+	clean_plugin charmap
+	clean_plugin git
+	clean_plugin terminal
+}
+
+clean_plugin() {
+	if use !${1} ; then
+		rm -rf "${ED}"/usr/share/gedit/plugins/${1}*
+		rm -rf "${ED}"/usr/$(get_libdir)/gedit/plugins/${1}*
+	fi
+}