[gentoo-commits] repo/gentoo:master commit in: dev-libs/appstream/

["Andreas Sturmlechner" <asturm@gentoo.org>]

commit:     31c76bd73f15e38afd5ac189231e8678fe491de5
Author:     Andreas Sturmlechner <asturm <AT> gentoo <DOT> org>
AuthorDate: Sun Mar 10 23:23:12 2019 +0000
Commit:     Andreas Sturmlechner <asturm <AT> gentoo <DOT> org>
CommitDate: Sun Mar 10 23:57:30 2019 +0000
URL:        https://gitweb.gentoo.org/repo/gentoo.git/commit/?id=31c76bd7

dev-libs/appstream: 0.12.6 version bump

Package-Manager: Portage-2.3.62, Repoman-2.3.12
Signed-off-by: Andreas Sturmlechner <asturm <AT> gentoo.org>

 dev-libs/appstream/Manifest                |  1 +
 dev-libs/appstream/appstream-0.12.6.ebuild | 70 ++++++++++++++++++++++++++++++
 2 files changed, 71 insertions(+)

diff --git a/dev-libs/appstream/Manifest b/dev-libs/appstream/Manifest
index be435a028d4..4a56dad69c7 100644
--- a/dev-libs/appstream/Manifest
+++ b/dev-libs/appstream/Manifest
@@ -1,2 +1,3 @@
 DIST AppStream-0.12.3.tar.xz 1940064 BLAKE2B a0160c4a922abfe315bdbfe6b7b32fea8d5eda5631347be4a39dcf102660ad26a3f40c5fed9dd0bdfb1b91956780ff7cf58e61d7f38b03d2f48a5bf67f2871f6 SHA512 3d54bb499e4056d341ffde2878549011708e6699b3ec58756ef2e4080864279ff5e5003224fcbad601007fd9296bb9ed062da7843e3e02272837ecc5d4c802f9
 DIST AppStream-0.12.4.tar.xz 1944416 BLAKE2B 3a315b167084f9f6d8f50a86fa2853444a12beb63e3c7e77bf97c861e1a31dd7fd5ff9c4406d0da1b551b1fbb366531740cd4efdde354b857613507c06eabe62 SHA512 8a7a10b0c577a22b89e0b5505415d5b799f3316b4c87b0a2a9281e7b2672e041225896ac847781504b2828c5ed8a250e3a0558355df838d58e174a984b04e3d0
+DIST AppStream-0.12.6.tar.xz 1953604 BLAKE2B 28b03a935b8c203f2ac2c52c1de8317cc899f2b81b00e83e2eb858dbd185a985ce608ba3f6b1c35f084b4ee91946a4870c89d6b0c0a4c6fd32a938558e3997f1 SHA512 c19cd89ba39aff5afa2ff6d5fca72581a8624463c33011b11036526db98392ff5aa6c0f599682e90fdee29b8732538cf96c20b66965016b96f60b3f899d722bb

diff --git a/dev-libs/appstream/appstream-0.12.6.ebuild b/dev-libs/appstream/appstream-0.12.6.ebuild
new file mode 100644
index 00000000000..2b8019ab068
--- /dev/null
+++ b/dev-libs/appstream/appstream-0.12.6.ebuild
@@ -0,0 +1,70 @@
+# Copyright 1999-2019 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=7
+
+inherit meson xdg-utils
+
+if [[ ${PV} = *9999* ]]; then
+	inherit git-r3
+	EGIT_REPO_URI="https://github.com/ximion/${PN}"
+else
+	MY_PN="AppStream"
+	SRC_URI="https://www.freedesktop.org/software/appstream/releases/${MY_PN}-${PV}.tar.xz"
+	KEYWORDS="~amd64 ~arm ~arm64 ~x86"
+	S="${WORKDIR}/${MY_PN}-${PV}"
+fi
+
+DESCRIPTION="Cross-distro effort for providing metadata for software in the Linux ecosystem"
+HOMEPAGE="https://www.freedesktop.org/wiki/Distributions/AppStream/"
+
+LICENSE="LGPL-2.1+ GPL-2+"
+# check as_api_level
+SLOT="0/4"
+IUSE="apt +introspection qt5 test"
+
+BDEPEND="
+	app-text/docbook-xml-dtd:4.5
+	dev-libs/appstream-glib
+	dev-util/itstool
+	>=dev-util/meson-0.42.0
+	>=sys-devel/gettext-0.19.8
+	test? (
+		dev-qt/linguist-tools:5
+		qt5? ( dev-qt/qttest:5 )
+	)
+"
+DEPEND="
+	>=dev-libs/glib-2.54:2
+	dev-libs/libxml2:2
+	dev-libs/libyaml
+	dev-libs/snowball-stemmer
+	introspection? ( >=dev-libs/gobject-introspection-1.56:= )
+	qt5? ( dev-qt/qtcore:5 )
+"
+RDEPEND="${DEPEND}"
+
+src_prepare() {
+	default
+	sed -e "/^as_doc_target_dir/s/appstream/${PF}/" -i docs/meson.build || die
+	if ! use test; then
+		sed -e "/^subdir.*tests/s/^/#DONT /" -i {,qt/}meson.build || die # bug 675944
+	fi
+}
+
+src_configure() {
+	xdg_environment_reset
+
+	local emesonargs=(
+		-Dapidocs=false
+		-Ddocs=false
+		-Dmaintainer=false
+		-Dstemming=true
+		-Dvapi=false
+		-Dapt-support=$(usex apt true false)
+		-Dgir=$(usex introspection true false)
+		-Dqt=$(usex qt5 true false)
+	)
+
+	meson_src_configure
+}