[gentoo-commits] proj/sci:master commit in: sci-mathematics/slepc/

["Matthias Maier" <tamiko@gentoo.org>]

commit:     adbc744f06cd4ea9f381b0688fe88d88499344d9
Author:     Matthias Maier <tamiko <AT> gentoo <DOT> org>
AuthorDate: Sat Mar  9 05:42:40 2019 +0000
Commit:     Matthias Maier <tamiko <AT> gentoo <DOT> org>
CommitDate: Sat Mar  9 06:07:11 2019 +0000
URL:        https://gitweb.gentoo.org/proj/sci.git/commit/?id=adbc744f

sci-mathematics/slepc: version bump to 3.10.2

Package-Manager: Portage-2.3.62, Repoman-2.3.12
Signed-off-by: Matthias Maier <tamiko <AT> gentoo.org>

 sci-mathematics/slepc/slepc-3.10.2.ebuild | 74 +++++++++++++++++++++++++++++++
 1 file changed, 74 insertions(+)

diff --git a/sci-mathematics/slepc/slepc-3.10.2.ebuild b/sci-mathematics/slepc/slepc-3.10.2.ebuild
new file mode 100644
index 000000000..2009090c1
--- /dev/null
+++ b/sci-mathematics/slepc/slepc-3.10.2.ebuild
@@ -0,0 +1,74 @@
+# Copyright 1999-2019 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=6
+
+PYTHON_COMPAT=( python2_7 )
+
+inherit eutils flag-o-matic python-any-r1 toolchain-funcs versionator
+
+DESCRIPTION="Scalable Library for Eigenvalue Problem Computations"
+HOMEPAGE="http://slepc.upv.es/"
+SRC_URI="http://slepc.upv.es/download/distrib/${P}.tar.gz"
+
+LICENSE="LGPL-3"
+SLOT="0"
+KEYWORDS="~amd64 ~x86"
+IUSE="complex-scalars doc mpi"
+
+PETSC_PV="$(get_version_component_range 1-2 ${PV})"
+RDEPEND="
+	=sci-mathematics/petsc-${PETSC_PV}*:=[mpi=,complex-scalars=]
+	sci-libs/arpack[mpi=]
+	mpi? ( virtual/mpi )
+"
+
+DEPEND="${RDEPEND}
+	${PYTHON_DEPS}
+	virtual/pkgconfig
+	dev-util/cmake
+"
+
+MAKEOPTS="${MAKEOPTS} -j1 V=1"
+
+src_prepare() {
+	default
+
+	sed -i -e 's%/usr/bin/env python%/usr/bin/env python2%' configure || die
+}
+
+src_configure() {
+	# *sigh*
+	addpredict "${PETSC_DIR}"/.nagged
+
+	# Make sure that the environment is set up correctly:
+	unset PETSC_DIR
+	unset PETSC_ARCH
+	unset SLEPC_DIR
+	source "${EPREFIX}"/etc/env.d/99petsc
+	export PETSC_DIR
+
+	# configure is a custom python script and doesn't want to have default
+	# configure arguments that we set with econf
+	./configure \
+		--prefix="${EPREFIX}/usr/$(get_libdir)/slepc" \
+		--with-arpack=1 \
+		--with-arpack-dir="${EPREFIX}/usr/$(get_libdir)" \
+		--with-arpack-flags="$(usex mpi "-lparpack,-larpack" "-larpack")"
+
+}
+
+src_install() {
+	emake SLEPC_DESTDIR="${D}/usr/$(get_libdir)/slepc" install
+
+	# add PETSC_DIR to environmental variables
+	cat >> 99slepc <<- EOF
+		SLEPC_DIR=${EPREFIX}/usr/$(get_libdir)/slepc
+	EOF
+	doenvd 99slepc
+
+	if use doc ; then
+		dodoc docs/slepc.pdf
+		dohtml -r docs/*.html docs/manualpages
+	fi
+}