[gentoo-commits] repo/gentoo:master commit in: net-libs/signond/

["Andreas Sturmlechner" <asturm@gentoo.org>]

commit:     8ba7594d3e73e3cde03b97b877ba350e41c83f6c
Author:     Andreas Sturmlechner <asturm <AT> gentoo <DOT> org>
AuthorDate: Sun Dec 23 01:05:18 2018 +0000
Commit:     Andreas Sturmlechner <asturm <AT> gentoo <DOT> org>
CommitDate: Sun Dec 23 01:25:27 2018 +0000
URL:        https://gitweb.gentoo.org/repo/gentoo.git/commit/?id=8ba7594d

net-libs/signond: Override LIBDIR to avoid buildsystem assumption

Bug: https://bugs.gentoo.org/668562
Package-Manager: Portage-2.3.52, Repoman-2.3.12
Signed-off-by: Andreas Sturmlechner <asturm <AT> gentoo.org>

 net-libs/signond/signond-8.59-r1.ebuild | 65 +++++++++++++++++++++++++++++++++
 1 file changed, 65 insertions(+)

diff --git a/net-libs/signond/signond-8.59-r1.ebuild b/net-libs/signond/signond-8.59-r1.ebuild
new file mode 100644
index 00000000000..8a154b36b17
--- /dev/null
+++ b/net-libs/signond/signond-8.59-r1.ebuild
@@ -0,0 +1,65 @@
+# Copyright 1999-2018 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=6
+
+inherit qmake-utils vcs-snapshot
+
+DESCRIPTION="Signon daemon for libaccounts-glib"
+HOMEPAGE="https://01.org/gsso/"
+SRC_URI="https://gitlab.com/accounts-sso/signond/repository/archive.tar.gz?ref=VERSION_8.59 -> ${P}.tar.gz"
+
+LICENSE="LGPL-2.1"
+SLOT="0"
+KEYWORDS="amd64 ~arm x86"
+IUSE="doc test"
+
+RESTRICT="test"
+
+COMMON_DEPEND="
+	dev-qt/qtcore:5
+	dev-qt/qtdbus:5
+	dev-qt/qtgui:5
+	dev-qt/qtnetwork:5
+	dev-qt/qtsql:5
+	net-libs/libproxy
+"
+DEPEND="${COMMON_DEPEND}
+	doc? ( app-doc/doxygen )
+	test? ( dev-qt/qttest:5 )
+"
+RDEPEND="${COMMON_DEPEND}
+	!<net-libs/libproxy-0.4.12[kde]
+"
+# <libproxy-0.4.12[kde] results in segfaults due to symbol collisions with qt4
+
+src_prepare() {
+	default
+
+	# remove unused dependency
+	sed -e "/xml \\\/d" -i src/signond/signond.pro || die
+
+	# ensure qt5 version of binary is used
+	sed -e "s|qdbusxml2cpp|$(qt5_get_bindir)/&|" -i src/signond/signond.pro || die
+
+	# install docs to correct location
+	sed -e "s|share/doc/\$\${PROJECT_NAME}|share/doc/${PF}|" -i doc/doc.pri || die
+
+	# don't install example plugin
+	sed -e "/example/d" -i src/plugins/plugins.pro || die
+
+	# make tests optional
+	use test || sed -i -e '/^SUBDIRS/s/tests//' signon.pro || die "couldn't disable tests"
+
+	# make docs optional
+	use doc || sed -e "/include(\s*doc\/doc.pri\s*)/d" -i \
+		signon.pro -i lib/SignOn/SignOn.pro lib/plugins/plugins.pro || die
+}
+
+src_configure() {
+	eqmake5 LIBDIR=/usr/$(get_libdir)
+}
+
+src_install() {
+	emake INSTALL_ROOT="${D}" install
+}