[gentoo-commits] repo/gentoo:master commit in: media-sound/clementine/

["Andreas Sturmlechner" <asturm@gentoo.org>]

commit:     f17ffe255aedfc5c0cc471cc716a9d897128cba1
Author:     Andreas Sturmlechner <asturm <AT> gentoo <DOT> org>
AuthorDate: Wed Jan 30 17:33:15 2019 +0000
Commit:     Andreas Sturmlechner <asturm <AT> gentoo <DOT> org>
CommitDate: Wed Jan 30 22:29:24 2019 +0000
URL:        https://gitweb.gentoo.org/repo/gentoo.git/commit/?id=f17ffe25

media-sound/clementine: 1.3.1_p20190127 snapshot bump

Patch upstreamed in that version.

Package-Manager: Portage-2.3.59, Repoman-2.3.12
Signed-off-by: Andreas Sturmlechner <asturm <AT> gentoo.org>

 media-sound/clementine/Manifest                    |   1 +
 .../clementine/clementine-1.3.1_p20190127.ebuild   | 180 +++++++++++++++++++++
 2 files changed, 181 insertions(+)

diff --git a/media-sound/clementine/Manifest b/media-sound/clementine/Manifest
index 20346bcffb3..6e52851f4d7 100644
--- a/media-sound/clementine/Manifest
+++ b/media-sound/clementine/Manifest
@@ -1,2 +1,3 @@
 DIST clementine-1.3.1_p20180416.tar.gz 8489387 BLAKE2B 37412428cf030a71f0011ba68a7ce71a3bbdc59402dc6d6349cca8ee44b208052cee9add1597a9577e5a6ed4bb2ebf16c4e1f79612d12be265f637caffd02a76 SHA512 8f38554571c637d9f79df43679ac2a76383f7a9b4ee8e921a16175889180e72afadc352dd40d73a671aa8ae9b01f6a251ae7b94b010043f8bcb8d8f42dcfff62
 DIST clementine-1.3.1_p20181201.tar.gz 8535075 BLAKE2B c4b6660ee9718054cc13c6b4fc2e1dccf9c117319f5b682dc5de2861fc40cc129e079449e1c2e15733faf14b6e18b42f37c228000a8e6c121b7fdcb2e48bc7b9 SHA512 fcc062857b95a5cabc41449143bb876df9955cdaaa59868f147d7a165dea13e2e4e1c11ea23f4309c8af7bef42d694a82867420245513af8e4dfbd91ab6f9a2c
+DIST clementine-1.3.1_p20190127.tar.gz 8516435 BLAKE2B ce884c25d76e26349cf11109f885361dd79c4d567b08927962a611a2bb17dbe6674ac176f6b09b3a8ebe14e82f30125a56ffd08ff6d2072a96ee7b9ba1f066db SHA512 b82d2dc49dbe41e68440fb421cda6989f670a2a43829bf42e21f3c07d6f6badcb217333559d6dd9c66accd88e2473e5c717969e987410bf4801669dccba7cd15

