[gentoo-commits] repo/gentoo:master commit in: media-video/aravis/

["Luca Barbato" <lu_zero@gentoo.org>]

commit:     05fb115367d4e3b2de2a0d98f63b8685a974bf6f
Author:     Luca Barbato <lu_zero <AT> gentoo <DOT> org>
AuthorDate: Tue Jan 15 15:20:04 2019 +0000
Commit:     Luca Barbato <lu_zero <AT> gentoo <DOT> org>
CommitDate: Tue Jan 15 15:20:43 2019 +0000
URL:        https://gitweb.gentoo.org/repo/gentoo.git/commit/?id=05fb1153

media-video/aravis: Version bump

New stable version

Package-Manager: Portage-2.3.52, Repoman-2.3.12
Signed-off-by: Luca Barbato <lu_zero <AT> gentoo.org>

 media-video/aravis/Manifest            |  1 +
 media-video/aravis/aravis-0.6.1.ebuild | 67 ++++++++++++++++++++++++++++++++++
 2 files changed, 68 insertions(+)

diff --git a/media-video/aravis/Manifest b/media-video/aravis/Manifest
index b6bb7dbfefb..951af5ec264 100644
--- a/media-video/aravis/Manifest
+++ b/media-video/aravis/Manifest
@@ -1 +1,2 @@
 DIST aravis-0.5.10.tar.xz 540700 BLAKE2B f12a2bfa2bf8ac1875b28ec0549e5ebe3e5eb1cd646e417acc52a760546343893e19d7fb13741799346286dc69d9ecf2a7d7a3c9ada6ffefafab5c6450468848 SHA512 27a182a8fce66416e14baa16609b91307683613fab9324c96f94b9a7dd956ba0d60f5c966b2ec5184374ab8f9f527ad4d7733dffd2c40faa409ff196c344eb29
+DIST aravis-0.6.1.tar.xz 547700 BLAKE2B 7230cf49e08865b6f4e6621585c394633c54b94b921e4c686757eb21a02d5f51406f5084f92d41ad1880468001c908eb648fd2c2247def46bcbceea92bffa3ce SHA512 098a079c7efc5e5f9d198beef8a6271f525779947d1767eba81262a33c38afa6d9f01f254e25b714b9c74550795beed144bb463c0e14d2a46e6e96d1af19bde4

diff --git a/media-video/aravis/aravis-0.6.1.ebuild b/media-video/aravis/aravis-0.6.1.ebuild
new file mode 100644
index 00000000000..6136076e6a1
--- /dev/null
+++ b/media-video/aravis/aravis-0.6.1.ebuild
@@ -0,0 +1,67 @@
+# Copyright 1999-2019 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=7
+
+if [[ ${PV} = *9999 ]]; then
+	EGIT_REPO_URI="https://github.com/AravisProject/aravis.git"
+	inherit git-r3 autotools
+else
+	SRC_URI="mirror://gnome/sources/${PN}/$(ver_cut 1-2)/${P}.tar.xz"
+	KEYWORDS="~amd64"
+fi
+
+DESCRIPTION="Library for video acquisition using Genicam cameras"
+HOMEPAGE="https://wiki.gnome.org/Projects/Aravis"
+
+LICENSE="LGPL-2.1"
+SLOT="0"
+IUSE="X gstreamer caps"
+
+GST_DEPEND="media-libs/gstreamer:1.0
+	media-libs/gst-plugins-base:1.0"
+
+RDEPEND=">=dev-libs/glib-2.32
+	dev-libs/libxml2
+	X? (
+		>=x11-libs/gtk+-3.12:3
+		${GST_DEPEND}
+		media-libs/gst-plugins-base:1.0
+		x11-libs/libnotify
+	)
+	caps? (
+		sys-libs/libcap-ng
+		sys-process/audit
+	)
+	gstreamer? ( ${GST_DEPEND} )"
+DEPEND="${RDEPEND}
+	virtual/pkgconfig
+	dev-libs/gobject-introspection"
+
+if [[ ${PV} != *9999 ]]; then
+	DEPEND+=" dev-util/gtk-doc dev-util/intltool"
+fi
+
+src_prepare() {
+	default
+	if [[ ${PV} = *9999 ]]; then
+		intltoolize || die
+		gtkdocize || die
+		eautoreconf
+	fi
+}
+
+src_configure() {
+	econf \
+		--disable-silent-rules \
+		--disable-static \
+		$(use_enable X viewer) \
+		$(use_enable gstreamer gst-plugin) \
+		$(use_enable caps packet-socket) \
+		--enable-introspection
+}
+
+src_install() {
+	emake install DESTDIR="${D}" aravisdocdir="/usr/share/doc/${PF}"
+	find "${D}" -name '*.la' -delete
+}