[gentoo-commits] repo/gentoo:master commit in: dev-libs/swayidle/

["Aaron Bauman" <bman@gentoo.org>]

commit:     39e359ccdec4a27c54e53271d6561bd885de7d1e
Author:     Niccolò Scatena <speedjack95 <AT> gmail <DOT> com>
AuthorDate: Sat Feb  9 16:32:49 2019 +0000
Commit:     Aaron Bauman <bman <AT> gentoo <DOT> org>
CommitDate: Wed Feb 13 00:04:17 2019 +0000
URL:        https://gitweb.gentoo.org/repo/gentoo.git/commit/?id=39e359cc

dev-libs/swayidle: Add 9999 live version

Package-Manager: Portage-2.3.59, Repoman-2.3.12
Signed-off-by: Niccolò Scatena <speedjack95 <AT> gmail.com>
Signed-off-by: Aaron Bauman <bman <AT> gentoo.org>

 dev-libs/swayidle/swayidle-9999.ebuild | 57 ++++++++++++++++++++++++++++++++++
 1 file changed, 57 insertions(+)

diff --git a/dev-libs/swayidle/swayidle-9999.ebuild b/dev-libs/swayidle/swayidle-9999.ebuild
new file mode 100644
index 00000000000..774758c9815
--- /dev/null
+++ b/dev-libs/swayidle/swayidle-9999.ebuild
@@ -0,0 +1,57 @@
+# Copyright 1999-2019 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=7
+
+inherit meson
+
+DESCRIPTION="Idle management daemon for Wayland"
+HOMEPAGE="https://github.com/swaywm/swayidle"
+
+if [[ ${PV} == 9999 ]]; then
+	inherit git-r3
+	EGIT_REPO_URI="https://github.com/swaywm/${PN}.git"
+else
+	SRC_URI="https://github.com/swaywm/${PN}/archive/${PV}.tar.gz -> ${P}.tar.gz"
+	KEYWORDS="~amd64 ~x86"
+fi
+
+LICENSE="MIT"
+SLOT="0"
+IUSE="elogind fish-completion +man systemd zsh-completion"
+REQUIRED_USE="?? ( elogind systemd )"
+
+DEPEND="
+	dev-libs/wayland
+	elogind? ( >=sys-auth/elogind-237[policykit] )
+	systemd? ( >=sys-apps/systemd-237[policykit] )
+"
+RDEPEND="
+	${DEPEND}
+	!<=dev-libs/sway-1.0_beta1
+	!~dev-libs/sway-1.0_beta2[swayidle]
+"
+BDEPEND="
+	>=dev-libs/wayland-protocols-1.14
+	virtual/pkgconfig
+	man? ( app-text/scdoc )
+"
+
+src_configure() {
+	local emesonargs=(
+		-Dman-pages=$(usex man enabled disabled)
+		$(meson_use fish-completion fish-completions)
+		$(meson_use zsh-completion zsh-completions)
+		"-Dbash-completions=true"
+		"-Dwerror=false"
+	)
+	if use systemd; then
+		emesonargs+=("-Dlogind=enabled" "-Dlogind-provider=systemd")
+	elif use elogind; then
+		emesonargs+=("-Dlogind=enabled" "-Dlogind-provider=elogind")
+	else
+		emesonargs+=("-Dlogind=disabled")
+	fi
+
+	meson_src_configure
+}