[gentoo-commits] repo/gentoo:master commit in: app-misc/sphinx/

["Hans de Graaff" <graaff@gentoo.org>]

commit:     59d71e2c5d1c835eda84c1647a52687dec3f38b6
Author:     Hans de Graaff <graaff <AT> gentoo <DOT> org>
AuthorDate: Mon Jan 21 19:20:08 2019 +0000
Commit:     Hans de Graaff <graaff <AT> gentoo <DOT> org>
CommitDate: Mon Jan 21 19:20:08 2019 +0000
URL:        https://gitweb.gentoo.org/repo/gentoo.git/commit/?id=59d71e2c

app-misc/sphinx: link against libre2 shared library

Explicitly provide the shared object to link against, since the build
system defaults to a static library and can't use normal linker
commands.

Fixes: https://bugs.gentoo.org/674308
Signed-off-by: Hans de Graaff <graaff <AT> gentoo.org>
Package-Manager: Portage-2.3.51, Repoman-2.3.11

 app-misc/sphinx/sphinx-2.2.11-r2.ebuild | 112 ++++++++++++++++++++++++++++++++
 1 file changed, 112 insertions(+)

diff --git a/app-misc/sphinx/sphinx-2.2.11-r2.ebuild b/app-misc/sphinx/sphinx-2.2.11-r2.ebuild
new file mode 100644
index 00000000000..ed278ee1e82
--- /dev/null
+++ b/app-misc/sphinx/sphinx-2.2.11-r2.ebuild
@@ -0,0 +1,112 @@
+# Copyright 1999-2019 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=6
+
+WANT_AUTOMAKE=1.15
+
+inherit eutils autotools toolchain-funcs
+
+#MY_P=${P/_/-}
+MY_P=${P}-release
+
+DESCRIPTION="Full-text search engine with support for MySQL and PostgreSQL"
+HOMEPAGE="http://www.sphinxsearch.com/"
+SRC_URI="http://sphinxsearch.com/files/${MY_P}.tar.gz"
+
+LICENSE="GPL-2"
+SLOT="0"
+KEYWORDS="~amd64 ~arm ~ia64 ~ppc ~ppc64 ~s390 ~sparc ~x86 ~amd64-linux ~ppc-macos ~x64-macos ~x86-macos ~sparc-solaris ~sparc64-solaris"
+IUSE="debug +id64 mariadb mysql odbc postgres re2 stemmer syslog xml"
+
+REQUIRED_USE="mysql? ( !mariadb ) mariadb? ( !mysql )"
+
+RDEPEND="
+	mysql? ( dev-db/mysql-connector-c )
+	mariadb? ( dev-db/mariadb-connector-c )
+	postgres? ( dev-db/postgresql:* )
+	odbc? ( dev-db/unixODBC )
+	re2? ( dev-libs/re2 )
+	stemmer? ( dev-libs/snowball-stemmer )
+	xml? ( dev-libs/expat )
+	virtual/libiconv"
+
+S=${WORKDIR}/${MY_P}
+
+src_prepare() {
+	epatch "${FILESDIR}"/${PN}-2.0.1_beta-darwin8.patch
+
+	# drop nasty hardcoded search path breaking Prefix
+	# We patch configure directly since otherwise we need to run
+	# eautoreconf twice and that causes problems, bug 425380
+	sed -i -e 's/\/usr\/local\//\/someplace\/nonexisting\//g' configure || die
+
+	if use mariadb ; then
+		sed -i -e 's/mysql_config/mariadb_config/g' configure || die
+	fi
+
+	# Fix QA compilation warnings.
+	sed -i -e '19i#include <string.h>' api/libsphinxclient/test.c || die
+
+	eapply_user
+
+	pushd api/libsphinxclient || die
+	eautoreconf
+	popd || die
+
+	# Drop bundled code to ensure building against system versions. We
+	# cannot remove libstemmer_c since configure updates its Makefile.
+	rm -rf libexpat libre2 || die
+}
+
+src_configure() {
+	# fix libiconv detection
+	use !elibc_glibc && export ac_cv_search_iconv=-liconv
+
+	local mysql_with
+	if use mysql || use mariadb ; then
+		mysql_with="--with-mysql"
+	else
+		mysql_with="--without-mysql"
+	fi
+
+	econf \
+		--sysconfdir="${EPREFIX}/etc/${PN}" \
+		$(use_enable id64) \
+		$(use_with debug) \
+		${mysql_with} \
+		$(use_with odbc unixodbc) \
+		$(use_with postgres pgsql) \
+		$(use_with re2) \
+		--with-re2-libs="${EPREFIX}/usr/$(get_libdir)/libre2.so" \
+		$(use_with stemmer libstemmer) \
+		$(use_with syslog syslog) \
+		$(use_with xml libexpat )
+
+	cd api/libsphinxclient || die
+	econf STRIP=:
+}
+
+src_compile() {
+	emake AR="$(tc-getAR)" || die "emake failed"
+
+	emake -j 1 -C api/libsphinxclient || die "emake libsphinxclient failed"
+}
+
+src_test() {
+	# Tests require a live database and only work from the source
+	# directory.
+	:
+}
+
+src_install() {
+	emake DESTDIR="${D}" install || die "install failed"
+	emake DESTDIR="${D}" -C api/libsphinxclient install || die "install libsphinxclient failed"
+
+	dodoc doc/*
+
+	dodir /var/lib/sphinx
+	dodir /var/log/sphinx
+
+	newinitd "${FILESDIR}"/searchd.rc searchd
+}