[gentoo-commits] repo/gentoo:master commit in: media-sound/exaile/

["Andreas Sturmlechner" <asturm@gentoo.org>]

commit:     b09dc87fc6873c1f03208a7bc907d3cccc288ec1
Author:     Andreas Sturmlechner <asturm <AT> gentoo <DOT> org>
AuthorDate: Tue Feb  5 22:31:31 2019 +0000
Commit:     Andreas Sturmlechner <asturm <AT> gentoo <DOT> org>
CommitDate: Tue Feb  5 23:26:42 2019 +0000
URL:        https://gitweb.gentoo.org/repo/gentoo.git/commit/?id=b09dc87f

media-sound/exaile: 4.0.0_rc3 version bump, EAPI-7 bump

Fix DESCRIPTION
Use https

Thanks-to: Simon <sur3 <AT> gmx.de>
Thanks-to: Sander Sweers <Sander.Sweers <AT> gmail.com>
Bug: https://bugs.gentoo.org/621900
Package-Manager: Portage-2.3.59, Repoman-2.3.12
Signed-off-by: Andreas Sturmlechner <asturm <AT> gentoo.org>

 media-sound/exaile/Manifest                |  1 +
 media-sound/exaile/exaile-4.0.0_rc3.ebuild | 79 ++++++++++++++++++++++++++++++
 media-sound/exaile/metadata.xml            |  3 ++
 3 files changed, 83 insertions(+)

diff --git a/media-sound/exaile/Manifest b/media-sound/exaile/Manifest
index bdbf1924d7f..d0dee184a36 100644
--- a/media-sound/exaile/Manifest
+++ b/media-sound/exaile/Manifest
@@ -1 +1,2 @@
 DIST exaile-3.4.5.tar.gz 3662446 BLAKE2B 13343a5468a4f7f309e173e5195d356d62e10efc20c99cc70a1f0215fafa073eeec19b4e35ae52e11a62575a72263ad11ebdf105fcdd066654f8d6c2b1ff6864 SHA512 9337b86ed2f6a13071615bd46a7a05a6564011a4e1fef4cb42925336864c07854cfe497d8defe65c4e287fd9546de6a51543180c5ce6a84525506e57209914be
+DIST exaile-4.0.0rc3.tar.gz 3627782 BLAKE2B 1c986309798d4cb78969a7443e4c29e02ca3a9c8e316264641ffafe97dd46b6a1745988230c13469ce2d9c37aadf7b07eee5bcd5836f33b1b2d25e3ebb69f574 SHA512 d3822a7d88934c90a2856074f177a346b19896ecca54f33e7506d37a0b25170983c057feaae162c2685780e7f0d1a6edc8ce7addbcc04cacf2d2b25e0c9f36de

diff --git a/media-sound/exaile/exaile-4.0.0_rc3.ebuild b/media-sound/exaile/exaile-4.0.0_rc3.ebuild
new file mode 100644
index 00000000000..f3e1373fd4a
--- /dev/null
+++ b/media-sound/exaile/exaile-4.0.0_rc3.ebuild
@@ -0,0 +1,79 @@
+# Copyright 1999-2019 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=7
+
+PYTHON_COMPAT=( python2_7 )
+PYTHON_REQ_USE="sqlite"
+inherit python-single-r1 xdg-utils
+
+if [[ ${PV} = *9999* ]]; then
+	inherit git-r3
+	EGIT_REPO_URI="https://github.com/exaile/exaile.git"
+else
+	SRC_URI="https://github.com/${PN}/${PN}/releases/download/${PV/_/-}/${PN}-${PV/_/}.tar.gz"
+	KEYWORDS="~amd64 ~sparc ~x86"
+	S="${WORKDIR}/${PN}-${PV/_/}"
+fi
+
+DESCRIPTION="GTK+ based media player aiming to be similar to Amarok"
+HOMEPAGE="https://www.exaile.org/"
+
+LICENSE="GPL-2 GPL-3"
+SLOT="0"
+IUSE="cddb libnotify nls scrobbler"
+REQUIRED_USE="${PYTHON_REQUIRED_USE}"
+
+RDEPEND="${PYTHON_DEPS}
+	dev-libs/gobject-introspection[${PYTHON_USEDEP}]
+	dev-python/bsddb3[${PYTHON_USEDEP}]
+	dev-python/dbus-python[${PYTHON_USEDEP}]
+	dev-python/gst-python:1.0[${PYTHON_USEDEP}]
+	dev-python/pycairo[${PYTHON_USEDEP}]
+	>=dev-python/pygobject-3.13.2:3[${PYTHON_USEDEP}]
+	>=media-libs/gst-plugins-base-1.6:1.0
+	>=media-libs/gst-plugins-good-1.4:1.0
+	>=media-libs/mutagen-1.10[${PYTHON_USEDEP}]
+	media-plugins/gst-plugins-meta:1.0
+	>=x11-libs/gtk+-3.10:3[introspection]
+	cddb? ( dev-python/cddb-py )
+	libnotify? ( dev-python/notify-python[${PYTHON_USEDEP}] )
+	scrobbler? ( dev-python/pylast[${PYTHON_USEDEP}] )
+"
+BDEPEND="
+	nls? (
+		dev-util/intltool
+		sys-devel/gettext
+	)
+"
+
+RESTRICT="test" #315589
+
+pkg_setup() {
+	python-single-r1_pkg_setup
+}
+
+src_compile() {
+	use nls && emake locale
+}
+
+src_install() {
+	emake \
+		PREFIX=/usr \
+		LIBINSTALLDIR=/usr/$(get_libdir) \
+		DESTDIR="${D}" \
+		install$(use nls || echo _no_locale)
+
+	python_optimize "${D}/usr/$(get_libdir)/${PN}"
+	python_optimize "${D}/usr/share/${PN}"
+}
+
+pkg_postinst() {
+	xdg_desktop_database_update
+	xdg_mimeinfo_database_update
+}
+
+pkg_postrm() {
+	xdg_desktop_database_update
+	xdg_mimeinfo_database_update
+}

diff --git a/media-sound/exaile/metadata.xml b/media-sound/exaile/metadata.xml
index 3f99551b683..56d330882f0 100644
--- a/media-sound/exaile/metadata.xml
+++ b/media-sound/exaile/metadata.xml
@@ -9,4 +9,7 @@
 		<remote-id type="launchpad">exaile</remote-id>
 		<remote-id type="github">exaile/exaile</remote-id>
 	</upstream>
+	<use>
+		<flag name="scrobbler">Enable audioscrobbler/last.fm support</flag>
+	</use>
 </pkgmetadata>