[gentoo-commits] repo/gentoo:master commit in: net-misc/rygel/

["Mart Raudsepp" <leio@gentoo.org>]

commit:     ef7c584f8113d2f94a4e620f080d0dc56f188c8c
Author:     Mart Raudsepp <leio <AT> gentoo <DOT> org>
AuthorDate: Tue Jan 22 16:37:12 2019 +0000
Commit:     Mart Raudsepp <leio <AT> gentoo <DOT> org>
CommitDate: Tue Jan 22 16:40:00 2019 +0000
URL:        https://gitweb.gentoo.org/repo/gentoo.git/commit/?id=ef7c584f

net-misc/rygel: bump to 0.36.2

This version is buildable against both tracker APIs (1.0 and 2.0)

Package-Manager: Portage-2.3.52, Repoman-2.3.12
Signed-off-by: Mart Raudsepp <leio <AT> gentoo.org>

 net-misc/rygel/Manifest            |  1 +
 net-misc/rygel/rygel-0.36.2.ebuild | 80 ++++++++++++++++++++++++++++++++++++++
 2 files changed, 81 insertions(+)

diff --git a/net-misc/rygel/Manifest b/net-misc/rygel/Manifest
index d1c06eb88eb..bf851879f11 100644
--- a/net-misc/rygel/Manifest
+++ b/net-misc/rygel/Manifest
@@ -1 +1,2 @@
 DIST rygel-0.34.0.tar.xz 3997364 BLAKE2B 2906bcdea61caddd93a7fa0363c7957ce3c0443581a625b40712d2c75f25d05c693b745f72392c917190f754533c03c524fefa80799a5e8163f44eb22c1d33da SHA512 90e582f42e73376bbe6b06f33d44c6a70969961728dc512523bcc578b5b7c3f826cb425b469ade87d3fdf82117309f8589c30b1cdd8ba74cc14424c7f2efdb21
+DIST rygel-0.36.2.tar.xz 4057356 BLAKE2B 3ff1a0df12cdda694ded3a9a5c6d1495eaf0dff7133cbc84b73ad6bc767cd3a5e31ff8b579aff9c0de455f149e49dc972f7d93d64424d25501b02f2a02f66552 SHA512 8c079f83a00c9ad237b634e6274d27acc94a91adfa2829f0336b2485aa801e6898c30ec7268352247f1d12232d9ab3cb7a6f8215370f03aaff5323c4a8fdff7f

diff --git a/net-misc/rygel/rygel-0.36.2.ebuild b/net-misc/rygel/rygel-0.36.2.ebuild
new file mode 100644
index 00000000000..7b6f937be84
--- /dev/null
+++ b/net-misc/rygel/rygel-0.36.2.ebuild
@@ -0,0 +1,80 @@
+# Copyright 1999-2019 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=6
+GNOME2_LA_PUNT="yes"
+
+inherit gnome2 systemd virtualx
+
+DESCRIPTION="Rygel is an open source UPnP/DLNA MediaServer"
+HOMEPAGE="https://wiki.gnome.org/Projects/Rygel"
+
+LICENSE="LGPL-2.1+ CC-BY-SA-3.0"
+SLOT="0"
+KEYWORDS="~amd64 ~x86"
+IUSE="X +introspection +sqlite tracker test transcode"
+
+RDEPEND="
+	>=dev-libs/glib-2.40.0:2
+	>=dev-libs/libgee-0.8:0.8
+	>=dev-libs/libxml2-2.7:2
+	>=media-libs/gupnp-dlna-0.9.4:2.0
+	media-libs/gstreamer:1.0
+	media-libs/gst-plugins-base:1.0
+	>=media-libs/libmediaart-0.7:2.0
+	media-plugins/gst-plugins-soup:1.0
+	>=net-libs/gssdp-0.14.15
+	>=net-libs/gupnp-0.20.14
+	>=net-libs/gupnp-av-0.12.8
+	>=net-libs/libsoup-2.44:2.4
+	>=sys-apps/util-linux-2.20
+	x11-misc/shared-mime-info
+	introspection? ( >=dev-libs/gobject-introspection-1.33.4:= )
+	sqlite? (
+		>=dev-db/sqlite-3.5:3
+		dev-libs/libunistring:=
+		x11-libs/gdk-pixbuf:2
+	)
+	tracker? ( app-misc/tracker:= )
+	transcode? (
+		media-libs/gst-plugins-bad:1.0
+		media-plugins/gst-plugins-twolame:1.0
+		media-plugins/gst-plugins-libav:1.0
+	)
+	X? ( >=x11-libs/gtk+-3:3 )
+"
+DEPEND="${RDEPEND}
+	dev-util/gtk-doc-am
+	>=sys-devel/gettext-0.19.7
+	virtual/pkgconfig
+"
+# Maintainer only
+#   app-text/docbook-xsl-stylesheets
+#	>=dev-lang/vala-0.22
+#   dev-libs/libxslt
+
+src_prepare() {
+	# Disable test triggering call to gst-plugins-scanner which causes
+	# sandbox issues when plugins such as clutter are installed
+	sed -e 's/return rygel_playbin_renderer_test_main (argv, argc);/return 0;/' \
+		-i tests/rygel-playbin-renderer-test.c || die
+
+	gnome2_src_prepare
+}
+
+src_configure() {
+	# We set xsltproc because man pages are provided by upstream
+	# and we do not want to regenerate them automagically.
+	gnome2_src_configure \
+		XSLTPROC=$(type -P false) \
+		--enable-gst-launch-plugin \
+		--with-media-engine=gstreamer \
+		--enable-nls \
+		--with-systemduserunitdir=$(systemd_get_userunitdir) \
+		$(use_enable introspection) \
+		$(use_enable sqlite media-export-plugin) \
+		$(use_enable sqlite lms-plugin) \
+		$(use_enable test tests) \
+		$(use_enable tracker tracker-plugin) \
+		$(use_with X ui)
+}