[gentoo-commits] repo/gentoo:master commit in: app-crypt/libsecret/

["Mart Raudsepp" <leio@gentoo.org>]

commit:     ed2d7abf54991fb5fbb019a9839a52bdc09c9645
Author:     Mart Raudsepp <leio <AT> gentoo <DOT> org>
AuthorDate: Mon Mar 11 17:19:50 2019 +0000
Commit:     Mart Raudsepp <leio <AT> gentoo <DOT> org>
CommitDate: Mon Mar 11 18:16:09 2019 +0000
URL:        https://gitweb.gentoo.org/repo/gentoo.git/commit/?id=ed2d7abf

app-crypt/libsecret: bump to 0.18.8

Package-Manager: Portage-2.3.52, Repoman-2.3.12
Signed-off-by: Mart Raudsepp <leio <AT> gentoo.org>

 app-crypt/libsecret/Manifest                |  1 +
 app-crypt/libsecret/libsecret-0.18.8.ebuild | 93 +++++++++++++++++++++++++++++
 2 files changed, 94 insertions(+)

diff --git a/app-crypt/libsecret/Manifest b/app-crypt/libsecret/Manifest
index 9ca94283cdf..16183a33672 100644
--- a/app-crypt/libsecret/Manifest
+++ b/app-crypt/libsecret/Manifest
@@ -1,2 +1,3 @@
 DIST libsecret-0.18.6.tar.xz 487836 BLAKE2B d38a41743142d33e634d77bbf55ccab044def9658b3f50bd3f8cec9be6372ad1a56dcc4de58126cba1246c16da2863c003bf14ea6c8a90d8667658cf492f4b9a SHA512 4997519762f1470cfc0a4b3a791362d030af3c9b6ce6f58f8f8073b3a8adeea9b8caacedc884163997081dc39f395f9172330dbb41fed45d6c43ac5809de48e3
 DIST libsecret-0.18.7.tar.xz 508392 BLAKE2B 9774df97c2abb362940c3b373e381afb82ee6af3866cdc18ad52159e824dd9097739d4900eb2dffe117e5b28e2057d0db0cadc3b02e063112309b63fd4d1b870 SHA512 a8890ec52dcfba585fd665ee89e81f4a1d6a04b67bcf4f3422f27973a4ef6fc1281bf54e92160d39dd696ae08a633bab5fe25c1124baf32eb5b414e98ddfa084
+DIST libsecret-0.18.8.tar.xz 509432 BLAKE2B 3e3995d2c44367e31f3914087494764acfe82fb597b524c4982b4fca4e16612509c675f545191ee3cdae59698614395bef54ad82ae88a7e4e19898ba0be7828f SHA512 9e2ec8d458af6ed078bf3c6d956599f73f2cc7720332c424e9aede1f77f3d969c5122cf7b70899bc07ad96a3a628bf79bc5fffa88274d1ef2bcaaca6719f90d4

diff --git a/app-crypt/libsecret/libsecret-0.18.8.ebuild b/app-crypt/libsecret/libsecret-0.18.8.ebuild
new file mode 100644
index 00000000000..b9c94f568b4
--- /dev/null
+++ b/app-crypt/libsecret/libsecret-0.18.8.ebuild
@@ -0,0 +1,93 @@
+# Copyright 1999-2019 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=6
+PYTHON_COMPAT=( python3_{4,5,6} )
+VALA_USE_DEPEND=vapigen
+
+inherit gnome2 multilib-minimal python-any-r1 vala virtualx
+
+DESCRIPTION="GObject library for accessing the freedesktop.org Secret Service API"
+HOMEPAGE="https://wiki.gnome.org/Projects/Libsecret"
+
+LICENSE="LGPL-2.1+ Apache-2.0" # Apache-2.0 license is used for tests only
+SLOT="0"
+
+IUSE="+crypt +introspection test vala"
+# Tests fail with USE=-introspection, https://bugs.gentoo.org/655482
+REQUIRED_USE="test? ( introspection )
+	vala? ( introspection )"
+
+KEYWORDS="~alpha ~amd64 ~arm ~arm64 ~ia64 ~mips ~ppc ~ppc64 ~sparc ~x86 ~amd64-fbsd"
+
+RDEPEND="
+	>=dev-libs/glib-2.44:2[${MULTILIB_USEDEP}]
+	crypt? ( >=dev-libs/libgcrypt-1.2.2:0=[${MULTILIB_USEDEP}] )
+	introspection? ( >=dev-libs/gobject-introspection-1.29:= )
+"
+PDEPEND=">=gnome-base/gnome-keyring-3
+"
+# PDEPEND to avoid circular dep (bug #547456)
+# gnome-keyring needed at runtime as explained at https://bugs.gentoo.org/475182#c2
+# Add ksecrets to PDEPEND when it's added to portage
+DEPEND="${RDEPEND}
+	dev-libs/libxslt
+	dev-util/gdbus-codegen
+	>=dev-util/gtk-doc-am-1.9
+	>=sys-devel/gettext-0.19.8
+	virtual/pkgconfig[${MULTILIB_USEDEP}]
+	test? (
+		$(python_gen_any_dep '
+			dev-python/mock[${PYTHON_USEDEP}]
+			dev-python/dbus-python[${PYTHON_USEDEP}]
+			introspection? ( dev-python/pygobject:3[${PYTHON_USEDEP}] )')
+		introspection? ( >=dev-libs/gjs-1.32 )
+	)
+	vala? ( $(vala_depend) )
+"
+
+python_check_deps() {
+	if use introspection; then
+		has_version --host-root "dev-python/pygobject:3[${PYTHON_USEDEP}]" || return
+	fi
+	has_version --host-root "dev-python/mock[${PYTHON_USEDEP}]" &&
+	has_version --host-root "dev-python/dbus-python[${PYTHON_USEDEP}]"
+}
+
+pkg_setup() {
+	use test && python-any-r1_pkg_setup
+}
+
+src_prepare() {
+	use vala && vala_src_prepare
+	gnome2_src_prepare
+
+	# Drop unwanted CFLAGS modifications
+	sed -e 's/CFLAGS="$CFLAGS -\(g\|O0\|O2\)"//' -i configure || die
+}
+
+multilib_src_configure() {
+	local ECONF_SOURCE=${S}
+	gnome2_src_configure \
+		--enable-manpages \
+		--disable-strict \
+		--disable-coverage \
+		--disable-static \
+		$(use_enable crypt gcrypt) \
+		$(multilib_native_use_enable introspection) \
+		$(multilib_native_use_enable vala) \
+		LIBGCRYPT_CONFIG="${EPREFIX}/usr/bin/${CHOST}-libgcrypt-config"
+
+	if multilib_is_native_abi; then
+		ln -s "${S}"/docs/reference/libsecret/html docs/reference/libsecret/html || die
+	fi
+}
+
+multilib_src_test() {
+	# tests fail without gobject-introspection
+	multilib_is_native_abi && virtx emake check
+}
+
+multilib_src_install() {
+	gnome2_src_install
+}