diff --git a/media-sound/clementine/clementine-1.3.1_p20190127.ebuild b/media-sound/clementine/clementine-1.3.1_p20190127.ebuild
new file mode 100644
index 00000000000..e80f66f40cc
--- /dev/null
+++ b/media-sound/clementine/clementine-1.3.1_p20190127.ebuild
@@ -0,0 +1,180 @@
+# Copyright 1999-2019 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=6
+
+PLOCALES="af ar be bg bn br bs ca cs cy da de el en en_CA en_GB eo es et eu fa fi fr ga gl he he_IL hi hr hu hy ia id is it ja ka kk ko lt lv mk_MK mr ms my nb nl oc pa pl pt pt_BR ro ru si_LK sk sl sr sr@latin sv te tr tr_TR uk uz vi zh_CN zh_TW"
+
+MY_P="${P/_}"
+if [[ ${PV} == *9999* ]]; then
+	EGIT_BRANCH="qt5"
+	EGIT_REPO_URI="https://github.com/clementine-player/Clementine.git"
+	GIT_ECLASS="git-r3"
+else
+	COMMIT=610566d25271c67d1625fd62041f6a27435b0a9d
+	SRC_URI="https://github.com/${PN}-player/${PN^}/archive/${COMMIT}.tar.gz -> ${P}.tar.gz"
+	KEYWORDS="~amd64 ~x86"
+fi
+inherit cmake-utils flag-o-matic gnome2-utils l10n virtualx xdg-utils ${GIT_ECLASS}
+unset GIT_ECLASS
+
+DESCRIPTION="Modern music player and library organizer based on Amarok 1.4 and Qt"
+HOMEPAGE="https://www.clementine-player.org https://github.com/clementine-player/Clementine"
+
+LICENSE="GPL-3"
+SLOT="0"
+IUSE="box cdda +dbus debug dropbox googledrive ipod lastfm mms moodbar mtp projectm pulseaudio seafile skydrive test +udisks wiimote"
+
+REQUIRED_USE="
+	udisks? ( dbus )
+	wiimote? ( dbus )
+"
+
+COMMON_DEPEND="
+	app-crypt/qca:2[qt5(+)]
+	dev-db/sqlite:=
+	dev-libs/crypto++[asm]
+	dev-libs/glib:2
+	dev-libs/libxml2
+	dev-libs/protobuf:=
+	dev-qt/qtconcurrent:5
+	dev-qt/qtcore:5
+	dev-qt/qtgui:5
+	dev-qt/qtnetwork:5[ssl]
+	dev-qt/qtsql:5[sqlite]
+	dev-qt/qtwidgets:5
+	media-libs/chromaprint:=
+	media-libs/gstreamer:1.0
+	media-libs/gst-plugins-base:1.0
+	>=media-libs/libmygpo-qt-1.0.9[qt5(+)]
+	>=media-libs/taglib-1.11.1_p20181028
+	sys-libs/zlib
+	virtual/glu
+	x11-libs/libX11
+	cdda? ( dev-libs/libcdio:= )
+	dbus? ( dev-qt/qtdbus:5 )
+	ipod? ( >=media-libs/libgpod-0.8.0 )
+	lastfm? ( >=media-libs/liblastfm-1.1.0_pre20150206 )
+	moodbar? ( sci-libs/fftw:3.0 )
+	mtp? ( >=media-libs/libmtp-1.0.0 )
+	projectm? (
+		media-libs/glew:=
+		>=media-libs/libprojectm-1.2.0
+		virtual/opengl
+	)
+"
+# Note: sqlite driver of dev-qt/qtsql is bundled, so no sqlite use is required; check if this can be overcome someway;
+# Libprojectm-1.2 seems to work fine, so no reason to use bundled version; check clementine's patches:
+# https://github.com/clementine-player/Clementine/tree/master/3rdparty/libprojectm/patches
+# Still possibly essential but not applied yet patches are:
+# 06-fix-numeric-locale.patch
+# 08-stdlib.h-for-rand.patch
+RDEPEND="${COMMON_DEPEND}
+	media-plugins/gst-plugins-meta:1.0
+	media-plugins/gst-plugins-soup:1.0
+	media-plugins/gst-plugins-taglib:1.0
+	mms? ( media-plugins/gst-plugins-libmms:1.0 )
+	mtp? ( gnome-base/gvfs[mtp] )
+	udisks? ( sys-fs/udisks:2 )
+"
+DEPEND="${COMMON_DEPEND}
+	>=dev-cpp/gtest-1.8.0
+	dev-libs/boost
+	dev-qt/linguist-tools:5
+	dev-qt/qtx11extras:5
+	dev-qt/qtxml:5
+	sys-devel/gettext
+	virtual/pkgconfig
+	box? ( dev-cpp/sparsehash )
+	dropbox? ( dev-cpp/sparsehash )
+	googledrive? ( dev-cpp/sparsehash )
+	projectm? ( dev-qt/qtopengl:5 )
+	pulseaudio? ( media-sound/pulseaudio )
+	seafile? ( dev-cpp/sparsehash )
+	skydrive? ( dev-cpp/sparsehash )
+	test? (
+		dev-qt/qttest:5
+		gnome-base/gsettings-desktop-schemas
+	)
+"
+
+RESTRICT="test"
+
+S="${WORKDIR}/${PN^}-${COMMIT}"
+
+DOCS=( Changelog README.md )
+
+src_prepare() {
+	l10n_find_plocales_changes "src/translations" "" ".po"
+
+	cmake-utils_src_prepare
+	# some tests fail or hang
+	sed -i \
+		-e '/add_test_file(translations_test.cpp/d' \
+		tests/CMakeLists.txt || die
+
+	if ! use test; then
+		sed -e "/find_package.*Qt5/s:\ Test::" -i CMakeLists.txt || die
+		cmake_comment_add_subdirectory tests
+	fi
+
+	rm -r 3rdparty/{libmygpo-qt,libmygpo-qt5,taglib} || die
+}
+
+src_configure() {
+	# spotify is not in portage
+	local mycmakeargs=(
+		-DBUILD_WERROR=OFF
+		# force to find crypto++ see bug #548544
+		-DCRYPTOPP_LIBRARIES="cryptopp"
+		-DCRYPTOPP_FOUND=ON
+		# avoid automagically enabling of ccache (bug #611010)
+		-DCCACHE_EXECUTABLE=OFF
+		-DENABLE_BREAKPAD=OFF  #< disable crash reporting
+		-DENABLE_DEVICEKIT=OFF
+		-DENABLE_GIO=ON
+		-DENABLE_SPOTIFY_BLOB=OFF
+		-DUSE_SYSTEM_GMOCK=ON
+		-DUSE_SYSTEM_PROJECTM=ON
+		-DBUNDLE_PROJECTM_PRESETS=OFF
+		-DLINGUAS="$(l10n_get_locales)"
+		-DENABLE_BOX="$(usex box)"
+		-DENABLE_AUDIOCD="$(usex cdda)"
+		-DCMAKE_DISABLE_FIND_PACKAGE_Qt5DBus=$(usex !dbus)
+		-DENABLE_DROPBOX="$(usex dropbox)"
+		-DENABLE_GOOGLE_DRIVE="$(usex googledrive)"
+		-DENABLE_LIBGPOD="$(usex ipod)"
+		-DENABLE_LIBLASTFM="$(usex lastfm)"
+		-DENABLE_MOODBAR="$(usex moodbar)"
+		-DENABLE_LIBMTP="$(usex mtp)"
+		-DENABLE_VISUALISATIONS="$(usex projectm)"
+		-DENABLE_SEAFILE="$(usex seafile)"
+		-DENABLE_SKYDRIVE="$(usex skydrive)"
+		-DENABLE_LIBPULSE="$(usex pulseaudio)"
+		-DENABLE_UDISKS2="$(usex udisks)"
+		-DENABLE_WIIMOTEDEV="$(usex wiimote)"
+	)
+
+	use !debug && append-cppflags -DQT_NO_DEBUG_OUTPUT
+
+	cmake-utils_src_configure
+}
+
+src_test() {
+	cd "${CMAKE_BUILD_DIR}" || die
+	virtx emake test
+}
+
+pkg_postinst() {
+	xdg_desktop_database_update
+	gnome2_icon_cache_update
+
+	elog "Note that list of supported formats is controlled by media-plugins/gst-plugins-meta "
+	elog "USE flags. You may be interested in setting aac, flac, mp3, ogg or wavpack USE flags "
+	elog "depending on your preferences"
+}
+
+pkg_postrm() {
+	xdg_desktop_database_update
+	gnome2_icon_cache_update
+}