[gentoo-commits] repo/gentoo:master commit in: net-irc/scrollz/

["Pacho Ramos" <pacho@gentoo.org>]

commit:     67f042f14014c7b7507048f95d4b84181e850b3f
Author:     Pacho Ramos <pacho <AT> gentoo <DOT> org>
AuthorDate: Sun Jan 20 11:58:27 2019 +0000
Commit:     Pacho Ramos <pacho <AT> gentoo <DOT> org>
CommitDate: Sun Jan 20 12:06:09 2019 +0000
URL:        https://gitweb.gentoo.org/repo/gentoo.git/commit/?id=67f042f1

net-irc/scrollz: Version bump

Closes: https://bugs.gentoo.org/675840
Package-Manager: Portage-2.3.55, Repoman-2.3.12
Signed-off-by: Pacho Ramos <pacho <AT> gentoo.org>

 net-irc/scrollz/Manifest           |  1 +
 net-irc/scrollz/scrollz-2.3.ebuild | 62 ++++++++++++++++++++++++++++++++++++++
 2 files changed, 63 insertions(+)

diff --git a/net-irc/scrollz/Manifest b/net-irc/scrollz/Manifest
index 552f1f35943..a9001decac7 100644
--- a/net-irc/scrollz/Manifest
+++ b/net-irc/scrollz/Manifest
@@ -1 +1,2 @@
 DIST ScrollZ-2.2.1.tar.gz 940738 BLAKE2B eaac2b2d990dade73f036a71534f624bf9b6fb6be04d6c19ad8d458f6a2aa035cbd97af305925db42586091ada6eb6ea3415b97819b57a68fa0dda07718122ee SHA512 38eac6a2ecf8789b2d5e042a6ff59463aecf65646c3b07ca1980f60dc47f153dd5f6e42f5a0c1edbef7d1b6743a368f9f4b25be57406353b8e34919e82c7bc21
+DIST ScrollZ-2.3.tar.gz 981707 BLAKE2B ee7c1955dbd2515204d805052d091274c3c7e08257a798c357c5a195c12d7ebc85a160cd40ddf1b2aa87a1b628bebf630c3b7428bde1f230bf9b372f74cc74d2 SHA512 cb3dc2f462452c605c688805ed5128e0197eb4daae895c03f00631c4e9a0994f89a9c55b7e0591588f3f313dab66fcbeb1683b42ef75c3b714185b40703b1979

diff --git a/net-irc/scrollz/scrollz-2.3.ebuild b/net-irc/scrollz/scrollz-2.3.ebuild
new file mode 100644
index 00000000000..91c290474e3
--- /dev/null
+++ b/net-irc/scrollz/scrollz-2.3.ebuild
@@ -0,0 +1,62 @@
+# Copyright 1999-2019 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=7
+inherit toolchain-funcs
+
+MY_P="ScrollZ-${PV}"
+
+DESCRIPTION="Advanced IRC client based on ircII"
+HOMEPAGE="http://www.scrollz.info/"
+SRC_URI="http://www.scrollz.info/download/${MY_P}.tar.gz"
+
+LICENSE="BSD"
+SLOT="0"
+KEYWORDS="~amd64 ~ppc ~x86 ~amd64-linux ~x86-linux ~ppc-macos"
+
+IUSE="gmp gnutls ipv6 socks5 ssl"
+REQUIRED_USE="gnutls? ( ssl )"
+
+RDEPEND="
+	sys-libs/ncurses:0=
+	gmp? ( dev-libs/gmp:0= )
+	ssl? (
+		gnutls? ( net-libs/gnutls:0= )
+		!gnutls? ( dev-libs/openssl:0= )
+		)
+"
+DEPEND="${RDEPEND}
+	virtual/pkgconfig
+"
+
+S="${WORKDIR}/ScrollZ-${MY_P}"
+
+src_configure() {
+	local _myssl
+
+	if use ssl; then
+		if use gnutls; then
+			_myssl="--with-ssl"
+		else
+			_myssl="--with-openssl"
+		fi
+	fi
+
+	tc-export CC #397441, ancient autoconf
+	econf \
+		--with-default-server="irc.gentoo.org" \
+		$(use_with socks5) \
+		$(use_enable ipv6) \
+		--enable-regexp \
+		$(use_enable gmp fish) \
+		${_myssl}
+}
+
+src_install() {
+	emake \
+		DESTDIR="${D}" \
+		mandir="${EPREFIX}/usr/share/man/man1" \
+		install
+
+	dodoc ChangeLog* NEWS README* todo
+}