[gentoo-commits] repo/gentoo:master commit in: x11-misc/rofi/

["Jeroen Roovers" <jer@gentoo.org>]

commit:     9daf75a6a9a064eaa607ad190b4a9e3ea59c7eef
Author:     Jeroen Roovers <jer <AT> gentoo <DOT> org>
AuthorDate: Wed Jan  2 00:25:50 2019 +0000
Commit:     Jeroen Roovers <jer <AT> gentoo <DOT> org>
CommitDate: Wed Jan  2 00:30:22 2019 +0000
URL:        https://gitweb.gentoo.org/repo/gentoo.git/commit/?id=9daf75a6

x11-misc/rofi: Add live ebuild

Package-Manager: Portage-2.3.53, Repoman-2.3.12
Signed-off-by: Jeroen Roovers <jer <AT> gentoo.org>

 x11-misc/rofi/rofi-99999.ebuild | 54 +++++++++++++++++++++++++++++++++++++++++
 1 file changed, 54 insertions(+)

diff --git a/x11-misc/rofi/rofi-99999.ebuild b/x11-misc/rofi/rofi-99999.ebuild
new file mode 100644
index 00000000000..8533b2dbdb9
--- /dev/null
+++ b/x11-misc/rofi/rofi-99999.ebuild
@@ -0,0 +1,54 @@
+# Copyright 1999-2019 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=7
+inherit autotools git-r3 toolchain-funcs
+
+DESCRIPTION="A window switcher, run dialog and dmenu replacement"
+HOMEPAGE="https://github.com/DaveDavenport/rofi/"
+EGIT_REPO_URI="${HOMEPAGE}"
+
+LICENSE="MIT"
+SLOT="0"
+KEYWORDS=""
+IUSE="test windowmode"
+
+RDEPEND="
+	dev-libs/glib:2
+	gnome-base/librsvg:2
+	media-libs/freetype
+	x11-libs/cairo[xcb]
+	x11-libs/libXft
+	x11-libs/libXinerama
+	x11-libs/libxcb
+	x11-libs/libxkbcommon[X]
+	x11-libs/pango[X]
+	x11-libs/startup-notification
+	x11-libs/xcb-util
+	x11-libs/xcb-util-wm
+	x11-libs/xcb-util-xrm
+"
+DEPEND="
+	${RDEPEND}
+	virtual/pkgconfig
+	x11-base/xorg-proto
+	test? ( >=dev-libs/check-0.11 )
+"
+PATCHES=(
+	"${FILESDIR}"/${PN}-0.15.12-Werror.patch
+	"${FILESDIR}"/${PN}-1.5.0-gtk-settings-test.patch
+)
+
+src_prepare() {
+	default
+
+	eautoreconf
+}
+
+src_configure() {
+	tc-export CC
+
+	econf \
+		$(use_enable test check) \
+		$(use_enable windowmode)
+}