[gentoo-commits] repo/gentoo:master commit in: net-misc/modemmanager/

["Mart Raudsepp" <leio@gentoo.org>]

commit:     0f4f670314baceed05c6e0bf776f5d5420aa90d7
Author:     Mart Raudsepp <leio <AT> gentoo <DOT> org>
AuthorDate: Wed Dec  5 14:02:39 2018 +0000
Commit:     Mart Raudsepp <leio <AT> gentoo <DOT> org>
CommitDate: Wed Dec  5 14:06:57 2018 +0000
URL:        https://gitweb.gentoo.org/repo/gentoo.git/commit/?id=0f4f6703

net-misc/modemmanager: remove old

Signed-off-by: Mart Raudsepp <leio <AT> gentoo.org>
Package-Manager: Portage-2.3.52, Repoman-2.3.11

 net-misc/modemmanager/Manifest                   |   1 -
 net-misc/modemmanager/modemmanager-1.6.12.ebuild | 110 -----------------------
 2 files changed, 111 deletions(-)

diff --git a/net-misc/modemmanager/Manifest b/net-misc/modemmanager/Manifest
index 76b6abd9187..983484905f6 100644
--- a/net-misc/modemmanager/Manifest
+++ b/net-misc/modemmanager/Manifest
@@ -1,2 +1 @@
-DIST ModemManager-1.6.12.tar.xz 1402364 BLAKE2B 11335c495cc428936c9b0dd319449a7bf4c58a95ccd53b7a5bb276d78030272a7f29e5f0fa96a96613c5e0cb6a62239d864a23de6260fb55f6ecab09a18e6454 SHA512 2ac72fb2d36530204528cc0cd4815d0b93a1a8c8539ac345101e5e15bbfffd3eda888bbdc54298d3547b9aeacb94c75be5c600e993099671da2f9f27e8ee93cd
 DIST ModemManager-1.8.2.tar.xz 2088248 BLAKE2B e53ec3dacac2b1d57191de0eba130ea575a40047e5faa1c813543f1ca17164d71a18478ec6c0392adabea94d2455ee510ceceefc16798fec6f26ec834ebbf84c SHA512 fb00ce6f3dc9795468e81ba295ad82e9586add2d7118661ea5f287a99afca97dc3aea64488393792bb1198e7abf2605bbc5ded2517980d67f8819931effdeea5

diff --git a/net-misc/modemmanager/modemmanager-1.6.12.ebuild b/net-misc/modemmanager/modemmanager-1.6.12.ebuild
deleted file mode 100644
index bd91deb3ef3..00000000000
--- a/net-misc/modemmanager/modemmanager-1.6.12.ebuild
+++ /dev/null
@@ -1,110 +0,0 @@
-# Copyright 1999-2018 Gentoo Foundation
-# Distributed under the terms of the GNU General Public License v2
-
-EAPI=6
-GNOME2_LA_PUNT="yes"
-VALA_USE_DEPEND="vapigen"
-
-inherit gnome2 user readme.gentoo-r1 systemd udev vala
-
-DESCRIPTION="Modem and mobile broadband management libraries"
-HOMEPAGE="https://cgit.freedesktop.org/ModemManager/ModemManager/"
-SRC_URI="https://www.freedesktop.org/software/ModemManager/ModemManager-${PV}.tar.xz"
-
-LICENSE="GPL-2+"
-SLOT="0/1" # subslot = dbus interface version, i.e. N in org.freedesktop.ModemManager${N}
-KEYWORDS="~alpha amd64 arm ~arm64 ~ia64 ~mips ppc ppc64 ~sparc x86"
-
-IUSE="+introspection mbim policykit +qmi systemd vala"
-REQUIRED_USE="
-	vala? ( introspection )
-"
-
-RDEPEND="
-	>=dev-libs/glib-2.36.0:2
-	>=virtual/libgudev-230:=
-	introspection? ( >=dev-libs/gobject-introspection-0.9.6:= )
-	mbim? ( >=net-libs/libmbim-1.14.0 )
-	policykit? ( >=sys-auth/polkit-0.106[introspection] )
-	qmi? ( >=net-libs/libqmi-1.16.0:= )
-	systemd? ( >=sys-apps/systemd-209 )
-"
-DEPEND="${RDEPEND}
-	dev-util/gdbus-codegen
-	>=dev-util/gtk-doc-am-1
-	>=dev-util/intltool-0.40
-	>=sys-devel/gettext-0.19.3
-	virtual/pkgconfig
-	vala? ( $(vala_depend) )
-"
-
-S="${WORKDIR}/ModemManager-${PV}"
-
-src_prepare() {
-	DOC_CONTENTS="If your USB modem shows up as a Flash drive when you plug it in,
-		You should install sys-apps/usb_modeswitch which will automatically
-		switch it over to USB modem mode whenever you plug it in.\n"
-
-	if use policykit; then
-		DOC_CONTENTS+="\nTo control your modem without needing to enter the root password,
-			add your user account to the 'plugdev' group."
-	fi
-
-	use vala && vala_src_prepare
-	gnome2_src_prepare
-}
-
-src_configure() {
-	gnome2_src_configure \
-		--disable-more-warnings \
-		--with-udev-base-dir="$(get_udevdir)" \
-		--disable-static \
-		--with-dist-version=${PVR} \
-		$(use_enable introspection) \
-		$(use_with mbim) \
-		$(use_with policykit polkit) \
-		$(usex systemd --with-suspend-resume=systemd --with-suspend-resume=no) \
-		$(use_with qmi) \
-		$(use_enable vala)
-}
-
-src_install() {
-	gnome2_src_install
-
-	# Allow users in plugdev group full control over their modem
-	if use policykit; then
-		insinto /usr/share/polkit-1/rules.d/
-		doins "${FILESDIR}"/01-org.freedesktop.ModemManager1.rules
-	fi
-
-	readme.gentoo_create_doc
-}
-
-pkg_postinst() {
-	gnome2_pkg_postinst
-
-	use policykit && enewgroup plugdev
-
-	# The polkit rules file moved to /usr/share
-	old_rules="${EROOT}etc/polkit-1/rules.d/01-org.freedesktop.ModemManager.rules"
-	if [[ -f "${old_rules}" ]]; then
-		case "$(md5sum ${old_rules})" in
-		  c5ff02532cb1da2c7545c3069e5d0992* | 5c50f0dc603c0a56e2851a5ce9389335* )
-			# Automatically delete the old rules.d file if the user did not change it
-			elog
-			elog "Removing old ${old_rules} ..."
-			rm -f "${old_rules}" || eerror "Failed, please remove ${old_rules} manually"
-			;;
-		  * )
-			elog "The ${old_rules}"
-			elog "file moved to /usr/share/polkit-1/rules.d/ in >=modemmanager-0.5.2.0-r2"
-			elog "If you edited ${old_rules}"
-			elog "without changing its behavior, you may want to remove it."
-			;;
-		esac
-	fi
-
-	systemd_reenable ModemManager.service
-
-	readme.gentoo_print_elog
-}