[gentoo-commits] repo/gentoo:master commit in: sci-libs/indilib/

["Andreas Sturmlechner" <asturm@gentoo.org>]

commit:     72ebe29f5d5a5fb8157baba4640f117104592a1e
Author:     Andreas Sturmlechner <asturm <AT> gentoo <DOT> org>
AuthorDate: Sat Dec 22 21:45:37 2018 +0000
Commit:     Andreas Sturmlechner <asturm <AT> gentoo <DOT> org>
CommitDate: Sun Dec 23 01:25:26 2018 +0000
URL:        https://gitweb.gentoo.org/repo/gentoo.git/commit/?id=72ebe29f

sci-libs/indilib: 1.7.5 version bump

Package-Manager: Portage-2.3.52, Repoman-2.3.12
Signed-off-by: Andreas Sturmlechner <asturm <AT> gentoo.org>

 sci-libs/indilib/Manifest             |  1 +
 sci-libs/indilib/indilib-1.7.5.ebuild | 51 +++++++++++++++++++++++++++++++++++
 2 files changed, 52 insertions(+)

diff --git a/sci-libs/indilib/Manifest b/sci-libs/indilib/Manifest
index ce8109973af..ad39b684dc2 100644
--- a/sci-libs/indilib/Manifest
+++ b/sci-libs/indilib/Manifest
@@ -1 +1,2 @@
 DIST indilib-1.6.0.tar.gz 1726681 BLAKE2B fc746fe74b41467930f50f4aabe63d485372dc3f7e551bf8b91ec92694efc5a73a29495ee4931f84215a90afdd1deb3c12f87aaedc32d33e408114674e6d79ad SHA512 a086a63e15f5f6fb05a0d1569578f5fbd4d6ba6ff5a0aaff7bd475925d3858840753f1aa04e7429a22576f52432a19e93b781e821ea908db6b7352af85f30422
+DIST indilib-1.7.5.tar.xz 1380436 BLAKE2B 092f4100894218bf749ee0d7c910c4ee20026cf471f4f65686b67dd37a924b448b6de3733e70d7047dca6a77fd8ae26b9a568f8249336be78d052984838a2ccf SHA512 57205ed9ea9d8e8215886b17d9f0307755bca571d599967dc607320fad5ec62096f31526280f3b184ffeb0434d9adb71e65a7d6f89d29edaa643d729765f47a8

diff --git a/sci-libs/indilib/indilib-1.7.5.ebuild b/sci-libs/indilib/indilib-1.7.5.ebuild
new file mode 100644
index 00000000000..ef516b5138a
--- /dev/null
+++ b/sci-libs/indilib/indilib-1.7.5.ebuild
@@ -0,0 +1,51 @@
+# Copyright 1999-2018 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=7
+
+inherit cmake-utils udev
+
+DESCRIPTION="INDI Astronomical Control Protocol library"
+HOMEPAGE="https://www.indilib.org/"
+# SRC_URI="https://github.com/${PN}/${PN/lib/}/archive/v${PV}.tar.gz -> ${P}.tar.gz"
+SRC_URI="https://dev.gentoo.org/~asturm/distfiles/${P}.tar.xz"
+
+LICENSE="BSD GPL-2+ LGPL-2+ LGPL-2.1+"
+SLOT="0/1"
+KEYWORDS="~amd64 ~ppc ~ppc64 ~x86"
+IUSE="ogg test"
+
+RDEPEND="
+	net-misc/curl
+	sci-libs/cfitsio:=
+	sci-libs/gsl:=
+	sci-libs/libnova
+	sys-libs/zlib
+	virtual/jpeg:0
+	virtual/libusb:0
+	ogg? (
+		media-libs/libogg
+		media-libs/libtheora
+	)
+"
+DEPEND="${RDEPEND}
+	kernel_linux? ( sys-kernel/linux-headers )
+	test? ( >=dev-cpp/gtest-1.8.0 )
+"
+
+S="${WORKDIR}/lib${PN/lib/}"
+
+src_test() {
+	BUILD_DIR="${BUILD_DIR}"/test cmake-utils_src_test
+}
+
+src_configure() {
+	local mycmakeargs=(
+		-DINDI_BUILD_QT5_CLIENT=OFF
+		-DINDI_BUILD_UNITTESTS=$(usex test)
+		-DUDEVRULES_INSTALL_DIR="$(get_udevdir)"
+		$(cmake-utils_use_find_package ogg OggTheora)
+	)
+
+	cmake-utils_src_configure
+}