[gentoo-commits] repo/gentoo:master commit in: gnome-extra/gnome-boxes/

["Mart Raudsepp" <leio@gentoo.org>]

commit:     b99ccc5e6df439ca83895ced05527d738a314a3b
Author:     Mart Raudsepp <leio <AT> gentoo <DOT> org>
AuthorDate: Wed Jan 23 11:30:50 2019 +0000
Commit:     Mart Raudsepp <leio <AT> gentoo <DOT> org>
CommitDate: Wed Jan 23 11:30:50 2019 +0000
URL:        https://gitweb.gentoo.org/repo/gentoo.git/commit/?id=b99ccc5e

gnome-extra/gnome-boxes: bump to 3.26.4

Bug: https://bugs.gentoo.org/673186
Package-Manager: Portage-2.3.52, Repoman-2.3.12
Signed-off-by: Mart Raudsepp <leio <AT> gentoo.org>

 gnome-extra/gnome-boxes/Manifest                  |   1 +
 gnome-extra/gnome-boxes/gnome-boxes-3.26.4.ebuild | 106 ++++++++++++++++++++++
 2 files changed, 107 insertions(+)

diff --git a/gnome-extra/gnome-boxes/Manifest b/gnome-extra/gnome-boxes/Manifest
index 2fcee534bcf..ef813bdf02f 100644
--- a/gnome-extra/gnome-boxes/Manifest
+++ b/gnome-extra/gnome-boxes/Manifest
@@ -1 +1,2 @@
 DIST gnome-boxes-3.24.1.tar.xz 1710348 BLAKE2B ce90cc1a6baefa45c1a553b059f4fa7ac5c9a6fbd7a2d71377a9c6f38fddb7ac5a110f38d0a65b45cf2ba948ebee6026cc22b5f93a2ba521c9db6cb20bd3dc37 SHA512 a687dd65af91d717862bba0a81d715b64de1092cbb5ffd8a756fe80988c84110127f186007e8cf4011bf23cc0ec0adb346ead72ef47c655f85a7fcb9ed3ec393
+DIST gnome-boxes-3.26.4.tar.xz 1893760 BLAKE2B 91d01f33b2fb03150c0abd75cb58a9a9ecd8deeb14d32502f5766e06c93b4d236f971417e0a26c44e1250afa069966b607912f2dde92fc5058e598eb029ff03b SHA512 f92f09ea6f61d418253b3b4388bc7aac321cbbba853908b3a8e4faca0e04287cc7c3387eefdd2e150bc9dace8ef5ebbbab3dc3b38b26e0e2d010272703fbf6a3

diff --git a/gnome-extra/gnome-boxes/gnome-boxes-3.26.4.ebuild b/gnome-extra/gnome-boxes/gnome-boxes-3.26.4.ebuild
new file mode 100644
index 00000000000..bfb069b4f2d
--- /dev/null
+++ b/gnome-extra/gnome-boxes/gnome-boxes-3.26.4.ebuild
@@ -0,0 +1,106 @@
+# Copyright 1999-2019 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=6
+VALA_USE_DEPEND="vapigen"
+VALA_MIN_API_VERSION="0.36"
+
+inherit gnome2 linux-info readme.gentoo-r1 vala
+
+DESCRIPTION="Simple GNOME 3 application to access remote or virtual systems"
+HOMEPAGE="https://wiki.gnome.org/Apps/Boxes"
+
+LICENSE="LGPL-2+"
+SLOT="0"
+
+# We force 'bindist' due to licenses from gnome-boxes-nonfree
+IUSE="" #bindist
+
+KEYWORDS="~amd64"
+
+# NOTE: sys-fs/* stuff is called via exec()
+# FIXME: ovirt is not available in tree
+# FIXME: use vala.eclass but only because of libgd not being able
+#        to use its pre-generated files so do not copy all the
+#        vala deps like live ebuild has.
+# FIXME: qemu probably needs to depend on spice[smartcard]
+#        directly with USE=spice
+# tracker-2 is supported, but we don't have the USE=iso replacement in main tree yet to depend on
+RDEPEND="
+	>=app-arch/libarchive-3:=
+	>=dev-libs/glib-2.52:2
+	>=dev-libs/gobject-introspection-0.9.6:=
+	>=dev-libs/libxml2-2.7.8:2
+	>=sys-libs/libosinfo-0.2.12
+	>=app-emulation/qemu-1.3.1[spice,smartcard,usbredir]
+	>=app-emulation/libvirt-0.9.3[libvirtd,qemu]
+	>=app-emulation/libvirt-glib-0.2.3
+	>=x11-libs/gtk+-3.19.8:3
+	>=net-libs/gtk-vnc-0.4.4[gtk3(+)]
+	app-crypt/libsecret
+	app-emulation/spice[smartcard]
+	>=net-misc/spice-gtk-0.32[gtk3(+),smartcard,usbredir]
+	virtual/libusb:1
+
+	app-misc/tracker:0/100[iso]
+
+	>=net-libs/libsoup-2.44:2.4
+
+	sys-fs/mtools
+	>=virtual/libgudev-165:=
+"
+#	!bindist? ( gnome-extra/gnome-boxes-nonfree )
+
+DEPEND="${RDEPEND}
+	$(vala_depend)
+	dev-util/itstool
+	>=sys-devel/gettext-0.19.8
+	virtual/pkgconfig
+"
+# eautoreconf needs yelp-tools
+
+DISABLE_AUTOFORMATTING="yes"
+DOC_CONTENTS="Before running gnome-boxes, you will need to load the KVM modules.
+If you have an Intel Processor, run:
+# modprobe kvm-intel
+
+If you have an AMD Processor, run:
+# modprobe kvm-amd"
+
+pkg_pretend() {
+	linux-info_get_any_version
+
+	if linux_config_exists; then
+		if ! { linux_chkconfig_present KVM_AMD || \
+			linux_chkconfig_present KVM_INTEL; }; then
+			ewarn "You need KVM support in your kernel to use GNOME Boxes local support!"
+		fi
+	fi
+}
+
+src_prepare() {
+	# Do not change CFLAGS, wondering about VALA ones but appears to be
+	# needed as noted in configure comments below
+	sed 's/CFLAGS="$CFLAGS -O0 -ggdb3"//' -i configure{.ac,} || die
+
+	vala_src_prepare
+	gnome2_src_prepare
+}
+
+src_configure() {
+	# debug needed for splitdebug proper behavior (cardoe), bug #????
+	gnome2_src_configure \
+		--enable-debug \
+		--disable-strict-cc \
+		--disable-ovirt
+}
+
+src_install() {
+	gnome2_src_install
+	readme.gentoo_create_doc
+}
+
+pkg_postinst() {
+	gnome2_pkg_postinst
+	readme.gentoo_print_elog
+}