[gentoo-commits] repo/gentoo:master commit in: app-admin/setools/

["Jason Zaman" <perfinion@gentoo.org>]

commit:     929d8a3da1b258a61715d5baece976b351446765
Author:     Jason Zaman <perfinion <AT> gentoo <DOT> org>
AuthorDate: Mon Dec 24 14:03:08 2018 +0000
Commit:     Jason Zaman <perfinion <AT> gentoo <DOT> org>
CommitDate: Thu Dec 27 10:06:44 2018 +0000
URL:        https://gitweb.gentoo.org/repo/gentoo.git/commit/?id=929d8a3d

app-admin/setools: bump 4.2.0

Signed-off-by: Jason Zaman <perfinion <AT> gentoo.org>
Package-Manager: Portage-2.3.51, Repoman-2.3.11

 app-admin/setools/Manifest             |  1 +
 app-admin/setools/setools-4.2.0.ebuild | 49 ++++++++++++++++++++++++++++++++++
 2 files changed, 50 insertions(+)

diff --git a/app-admin/setools/Manifest b/app-admin/setools/Manifest
index 470bc7c3df5..e9c135ce05a 100644
--- a/app-admin/setools/Manifest
+++ b/app-admin/setools/Manifest
@@ -1 +1,2 @@
 DIST setools-4.1.1.tar.gz 461649 BLAKE2B a753718aa6a5de889ba7a2eea921340061edf1bcb0b572a365e858949a92d2f8a92a876be2e4bc539d85fa6029511ab6afabfbe8138cdb5a73b587a9b58551bb SHA512 2e55a3b07e2f94d7c84054f31d266567b9acc708fe2b0e16ac3ea24e8301c712bcf564ff915a6135a1a6ba6822682bb3a6530dae20161a832fb7048364acbd04
+DIST setools-4.2.0.tar.gz 363802 BLAKE2B a57a7d565bb6e91f67cba0516434d8a0d3635d0717e878d8ac43b6cf7de0884ea74152ec50e93554f7d1a75a4098db2241668e1765e7b069d23b6cc13d4b712e SHA512 b51f458f7f2d1b569f63478f53709268615f711104915cc2d5031b2049435e4f43a103ebe50c9797ebe4b2645bf1974c73c2f53e7f602ae03c47221edb89d680

diff --git a/app-admin/setools/setools-4.2.0.ebuild b/app-admin/setools/setools-4.2.0.ebuild
new file mode 100644
index 00000000000..70e0fb4bed2
--- /dev/null
+++ b/app-admin/setools/setools-4.2.0.ebuild
@@ -0,0 +1,49 @@
+# Copyright 1999-2018 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI="6"
+PYTHON_COMPAT=( python3_5 python3_6 )
+
+inherit distutils-r1
+
+DESCRIPTION="Policy Analysis Tools for SELinux"
+HOMEPAGE="https://github.com/SELinuxProject/setools/wiki"
+
+if [[ ${PV} == 9999 ]] ; then
+	inherit git-r3
+	EGIT_REPO_URI="https://github.com/SELinuxProject/setools.git"
+else
+	SRC_URI="https://github.com/SELinuxProject/setools/archive/${PV}.tar.gz -> ${P}.tar.gz"
+	KEYWORDS="~amd64 ~arm64 ~x86"
+fi
+
+LICENSE="GPL-2 LGPL-2.1"
+SLOT="0"
+IUSE="X test"
+
+RDEPEND="${PYTHON_DEPS}
+	>=dev-python/networkx-2.0[${PYTHON_USEDEP}]
+	>=sys-libs/libsepol-2.8:=
+	>=sys-libs/libselinux-2.8:=
+	X? (
+		dev-python/PyQt5[gui,widgets,${PYTHON_USEDEP}]
+	)"
+
+DEPEND="${RDEPEND}
+	>=dev-python/cython-0.27
+	test? (
+		sys-apps/checkpolicy
+	)"
+
+python_prepare_all() {
+	sed -i "s/'-Werror', //" "${S}"/setup.py || die "failed to remove Werror"
+	sed -i "s@^lib_dirs = .*@lib_dirs = ['${ROOT:-/}usr/$(get_libdir)']@" "${S}"/setup.py || \
+		die "failed to set lib_dirs"
+
+	use X || local PATCHES=( "${FILESDIR}"/setools-4.2.0-remove-gui.patch )
+	distutils-r1_python_prepare_all
+}
+
+python_test() {
+	esetup.py test
+}