[gentoo-commits] repo/gentoo:master commit in: dev-util/sysdig/

["Michał Górny" <mgorny@gentoo.org>]

commit:     d0390d409c0345e7a077f4f3f134a2253f5e54ab
Author:     Michał Górny <mgorny <AT> gentoo <DOT> org>
AuthorDate: Sat Dec 22 08:16:57 2018 +0000
Commit:     Michał Górny <mgorny <AT> gentoo <DOT> org>
CommitDate: Sat Dec 22 08:35:06 2018 +0000
URL:        https://gitweb.gentoo.org/repo/gentoo.git/commit/?id=d0390d40

dev-util/sysdig: Bump to 0.24.2

Signed-off-by: Michał Górny <mgorny <AT> gentoo.org>

 dev-util/sysdig/Manifest             |  1 +
 dev-util/sysdig/sysdig-0.24.2.ebuild | 94 ++++++++++++++++++++++++++++++++++++
 2 files changed, 95 insertions(+)

diff --git a/dev-util/sysdig/Manifest b/dev-util/sysdig/Manifest
index 54e6fcacdab..8d656233e54 100644
--- a/dev-util/sysdig/Manifest
+++ b/dev-util/sysdig/Manifest
@@ -1 +1,2 @@
 DIST sysdig-0.24.1.tar.gz 846153 BLAKE2B bc64317e02526d9729c9fb3738f2982f4b425cdb43c64f77944938186cde4ed2d8d2649984efe0055bbaed250b08bda4008272805024e1d8993e17bc93509663 SHA512 a89ce82527b47104161668e134387a04f4a6753adcd881df25410b629603b58fc8f675de6941f4911ad2da42ffbfd46b38f9cc9837c0809c559fee9a739a204a
+DIST sysdig-0.24.2.tar.gz 855317 BLAKE2B d394ac3bd7e405664da2b45d8cfd5d3433e20266a9489f63b7d4c3bb955a60640d13bb33e6dd2057b16b6ce0617afab88cad2ceab58aa50f6b43a64f6a50f45b SHA512 10ec381144733abc2c386f6570d4245ac2c1eec64d0f56800963acbd9cc38eece504f836f1ab0e24224ff44233945c8273b72efc77d7eadce98d7c4fc378740b

diff --git a/dev-util/sysdig/sysdig-0.24.2.ebuild b/dev-util/sysdig/sysdig-0.24.2.ebuild
new file mode 100644
index 00000000000..3ba452c42e3
--- /dev/null
+++ b/dev-util/sysdig/sysdig-0.24.2.ebuild
@@ -0,0 +1,94 @@
+# Copyright 1999-2018 Gentoo Foundation
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI="6"
+
+: ${CMAKE_MAKEFILE_GENERATOR:=ninja}
+MODULES_OPTIONAL_USE=modules
+inherit linux-mod bash-completion-r1 cmake-utils
+
+DESCRIPTION="A system exploration and troubleshooting tool"
+HOMEPAGE="https://www.sysdig.org/"
+SRC_URI="https://github.com/draios/sysdig/archive/${PV}.tar.gz -> ${P}.tar.gz"
+
+LICENSE="Apache-2.0
+	modules? ( || ( MIT GPL-2 ) )"
+SLOT="0"
+KEYWORDS="~amd64 ~x86"
+IUSE="libressl +modules"
+
+RDEPEND="
+	app-misc/jq:0=
+	dev-cpp/tbb:0=
+	dev-lang/luajit:2=
+	>=dev-libs/jsoncpp-0.6_pre:0=
+	dev-libs/libb64:0=
+	sys-libs/ncurses:0=
+	sys-libs/zlib:0=
+	libressl? ( dev-libs/libressl:0= )
+	!libressl? ( dev-libs/openssl:0= )
+	net-misc/curl:0="
+DEPEND="${RDEPEND}
+	app-arch/xz-utils
+	virtual/os-headers"
+
+# needed for the kernel module
+CONFIG_CHECK="HAVE_SYSCALL_TRACEPOINTS ~TRACEPOINTS"
+
+pkg_pretend() {
+	linux-mod_pkg_setup
+}
+
+pkg_setup() {
+	linux-mod_pkg_setup
+}
+
+src_prepare() {
+	sed -i -e 's:-ggdb::' CMakeLists.txt || die
+
+	cmake-utils_src_prepare
+}
+
+src_configure() {
+	local mycmakeargs=(
+		# we will use linux-mod for that
+		-DBUILD_DRIVER=OFF
+		# libscap examples are not installed or really useful
+		-DBUILD_LIBSCAP_EXAMPLES=OFF
+
+		# unbundle the deps
+		-DUSE_BUNDLED_DEPS=OFF
+	)
+
+	cmake-utils_src_configure
+
+	# setup linux-mod ugliness
+	MODULE_NAMES="sysdig-probe(extra:${S}/driver:)"
+	BUILD_PARAMS='KERNELDIR="${KERNEL_DIR}"'
+	BUILD_TARGETS="all"
+
+	if use modules; then
+		cmake-utils_src_make configure_driver
+
+		cp "${BUILD_DIR}"/driver/Makefile.dkms driver/Makefile || die
+	fi
+}
+
+src_compile() {
+	cmake-utils_src_compile
+
+	linux-mod_src_compile
+}
+
+src_install() {
+	cmake-utils_src_install
+
+	linux-mod_src_install
+
+	# remove sources
+	rm -r "${ED%/}"/usr/src || die
+
+	# move bashcomp to the proper location
+	dobashcomp "${ED%/}"/usr/etc/bash_completion.d/sysdig || die
+	rm -r "${ED%/}"/usr/etc || die
+}