From mboxrd@z Thu Jan 1 00:00:00 1970
Return-Path: <gentoo-commits+bounces-1076858-garchives=archives.gentoo.org@lists.gentoo.org>
Received: from lists.gentoo.org (pigeon.gentoo.org [208.92.234.80])
(using TLSv1.2 with cipher ECDHE-RSA-AES256-GCM-SHA384 (256/256 bits))
(No client certificate requested)
by finch.gentoo.org (Postfix) with ESMTPS id 50561138335
for <garchives@archives.gentoo.org>; Tue, 12 Mar 2019 09:08:43 +0000 (UTC)
Received: from pigeon.gentoo.org (localhost [127.0.0.1])
by pigeon.gentoo.org (Postfix) with SMTP id 54564E08AB;
Tue, 12 Mar 2019 09:08:42 +0000 (UTC)
Received: from smtp.gentoo.org (smtp.gentoo.org [140.211.166.183])
(using TLSv1.2 with cipher ECDHE-RSA-AES128-GCM-SHA256 (128/128 bits))
(No client certificate requested)
by pigeon.gentoo.org (Postfix) with ESMTPS id 1F798E08AB
for <gentoo-commits@lists.gentoo.org>; Tue, 12 Mar 2019 09:08:42 +0000 (UTC)
Received: from oystercatcher.gentoo.org (oystercatcher.gentoo.org [148.251.78.52])
(using TLSv1.2 with cipher ECDHE-RSA-AES128-GCM-SHA256 (128/128 bits))
(No client certificate requested)
by smtp.gentoo.org (Postfix) with ESMTPS id C97E1335C9C
for <gentoo-commits@lists.gentoo.org>; Tue, 12 Mar 2019 09:08:40 +0000 (UTC)
Received: from localhost.localdomain (localhost [IPv6:::1])
by oystercatcher.gentoo.org (Postfix) with ESMTP id 37467517
for <gentoo-commits@lists.gentoo.org>; Tue, 12 Mar 2019 09:08:39 +0000 (UTC)
From: "Lars Wendler" <polynomial-c@gentoo.org>
To: gentoo-commits@lists.gentoo.org
Content-Transfer-Encoding: 8bit
Content-type: text/plain; charset=UTF-8
Reply-To: gentoo-dev@lists.gentoo.org, "Lars Wendler" <polynomial-c@gentoo.org>
Message-ID: <1552381439.e6e63cadb5d42f2cba3b77a026314b6b2e4cf2db.polynomial-c@gentoo>
Subject: [gentoo-commits] repo/gentoo:master commit in: dev-vcs/mercurial/
X-VCS-Repository: repo/gentoo
X-VCS-Files: dev-vcs/mercurial/Manifest dev-vcs/mercurial/mercurial-4.9.ebuild
X-VCS-Directories: dev-vcs/mercurial/
X-VCS-Committer: polynomial-c
X-VCS-Committer-Name: Lars Wendler
X-VCS-Revision: e6e63cadb5d42f2cba3b77a026314b6b2e4cf2db
X-VCS-Branch: master
Date: Tue, 12 Mar 2019 09:08:39 +0000 (UTC)
Precedence: bulk
List-Post: <mailto:gentoo-commits@lists.gentoo.org>
List-Help: <mailto:gentoo-commits+help@lists.gentoo.org>
List-Unsubscribe: <mailto:gentoo-commits+unsubscribe@lists.gentoo.org>
List-Subscribe: <mailto:gentoo-commits+subscribe@lists.gentoo.org>
List-Id: Gentoo Linux mail <gentoo-commits.gentoo.org>
X-BeenThere: gentoo-commits@lists.gentoo.org
X-Auto-Response-Suppress: DR, RN, NRN, OOF, AutoReply
X-Archives-Salt: 5fb601ee-b6ab-4bcb-a247-dfe9eec2e44c
X-Archives-Hash: 79642bdf77b34029c0d03907ac72e322
commit: e6e63cadb5d42f2cba3b77a026314b6b2e4cf2db
Author: Lars Wendler <polynomial-c <AT> gentoo <DOT> org>
AuthorDate: Tue Mar 12 09:03:59 2019 +0000
Commit: Lars Wendler <polynomial-c <AT> gentoo <DOT> org>
CommitDate: Tue Mar 12 09:03:59 2019 +0000
URL: https://gitweb.gentoo.org/repo/gentoo.git/commit/?id=e6e63cad
dev-vcs/mercurial: Bump to version 4.9
Package-Manager: Portage-2.3.62, Repoman-2.3.12
Signed-off-by: Lars Wendler <polynomial-c <AT> gentoo.org>
dev-vcs/mercurial/Manifest | 1 +
dev-vcs/mercurial/mercurial-4.9.ebuild | 145 +++++++++++++++++++++++++++++++++
2 files changed, 146 insertions(+)
diff --git a/dev-vcs/mercurial/Manifest b/dev-vcs/mercurial/Manifest
index 60dbab87de2..ae4a8075531 100644
--- a/dev-vcs/mercurial/Manifest
+++ b/dev-vcs/mercurial/Manifest
@@ -4,3 +4,4 @@ DIST mercurial-4.7.1.tar.gz 6480135 BLAKE2B de34cdd34d5fa2a6f4e1f24730c99b5764b9
DIST mercurial-4.7.2.tar.gz 6481684 BLAKE2B 1006e541b52148f44b14767a738f4add4d03c719bc6f96f3f245f6bfd401223b1e7444216304fba749b88611cd031cb14089d9938a5533477160226286dd401d SHA512 e8742e9555a6b57e96e61091757b4bcb574605c49082874bd4edb9114a70e5cb024c1360a75c24f1a9ae3bca3205316e6a264ae18d3c9946248bc1d2b042ad43
DIST mercurial-4.8.1.tar.gz 6869733 BLAKE2B 754be4e004af2b62e7ea2cbb1bbe27d4c0f03039e9c4db5ac5e734cb2b13002d7d68a1e2794e2478ce49302f6cb90976bb43bca56a8db7b05eb4ead93a3a46de SHA512 a4485c22f9bb0bb752bf42941f613cb3542c66cbec5d7d49be2090ac544f5dca0f476e4535a56e3f4f4f5fc02fb12739e6d1c7b407264fc2ba4b19b0230b9f93
DIST mercurial-4.8.2.tar.gz 6870985 BLAKE2B 822cbfd09b299870b02b7e181c216557d4dcbb60abcb34a95d22b457f130ff2c84c4f85291b6cd4b0314acd9061ec0d416c96821c2daa8627cd7740965944103 SHA512 1010f20ea5ed081f2d5c58e97696027b2d06dd0471b39e88a1858d5409bcf59f2ccf360925c417495834fccba06e1525ae70894233164d617227814ca2277e20
+DIST mercurial-4.9.tar.gz 7075692 BLAKE2B ed11442e0cd5b27f47394ed1c15016930556d5cdc59ab18f1e0d5371e434eb752b68d3d9f6dd34ed9c63df62a646223e86c6c5178775d9b856eed5df65677900 SHA512 59a5467cebb51f17cce7bcada37f8d85906493ab2e3d443ceeae2c6598fb69d2d59f1e99c73bd08345c5f90501a7bae0d70e04c770ea7653ec30648e591c97fb
diff --git a/dev-vcs/mercurial/mercurial-4.9.ebuild b/dev-vcs/mercurial/mercurial-4.9.ebuild
new file mode 100644
index 00000000000..c2da7946346
--- /dev/null
+++ b/dev-vcs/mercurial/mercurial-4.9.ebuild
@@ -0,0 +1,145 @@
+# Copyright 1999-2019 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=7
+
+PYTHON_COMPAT=( python2_7 )
+PYTHON_REQ_USE="threads"
+
+inherit bash-completion-r1 elisp-common eutils distutils-r1 flag-o-matic
+
+DESCRIPTION="Scalable distributed SCM"
+HOMEPAGE="https://www.mercurial-scm.org/"
+SRC_URI="https://www.mercurial-scm.org/release/${P}.tar.gz"
+
+LICENSE="GPL-2+"
+SLOT="0"
+KEYWORDS="~alpha ~amd64 ~arm ~hppa ~ia64 ~mips ~ppc64 ~sparc ~x86 ~ppc-aix ~x86-fbsd ~amd64-linux ~x86-linux ~ppc-macos ~x64-macos ~x86-macos ~sparc-solaris ~sparc64-solaris ~x64-solaris ~x86-solaris"
+IUSE="bugzilla emacs gpg test tk"
+
+RDEPEND="app-misc/ca-certificates
+ dev-python/zstandard[${PYTHON_USEDEP}]
+ bugzilla? ( dev-python/mysql-python[${PYTHON_USEDEP}] )
+ gpg? ( app-crypt/gnupg )
+ tk? ( dev-lang/tk )"
+
+DEPEND="emacs? ( virtual/emacs )
+ test? ( app-arch/unzip
+ dev-python/pygments[${PYTHON_USEDEP}] )"
+
+SITEFILE="70${PN}-gentoo.el"
+
+PATCHES=(
+ "${FILESDIR}/${PN}-3.0.1-po_fixes.patch"
+ "${FILESDIR}/${PN}-4.8.1-unbundle_zstd.patch"
+)
+
+python_prepare_all() {
+ # fix up logic that won't work in Gentoo Prefix (also won't outside in
+ # certain cases), bug #362891
+ sed -i -e 's:xcodebuild:nocodebuild:' setup.py || die
+
+ # Don't use bundled zstandard (#666972)
+ rm -r contrib/python-zstandard || die
+
+ distutils-r1_python_prepare_all
+}
+
+python_configure_all() {
+ strip-flags -ftracer -ftree-vectorize
+ # Note: make it impl-conditional if py3 is supported
+ append-flags -fno-strict-aliasing
+
+ "${PYTHON}" setup.py build_mo || die
+}
+
+python_compile_all() {
+ rm -r contrib/win32 || die
+ if use emacs; then
+ cd contrib || die
+ elisp-compile mercurial.el || die "elisp-compile failed!"
+ fi
+}
+
+python_install_all() {
+ distutils-r1_python_install_all
+
+ newbashcomp contrib/bash_completion hg
+
+ insinto /usr/share/zsh/site-functions
+ newins contrib/zsh_completion _hg
+
+ rm -f doc/*.?.txt
+ dodoc CONTRIBUTORS
+ cp hgweb*.cgi "${ED}"/usr/share/doc/${PF}/ || die
+
+ dobin hgeditor
+ dobin contrib/hgk
+ python_foreach_impl python_doscript contrib/hg-ssh
+
+ if use emacs; then
+ elisp-install ${PN} contrib/mercurial.el* || die "elisp-install failed!"
+ elisp-site-file-install "${FILESDIR}"/${SITEFILE}
+ fi
+
+ local RM_CONTRIB=( hgk hg-ssh bash_completion zsh_completion wix plan9 *.el )
+ for f in ${RM_CONTRIB[@]}; do
+ rm -r contrib/${f} || die
+ done
+
+ dodoc -r contrib
+ docompress -x /usr/share/doc/${PF}/contrib
+ doman doc/*.?
+
+ insinto /etc/mercurial/hgrc.d
+ doins "${FILESDIR}/cacerts.rc"
+
+ # symlink to system zstd
+ local sitedir=$(python_get_sitedir)
+ dosym ../zstd.so "${sitedir#${EPREFIX}}"/${PN}/zstd.so
+}
+
+src_test() {
+ pushd tests &>/dev/null || die
+ rm -rf *svn* # Subversion tests fail with 1.5
+ rm -f test-archive* # Fails due to verbose tar output changes
+ rm -f test-convert-baz* # GNU Arch baz
+ rm -f test-convert-cvs* # CVS
+ rm -f test-convert-darcs* # Darcs
+ rm -f test-convert-git* # git
+ rm -f test-convert-mtn* # monotone
+ rm -f test-convert-tla* # GNU Arch tla
+ #rm -f test-doctest* # doctest always fails with python 2.5.x
+ rm -f test-largefiles* # tends to time out
+
+ popd &>/dev/null || die
+ distutils-r1_src_test
+}
+
+python_test() {
+ local TEST_DIR
+
+ rm -rf "${TMPDIR}"/test
+ distutils_install_for_testing
+ cd tests || die
+ "${PYTHON}" run-tests.py --verbose \
+ --tmpdir="${TMPDIR}"/test \
+ --with-hg="${TEST_DIR}"/scripts/hg \
+ || die "Tests fail with ${EPYTHON}"
+}
+
+pkg_postinst() {
+ use emacs && elisp-site-regen
+
+ elog "If you want to convert repositories from other tools using convert"
+ elog "extension please install correct tool:"
+ elog " dev-vcs/cvs"
+ elog " dev-vcs/darcs"
+ elog " dev-vcs/git"
+ elog " dev-vcs/monotone"
+ elog " dev-vcs/subversion"
+}
+
+pkg_postrm() {
+ use emacs && elisp-site-regen
+}