* [gentoo-commits] repo/gentoo:master commit in: dev-libs/efl/files/, dev-libs/efl/
@ 2017-03-04 0:37 Alon Bar-Lev
0 siblings, 0 replies; 4+ messages in thread
From: Alon Bar-Lev @ 2017-03-04 0:37 UTC (permalink / raw
To: gentoo-commits
commit: 1c8cf2757d1e8085ed7b1969718ce22650edb23f
Author: Alon Bar-Lev <alonbl <AT> gentoo <DOT> org>
AuthorDate: Sat Mar 4 00:36:03 2017 +0000
Commit: Alon Bar-Lev <alonbl <AT> gentoo <DOT> org>
CommitDate: Sat Mar 4 00:37:16 2017 +0000
URL: https://gitweb.gentoo.org/repo/gentoo.git/commit/?id=1c8cf275
dev-libs/efl: support gnutls-3.4
Bug: 584924
Package-Manager: Portage-2.3.3, Repoman-2.3.1
dev-libs/efl/efl-1.17.0-r1.ebuild | 279 +++++++++++++++++++++++++
dev-libs/efl/files/efl-1.17.0-gnutls-3.4.patch | 39 ++++
2 files changed, 318 insertions(+)
diff --git a/dev-libs/efl/efl-1.17.0-r1.ebuild b/dev-libs/efl/efl-1.17.0-r1.ebuild
new file mode 100644
index 00000000000..27b0c680047
--- /dev/null
+++ b/dev-libs/efl/efl-1.17.0-r1.ebuild
@@ -0,0 +1,279 @@
+# Copyright 1999-2017 Gentoo Foundation
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI="5"
+
+MY_P=${P/_/-}
+
+if [[ "${PV}" == "9999" ]] ; then
+ EGIT_SUB_PROJECT="core"
+ EGIT_URI_APPEND="${PN}"
+elif [[ *"${PV}" == *"_pre"* ]] ; then
+ MY_P=${P%%_*}
+ SRC_URI="https://download.enlightenment.org/pre-releases/${MY_P}.tar.xz"
+ EKEY_STATE="snap"
+else
+ SRC_URI="https://download.enlightenment.org/rel/libs/${PN}/${MY_P}.tar.xz"
+ EKEY_STATE="release"
+fi
+
+inherit enlightenment pax-utils
+
+DESCRIPTION="Enlightenment Foundation Libraries all-in-one package"
+
+LICENSE="BSD-2 GPL-2 LGPL-2.1 ZLIB"
+IUSE="+bmp debug drm +eet egl fbcon +fontconfig fribidi gif gles glib gnutls gstreamer harfbuzz +ico ibus jpeg2k libressl neon oldlua opengl ssl physics pixman +png +ppm +psd pulseaudio scim sdl sound systemd tga tiff tslib v4l valgrind wayland webp X xim xine xpm"
+KEYWORDS="~alpha ~amd64 ~arm ~hppa ~ia64 ~mips ~ppc ~ppc64 ~sh ~sparc ~x86 ~amd64-fbsd ~x86-fbsd ~amd64-linux ~x86-linux ~ppc-macos ~x86-macos ~x64-solaris ~x86-solaris"
+
+REQUIRED_USE="
+ pulseaudio? ( sound )
+ opengl? ( || ( X sdl wayland ) )
+ gles? ( || ( X wayland ) )
+ gles? ( !sdl )
+ gles? ( egl )
+ sdl? ( opengl )
+ wayland? ( egl !opengl gles )
+ xim? ( X )
+"
+
+RDEPEND="
+ drm? (
+ >=dev-libs/libinput-0.8
+ media-libs/mesa[gbm]
+ >=x11-libs/libdrm-2.4
+ >=x11-libs/libxkbcommon-0.3.0
+ )
+ fontconfig? ( media-libs/fontconfig )
+ fribidi? ( dev-libs/fribidi )
+ gif? ( media-libs/giflib )
+ glib? ( dev-libs/glib:2 )
+ gnutls? ( net-libs/gnutls )
+ !gnutls? (
+ ssl? (
+ !libressl? ( dev-libs/openssl:0= )
+ libressl? ( dev-libs/libressl )
+ )
+ )
+ gstreamer? (
+ media-libs/gstreamer:1.0
+ media-libs/gst-plugins-base:1.0
+ )
+ harfbuzz? ( media-libs/harfbuzz )
+ ibus? ( app-i18n/ibus )
+ jpeg2k? ( media-libs/openjpeg:0 )
+ !oldlua? ( >=dev-lang/luajit-2.0.0 )
+ oldlua? ( dev-lang/lua:* )
+ physics? ( >=sci-physics/bullet-2.80 )
+ pixman? ( x11-libs/pixman )
+ png? ( media-libs/libpng:0= )
+ pulseaudio? ( media-sound/pulseaudio )
+ scim? ( app-i18n/scim )
+ sdl? (
+ media-libs/libsdl2
+ virtual/opengl
+ )
+ sound? ( media-libs/libsndfile )
+ systemd? ( sys-apps/systemd )
+ tiff? ( media-libs/tiff:0= )
+ tslib? ( x11-libs/tslib )
+ valgrind? ( dev-util/valgrind )
+ wayland? (
+ >=dev-libs/wayland-1.8.0
+ >=x11-libs/libxkbcommon-0.3.1
+ media-libs/mesa[gles2,wayland]
+ )
+ webp? ( media-libs/libwebp )
+ X? (
+ x11-libs/libXcursor
+ x11-libs/libX11
+ x11-libs/libXcomposite
+ x11-libs/libXdamage
+ x11-libs/libXext
+ x11-libs/libXfixes
+ x11-libs/libXinerama
+ x11-libs/libXp
+ x11-libs/libXrandr
+ x11-libs/libXrender
+ x11-libs/libXtst
+ x11-libs/libXScrnSaver
+
+ opengl? (
+ x11-libs/libX11
+ x11-libs/libXrender
+ virtual/opengl
+ )
+
+ gles? (
+ x11-libs/libX11
+ x11-libs/libXrender
+ virtual/opengl
+ )
+ )
+ xine? ( >=media-libs/xine-lib-1.1.1 )
+ xpm? ( x11-libs/libXpm )
+
+ sys-apps/dbus
+ >=sys-apps/util-linux-2.20.0
+ sys-libs/zlib
+ virtual/jpeg:0=
+
+ !dev-libs/ecore
+ !dev-libs/edbus
+ !dev-libs/eet
+ !dev-libs/eeze
+ !dev-libs/efreet
+ !dev-libs/eina
+ !dev-libs/eio
+ !dev-libs/embryo
+ !dev-libs/eobj
+ !dev-libs/ephysics
+ !media-libs/edje
+ !media-libs/emotion
+ !media-libs/ethumb
+ !media-libs/evas
+"
+#external lz4 support currently broken because of unstable ABI/API
+# app-arch/lz4
+
+#soft blockers added above for binpkg users
+#hard blocks are needed for building
+CORE_EFL_CONFLICTS="
+ !!dev-libs/ecore
+ !!dev-libs/edbus
+ !!dev-libs/eet
+ !!dev-libs/eeze
+ !!dev-libs/efreet
+ !!dev-libs/eina
+ !!dev-libs/eio
+ !!dev-libs/embryo
+ !!dev-libs/eobj
+ !!dev-libs/ephysics
+ !!media-libs/edje
+ !!media-libs/emotion
+ !!media-libs/ethumb
+ !!media-libs/evas
+"
+
+DEPEND="
+ ${CORE_EFL_CONFLICTS}
+
+ ${RDEPEND}
+ doc? ( app-doc/doxygen )
+"
+
+S=${WORKDIR}/${MY_P}
+
+src_prepare() {
+ enlightenment_src_prepare
+
+ epatch "${FILESDIR}/${P}-gnutls-3.4.patch"
+
+ # Remove stupid sleep command.
+ # Also back out gnu make hack that causes regen of Makefiles.
+ # Delete var setting that causes the build to abort.
+ sed -i \
+ -e '/sleep 10/d' \
+ -e '/^#### Work around bug in automake check macro$/,/^#### Info$/d' \
+ -e '/BARF_OK=/s:=.*:=:' \
+ configure || die
+}
+
+src_configure() {
+ if use ssl && use gnutls ; then
+ einfo "You enabled both USE=ssl and USE=gnutls, but only one can be used;"
+ einfo "gnutls has been selected for you."
+ fi
+ if use opengl && use gles ; then
+ einfo "You enabled both USE=opengl and USE=gles, but only one can be used;"
+ einfo "opengl has been selected for you."
+ fi
+
+ E_ECONF=(
+ --with-profile=$(usex debug debug release)
+ --with-crypto=$(usex gnutls gnutls $(usex ssl openssl none))
+ --with-x11=$(usex X xlib none)
+ $(use_with X x)
+ --with-opengl=$(usex opengl full $(usex gles es none))
+ --with-glib=$(usex glib)
+ --enable-i-really-know-what-i-am-doing-and-that-this-will-probably-break-things-and-i-will-fix-them-myself-and-send-patches-abb
+
+ $(use_enable bmp image-loader-bmp)
+ $(use_enable bmp image-loader-wbmp)
+ $(use_enable drm)
+ $(use_enable doc)
+ $(use_enable eet image-loader-eet)
+ $(use_enable egl)
+ $(use_enable fbcon fb)
+ $(use_enable fontconfig)
+ $(use_enable fribidi)
+ $(use_enable gif image-loader-gif)
+ $(use_enable gstreamer gstreamer1)
+ $(use_enable harfbuzz)
+ $(use_enable ico image-loader-ico)
+ $(use_enable ibus)
+ $(use_enable jpeg2k image-loader-jp2k)
+ $(use_enable neon)
+ $(use_enable nls)
+ $(use_enable oldlua lua-old)
+ $(use_enable physics)
+ $(use_enable pixman)
+ $(use_enable pixman pixman-font)
+ $(use_enable pixman pixman-rect)
+ $(use_enable pixman pixman-line)
+ $(use_enable pixman pixman-poly)
+ $(use_enable pixman pixman-image)
+ $(use_enable pixman pixman-image-scale-sample)
+ $(use_enable png image-loader-png)
+ $(use_enable ppm image-loader-pmaps)
+ $(use_enable psd image-loader-psd)
+ $(use_enable pulseaudio)
+ $(use_enable scim)
+ $(use_enable sdl)
+ $(use_enable sound audio)
+ $(use_enable systemd)
+ $(use_enable tga image-loader-tga)
+ $(use_enable tiff image-loader-tiff)
+ $(use_enable tslib)
+ $(use_enable v4l v4l2)
+ $(use_enable valgrind)
+ $(use_enable wayland)
+ $(use_enable webp image-loader-webp)
+ $(use_enable xim)
+ $(use_enable xine)
+ $(use_enable xpm image-loader-xpm)
+ --enable-cserve
+ --enable-image-loader-generic
+ --enable-image-loader-jpeg
+
+ --disable-tizen
+ --disable-gesture
+ --disable-gstreamer
+ --enable-xinput2
+ --disable-xinput22
+ --disable-multisense
+ --enable-libmount
+
+ # external lz4 support currently broken because of unstable ABI/API
+ #--enable-liblz4
+ )
+
+ enlightenment_src_configure
+}
+
+src_compile() {
+ if host-is-pax && ! use oldlua ; then
+ # We need to build the lua code first so we can pax-mark it. #547076
+ local target='_e_built_sources_target_gogogo_'
+ printf '%s: $(BUILT_SOURCES)\n' "${target}" >> src/Makefile || die
+ emake -C src "${target}"
+ emake -C src bin/elua/elua
+ pax-mark m src/bin/elua/.libs/elua
+ fi
+ enlightenment_src_compile
+}
+
+src_install() {
+ MAKEOPTS+=" -j1"
+
+ enlightenment_src_install
+}
diff --git a/dev-libs/efl/files/efl-1.17.0-gnutls-3.4.patch b/dev-libs/efl/files/efl-1.17.0-gnutls-3.4.patch
new file mode 100644
index 00000000000..6c5f8eb757c
--- /dev/null
+++ b/dev-libs/efl/files/efl-1.17.0-gnutls-3.4.patch
@@ -0,0 +1,39 @@
+From 6f42992b4f1110f44d2db57cd6fe42559cfffdc2 Mon Sep 17 00:00:00 2001
+From: Cedric BAIL <cedric@osg.samsung.com>
+Date: Wed, 21 Sep 2016 10:33:44 -0700
+Subject: [PATCH] eet: fix gnutls support with newer version.
+
+---
+ src/lib/eet/eet_cipher.c | 9 ++++-----
+ 1 file changed, 4 insertions(+), 5 deletions(-)
+
+diff --git a/src/lib/eet/eet_cipher.c b/src/lib/eet/eet_cipher.c
+index a34fdff..cf9ef71 100644
+--- a/src/lib/eet/eet_cipher.c
++++ b/src/lib/eet/eet_cipher.c
+@@ -679,7 +679,6 @@ eet_identity_check(const void *data_base,
+ gnutls_datum_t datum;
+ gnutls_datum_t signature;
+ gnutls_pubkey_t pubkey;
+- gnutls_digest_algorithm_t hash_algo;
+ unsigned char *hash;
+ gcry_md_hd_t md;
+ int err;
+@@ -717,10 +716,10 @@ eet_identity_check(const void *data_base,
+ if (gnutls_pubkey_import_x509(pubkey, cert, 0) < 0)
+ goto on_error;
+
+- if (gnutls_pubkey_get_verify_algorithm(pubkey, &signature, &hash_algo) < 0)
+- goto on_error;
+-
+- if (gnutls_pubkey_verify_hash(pubkey, 0, &datum, &signature) < 0)
++ if (gnutls_pubkey_verify_hash2(pubkey,
++ gnutls_x509_crt_get_signature_algorithm(cert),
++ 0,
++ &datum, &signature) < 0)
+ goto on_error;
+
+ if (sha1)
+--
+2.10.2
+
^ permalink raw reply related [flat|nested] 4+ messages in thread
* [gentoo-commits] repo/gentoo:master commit in: dev-libs/efl/files/, dev-libs/efl/
@ 2018-12-05 8:40 Michał Górny
0 siblings, 0 replies; 4+ messages in thread
From: Michał Górny @ 2018-12-05 8:40 UTC (permalink / raw
To: gentoo-commits
commit: 32578b4efcf9161fef1b2267cc1fc2d31aa52a7e
Author: Joonas Niilola <juippis <AT> gmail <DOT> com>
AuthorDate: Wed Dec 5 07:16:15 2018 +0000
Commit: Michał Górny <mgorny <AT> gentoo <DOT> org>
CommitDate: Wed Dec 5 08:35:31 2018 +0000
URL: https://gitweb.gentoo.org/repo/gentoo.git/commit/?id=32578b4e
dev-libs/efl: revbump 1.21.1 to fix evas-preload segfault
- thanks to tbartdev <AT> gmx-topmail.de for the patch
- upstream bug: https://phab.enlightenment.org/T7354
Closes: https://bugs.gentoo.org/671876
Package-Manager: Portage[mgorny]-2.3.51.1
Signed-off-by: Joonas Niilola <juippis <AT> gmail.com>
Signed-off-by: Michał Górny <mgorny <AT> gentoo.org>
dev-libs/efl/efl-1.21.1-r1.ebuild | 279 +++++++++++++++++++++
.../efl-1.21.1-fix_evas_preload_segfault.patch | 10 +
2 files changed, 289 insertions(+)
diff --git a/dev-libs/efl/efl-1.21.1-r1.ebuild b/dev-libs/efl/efl-1.21.1-r1.ebuild
new file mode 100644
index 00000000000..c6e1fed2916
--- /dev/null
+++ b/dev-libs/efl/efl-1.21.1-r1.ebuild
@@ -0,0 +1,279 @@
+# Copyright 1999-2018 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=6
+
+inherit gnome2-utils pax-utils xdg-utils
+
+DESCRIPTION="Enlightenment Foundation Libraries all-in-one package"
+HOMEPAGE="https://www.enlightenment.org"
+SRC_URI="https://download.enlightenment.org/rel/libs/${PN}/${P}.tar.xz"
+
+LICENSE="BSD-2 GPL-2 LGPL-2.1 ZLIB"
+SLOT="0"
+KEYWORDS="~amd64 ~arm ~ppc ~x86 ~amd64-linux ~x86-linux"
+IUSE="avahi +bmp dds connman debug drm +eet egl examples fbcon +fontconfig fribidi gif gles glib gnutls gstreamer harfbuzz hyphen +ico ibus jpeg2k libressl libuv luajit neon nls opengl ssl pdf physics postscript +ppm +psd pulseaudio raw scim sdl sound static-libs svg +system-lz4 systemd tga tiff tslib unwind v4l valgrind vlc vnc wayland webp X xcf xim xine xpresent xpm"
+
+REQUIRED_USE="
+ ?? ( opengl egl )
+ ?? ( opengl gles )
+ fbcon? ( !tslib )
+ gles? (
+ || ( X wayland )
+ !sdl
+ egl
+ )
+ ibus? ( glib )
+ opengl? ( X )
+ pulseaudio? ( sound )
+ sdl? ( opengl )
+ vnc? ( X fbcon )
+ wayland? ( egl gles !opengl )
+ xim? ( X )
+ xpresent? ( X )
+"
+
+RDEPEND="
+ net-misc/curl
+ media-libs/libpng:0=
+ sys-apps/dbus
+ sys-apps/util-linux
+ sys-libs/zlib:=
+ virtual/jpeg:0=
+ avahi? ( net-dns/avahi )
+ connman? ( net-misc/connman )
+ drm? (
+ dev-libs/libinput
+ media-libs/mesa[gbm]
+ x11-libs/libdrm
+ x11-libs/libxkbcommon
+ )
+ egl? ( media-libs/mesa[egl] )
+ fontconfig? ( media-libs/fontconfig )
+ fribidi? ( dev-libs/fribidi )
+ gif? ( media-libs/giflib:= )
+ gles? ( media-libs/mesa[gles2] )
+ glib? ( dev-libs/glib:2 )
+ gstreamer? (
+ media-libs/gstreamer:1.0
+ media-libs/gst-plugins-base:1.0
+ )
+ harfbuzz? ( media-libs/harfbuzz )
+ hyphen? ( dev-libs/hyphen )
+ ibus? ( app-i18n/ibus )
+ jpeg2k? ( media-libs/openjpeg:0= )
+ libuv? ( dev-libs/libuv )
+ luajit? ( dev-lang/luajit:= )
+ !luajit? ( dev-lang/lua:* )
+ nls? ( sys-devel/gettext )
+ pdf? ( app-text/poppler:=[cxx] )
+ physics? ( sci-physics/bullet:= )
+ postscript? ( app-text/libspectre )
+ pulseaudio? ( media-sound/pulseaudio )
+ raw? ( media-libs/libraw:= )
+ scim? ( app-i18n/scim )
+ sdl? (
+ media-libs/libsdl2
+ virtual/opengl
+ )
+ sound? ( media-libs/libsndfile )
+ ssl? (
+ gnutls? ( net-libs/gnutls:= )
+ !gnutls? (
+ !libressl? ( dev-libs/openssl:= )
+ libressl? ( dev-libs/libressl:= )
+ )
+ )
+ svg? (
+ gnome-base/librsvg
+ x11-libs/cairo
+ )
+ system-lz4? ( app-arch/lz4 )
+ systemd? ( sys-apps/systemd )
+ tiff? ( media-libs/tiff:0= )
+ tslib? ( x11-libs/tslib:= )
+ unwind? ( sys-libs/libunwind )
+ valgrind? ( dev-util/valgrind )
+ vlc? ( media-video/vlc )
+ vnc? ( net-libs/libvncserver )
+ wayland? (
+ dev-libs/wayland
+ media-libs/mesa[gles2,wayland]
+ x11-libs/libxkbcommon
+ )
+ webp? ( media-libs/libwebp:= )
+ X? (
+ media-libs/freetype
+ x11-libs/libXcursor
+ x11-libs/libX11
+ x11-libs/libXcomposite
+ x11-libs/libXdamage
+ x11-libs/libXext
+ x11-libs/libXfixes
+ x11-libs/libXinerama
+ x11-libs/libXrandr
+ x11-libs/libXrender
+ x11-libs/libXtst
+ x11-libs/libXScrnSaver
+ gles? (
+ x11-libs/libX11
+ x11-libs/libXrender
+ virtual/opengl
+ )
+ opengl? (
+ x11-libs/libX11
+ x11-libs/libXrender
+ virtual/opengl
+ )
+ )
+ xine? ( media-libs/xine-lib )
+ xpm? ( x11-libs/libXpm )
+ xpresent? ( x11-libs/libXpresent )
+"
+
+DEPEND="
+ ${RDEPEND}
+ virtual/pkgconfig
+"
+
+PATCHES=(
+ "${FILESDIR}/${P}-fix_evas_preload_segfault.patch"
+)
+
+src_prepare() {
+ default
+
+ # Upstream still doesnt offer a configure flag. #611108
+ if ! use unwind ; then
+ sed -i -e 's:libunwind libunwind-generic:xxxxxxxxxxxxxxxx:' \
+ configure || die "Sedding configure file with unwind fix failed."
+ fi
+
+ xdg_environment_reset
+}
+
+src_configure() {
+ local myconf=(
+ --enable-cserve
+ --enable-image-loader-generic
+ --enable-image-loader-jpeg
+ --enable-image-loader-png
+ --enable-libeeze
+ --enable-libmount
+ --enable-xinput22
+
+ --disable-doc
+ --disable-eglfs
+ --disable-gesture
+ --disable-gstreamer
+ --disable-image-loader-tgv
+ --disable-tizen
+ --disable-wayland-ivi-shell
+
+ $(use_enable avahi)
+ $(use_enable bmp image-loader-bmp)
+ $(use_enable bmp image-loader-wbmp)
+ $(use_enable dds image-loader-dds)
+ $(use_enable drm)
+ $(use_enable drm elput)
+ $(use_enable eet image-loader-eet)
+ $(use_enable egl)
+ $(use_enable examples always-build-examples)
+ $(use_enable fbcon fb)
+ $(use_enable fontconfig)
+ $(use_enable fribidi)
+ $(use_enable gif image-loader-gif)
+ $(use_enable gstreamer gstreamer1)
+ $(use_enable harfbuzz)
+ $(use_enable hyphen)
+ $(use_enable ico image-loader-ico)
+ $(use_enable ibus)
+ $(use_enable jpeg2k image-loader-jp2k)
+ $(use_enable libuv)
+ $(use_enable !luajit lua-old)
+ $(use_enable neon)
+ $(use_enable nls)
+ $(use_enable pdf poppler)
+ $(use_enable physics)
+ $(use_enable postscript spectre)
+ $(use_enable ppm image-loader-pmaps)
+ $(use_enable psd image-loader-psd)
+ $(use_enable pulseaudio)
+ $(use_enable raw libraw)
+ $(use_enable scim)
+ $(use_enable sdl)
+ $(use_enable sound audio)
+ $(use_enable static-libs static)
+ $(use_enable svg librsvg)
+ $(use_enable system-lz4 liblz4)
+ $(use_enable systemd)
+ $(use_enable tga image-loader-tga)
+ $(use_enable tiff image-loader-tiff)
+ $(use_enable tslib)
+ $(use_enable v4l v4l2)
+ $(use_enable valgrind)
+ $(use_enable vlc libvlc)
+ $(use_enable vnc vnc-server)
+ $(use_enable wayland)
+ $(use_enable webp image-loader-webp)
+ $(use_enable xcf)
+ $(use_enable xim)
+ $(use_enable xine)
+ $(use_enable xpm image-loader-xpm)
+ $(use_enable xpresent)
+
+ --with-crypto=$(usex gnutls gnutls $(usex ssl openssl none))
+ --with-glib=$(usex glib)
+ --with-js=none
+ --with-net-control=$(usex connman connman none)
+ --with-profile=$(usex debug debug release)
+ --with-x11=$(usex X xlib none)
+
+ $(use_with X x)
+ )
+
+ use drm && use wayland && myconf+=( --enable-gl-drm )
+
+ if use opengl ; then
+ myconf+=( --with-opengl=full )
+ elif use egl ; then
+ myconf+=( --with-opengl=es )
+ elif use drm && use wayland ; then
+ myconf+=( --with-opengl=es )
+ else
+ myconf+=( --with-opengl=none )
+ fi
+
+ econf "${myconf[@]}"
+}
+
+src_compile() {
+ if host-is-pax && use luajit ; then
+ # We need to build the lua code first so we can pax-mark it. #547076
+ local target='_e_built_sources_target_gogogo_'
+ printf '%s: $(BUILT_SOURCES)\n' "${target}" >> src/Makefile || die
+ emake -C src "${target}"
+ emake -C src bin/elua/elua
+ pax-mark m src/bin/elua/.libs/elua
+ fi
+
+ V=1 emake || die "Compiling EFL failed."
+}
+
+src_install() {
+ einstalldocs
+
+ V=1 emake install DESTDIR="${D}" || die "Installing EFL files failed."
+
+ find "${D}" -name '*.la' -delete || die
+}
+
+pkg_postinst() {
+ gnome2_icon_cache_update
+ xdg_mimeinfo_database_update
+}
+
+pkg_postrm() {
+ gnome2_icon_cache_update
+ xdg_mimeinfo_database_update
+}
diff --git a/dev-libs/efl/files/efl-1.21.1-fix_evas_preload_segfault.patch b/dev-libs/efl/files/efl-1.21.1-fix_evas_preload_segfault.patch
new file mode 100644
index 00000000000..8d42cbb0f25
--- /dev/null
+++ b/dev-libs/efl/files/efl-1.21.1-fix_evas_preload_segfault.patch
@@ -0,0 +1,10 @@
+--- a/src/lib/evas/cache/evas_cache_image.c 14:09:44.971119099 +0100
++++ b/src/lib/evas/cache/evas_cache_image.c 14:10:21.521226043 +0100
+@@ -361,6 +361,7 @@
+ cache = current->cache;
+
+ if ((!current->flags.loaded) &&
++ (current->info.loader) &&
+ current->info.loader->threadable)
+ {
+ evas_module_task_register(evas_cache_image_cancelled, current);
^ permalink raw reply related [flat|nested] 4+ messages in thread
* [gentoo-commits] repo/gentoo:master commit in: dev-libs/efl/files/, dev-libs/efl/
@ 2023-05-01 8:05 Joonas Niilola
0 siblings, 0 replies; 4+ messages in thread
From: Joonas Niilola @ 2023-05-01 8:05 UTC (permalink / raw
To: gentoo-commits
commit: 9088957da743bd19ba56a001852568916b5d393a
Author: orbea <orbea <AT> riseup <DOT> net>
AuthorDate: Fri Apr 28 16:36:57 2023 +0000
Commit: Joonas Niilola <juippis <AT> gentoo <DOT> org>
CommitDate: Mon May 1 08:05:29 2023 +0000
URL: https://gitweb.gentoo.org/repo/gentoo.git/commit/?id=9088957d
dev-libs/efl: add upstream patch for libressl
This patch was accepted upstream and fixed the build with libressl >=
3.5.0.
Upstream-PR: https://git.enlightenment.org/enlightenment/efl/pulls/10
Upstream-Commit: https://git.enlightenment.org/enlightenment/efl/commit/bdd5b244e6a6161228f4a98210cefd9ef8a12e85
Upstream-Commit: https://git.enlightenment.org/enlightenment/efl/commit/0e22417f4579333a967fb5ce65ab339dfc066753
Bug: https://bugs.gentoo.org/903001
Closes: https://github.com/gentoo/gentoo/pull/30794
Signed-off-by: Joonas Niilola <juippis <AT> gentoo.org>
dev-libs/efl/efl-1.26.3-r1.ebuild | 4 +
dev-libs/efl/files/efl-1.26.3-libressl.patch | 191 +++++++++++++++++++++++++++
2 files changed, 195 insertions(+)
diff --git a/dev-libs/efl/efl-1.26.3-r1.ebuild b/dev-libs/efl/efl-1.26.3-r1.ebuild
index 8b00eb21d056..fb26d694f9b3 100644
--- a/dev-libs/efl/efl-1.26.3-r1.ebuild
+++ b/dev-libs/efl/efl-1.26.3-r1.ebuild
@@ -131,6 +131,10 @@ BDEPEND="${PYTHON_DEPS}
nls? ( sys-devel/gettext )
wayland? ( dev-util/wayland-scanner )"
+PATCHES=(
+ "${FILESDIR}"/${PN}-1.26.3-libressl.patch #903001
+)
+
pkg_setup() {
# Deprecated, provided for backward-compatibility. Everything is moved to libefreet.so.
QA_FLAGS_IGNORED="/usr/$(get_libdir)/libefreet_trash.so.${PV}
diff --git a/dev-libs/efl/files/efl-1.26.3-libressl.patch b/dev-libs/efl/files/efl-1.26.3-libressl.patch
new file mode 100644
index 000000000000..6bb1b6bb83e3
--- /dev/null
+++ b/dev-libs/efl/files/efl-1.26.3-libressl.patch
@@ -0,0 +1,191 @@
+https://bugs.gentoo.org/903001
+https://git.enlightenment.org/enlightenment/efl/pulls/10
+https://git.enlightenment.org/enlightenment/efl/commit/bdd5b244e6a6161228f4a98210cefd9ef8a12e85
+https://git.enlightenment.org/enlightenment/efl/commit/0e22417f4579333a967fb5ce65ab339dfc066753
+
+From bdd5b244e6a6161228f4a98210cefd9ef8a12e85 Mon Sep 17 00:00:00 2001
+From: orbea <orbea@riseup.net>
+Date: Mon, 4 Jul 2022 09:05:38 -0700
+Subject: [PATCH] Support LibreSSL 3.5.x
+
+LibreSSL 3.5.x now works with the standard OpenSSL code paths.
+---
+ src/lib/ecore_con/efl_net_ssl_conn-openssl.c | 12 ++++++------
+ src/lib/eet/eet_cipher.c | 8 ++++----
+ src/lib/emile/emile_cipher_openssl.c | 14 +++++++-------
+ 3 files changed, 17 insertions(+), 17 deletions(-)
+
+From 0e22417f4579333a967fb5ce65ab339dfc066753 Mon Sep 17 00:00:00 2001
+From: "Carsten Haitzler (Rasterman)" <raster@rasterman.com>
+Date: Mon, 1 Aug 2022 17:35:52 +0100
+Subject: [PATCH] eet emile - cipher - add braces for if defines to be clear on
+ order of op
+
+---
+ src/lib/ecore_con/efl_net_ssl_conn-openssl.c | 12 ++++++------
+ src/lib/eet/eet_cipher.c | 8 ++++----
+ src/lib/emile/emile_cipher_openssl.c | 10 +++++-----
+ 3 files changed, 15 insertions(+), 15 deletions(-)
+
+diff --git a/src/lib/ecore_con/efl_net_ssl_conn-openssl.c b/src/lib/ecore_con/efl_net_ssl_conn-openssl.c
+index e59c6811c9..56c8a595eb 100644
+--- a/src/lib/ecore_con/efl_net_ssl_conn-openssl.c
++++ b/src/lib/ecore_con/efl_net_ssl_conn-openssl.c
+@@ -27,7 +27,7 @@
+ static int
+ efl_net_socket_bio_create(BIO *b)
+ {
+-#if OPENSSL_VERSION_NUMBER >= 0x10100000L && !defined(LIBRESSL_VERSION_NUMBER)
++#if (LIBRESSL_VERSION_NUMBER >= 0x3050000fL) || ((OPENSSL_VERSION_NUMBER >= 0x10100000L) && !defined(LIBRESSL_VERSION_NUMBER))
+ BIO_set_init(b, 1);
+ BIO_set_data(b, NULL);
+ BIO_set_flags(b, 0);
+@@ -44,7 +44,7 @@ static int
+ efl_net_socket_bio_destroy(BIO *b)
+ {
+ if (!b) return 0;
+-#if OPENSSL_VERSION_NUMBER >= 0x10100000L && !defined(LIBRESSL_VERSION_NUMBER)
++#if (LIBRESSL_VERSION_NUMBER >= 0x3050000fL) || ((OPENSSL_VERSION_NUMBER >= 0x10100000L) && !defined(LIBRESSL_VERSION_NUMBER))
+ BIO_set_init(b, 0);
+ BIO_set_data(b, NULL);
+ BIO_set_flags(b, 0);
+@@ -63,7 +63,7 @@ efl_net_socket_bio_read(BIO *b, char *buf, int len)
+ .mem = buf,
+ .len = len
+ };
+-#if OPENSSL_VERSION_NUMBER >= 0x10100000L && !defined(LIBRESSL_VERSION_NUMBER)
++#if (LIBRESSL_VERSION_NUMBER >= 0x3050000fL) || ((OPENSSL_VERSION_NUMBER >= 0x10100000L) && !defined(LIBRESSL_VERSION_NUMBER))
+ Eo *sock = BIO_get_data(b);
+ #else
+ Eo *sock = b->ptr;
+@@ -99,7 +99,7 @@ efl_net_socket_bio_write(BIO *b, const char *buf, int len)
+ .mem = buf,
+ .len = len
+ };
+-#if OPENSSL_VERSION_NUMBER >= 0x10100000L && !defined(LIBRESSL_VERSION_NUMBER)
++#if (LIBRESSL_VERSION_NUMBER >= 0x3050000fL) || ((OPENSSL_VERSION_NUMBER >= 0x10100000L) && !defined(LIBRESSL_VERSION_NUMBER))
+ Eo *sock = BIO_get_data(b);
+ #else
+ Eo *sock = b->ptr;
+@@ -146,7 +146,7 @@ efl_net_socket_bio_puts(BIO *b, const char *str)
+ static BIO_METHOD *
+ __efl_net_socket_bio_get(void)
+ {
+-#if OPENSSL_VERSION_NUMBER >= 0x10100000L && !defined(LIBRESSL_VERSION_NUMBER)
++#if (LIBRESSL_VERSION_NUMBER >= 0x3050000fL) || ((OPENSSL_VERSION_NUMBER >= 0x10100000L) && !defined(LIBRESSL_VERSION_NUMBER))
+ static BIO_METHOD *efl_net_socket_bio = NULL;
+
+ if (efl_net_socket_bio) return efl_net_socket_bio;
+@@ -359,7 +359,7 @@ efl_net_ssl_conn_setup(Efl_Net_Ssl_Conn *conn, Eina_Bool is_dialer, Efl_Net_Sock
+ conn->bio = BIO_new(__efl_net_socket_bio_get());
+ EINA_SAFETY_ON_NULL_GOTO(conn->bio, error_bio);
+
+-#if OPENSSL_VERSION_NUMBER >= 0x10100000L && !defined(LIBRESSL_VERSION_NUMBER)
++#if (LIBRESSL_VERSION_NUMBER >= 0x3050000fL) || ((OPENSSL_VERSION_NUMBER >= 0x10100000L) && !defined(LIBRESSL_VERSION_NUMBER))
+ BIO_set_data(conn->bio, sock);
+ #else
+ conn->bio->ptr = sock;
+diff --git a/src/lib/eet/eet_cipher.c b/src/lib/eet/eet_cipher.c
+index 025750cc98..30501b99e1 100644
+--- a/src/lib/eet/eet_cipher.c
++++ b/src/lib/eet/eet_cipher.c
+@@ -472,7 +472,7 @@ eet_identity_sign(FILE *fp,
+ gnutls_datum_t signum = { NULL, 0 };
+ gnutls_privkey_t privkey;
+ # else /* ifdef HAVE_GNUTLS */
+-# if OPENSSL_VERSION_NUMBER >= 0x10100000L && !defined(LIBRESSL_VERSION_NUMBER)
++# if (LIBRESSL_VERSION_NUMBER >= 0x3050000fL) || ((OPENSSL_VERSION_NUMBER >= 0x10100000L) && !defined(LIBRESSL_VERSION_NUMBER))
+ EVP_MD_CTX *md_ctx;
+ # else
+ EVP_MD_CTX md_ctx;
+@@ -562,7 +562,7 @@ eet_identity_sign(FILE *fp,
+ }
+
+ /* Do the signature. */
+-#if OPENSSL_VERSION_NUMBER >= 0x10100000L && !defined(LIBRESSL_VERSION_NUMBER)
++#if (LIBRESSL_VERSION_NUMBER >= 0x3050000fL) || ((OPENSSL_VERSION_NUMBER >= 0x10100000L) && (!defined(LIBRESSL_VERSION_NUMBER)))
+ md_ctx = EVP_MD_CTX_new();
+ if (!md_ctx)
+ {
+@@ -756,7 +756,7 @@ eet_identity_check(const void *data_base,
+ const unsigned char *tmp;
+ EVP_PKEY *pkey;
+ X509 *x509;
+-#if OPENSSL_VERSION_NUMBER >= 0x10100000L && !defined(LIBRESSL_VERSION_NUMBER)
++#if (LIBRESSL_VERSION_NUMBER >= 0x3050000fL) || ((OPENSSL_VERSION_NUMBER >= 0x10100000L) && !defined(LIBRESSL_VERSION_NUMBER))
+ EVP_MD_CTX *md_ctx;
+ #else
+ EVP_MD_CTX md_ctx;
+@@ -779,7 +779,7 @@ eet_identity_check(const void *data_base,
+ }
+
+ /* Verify the signature */
+-#if OPENSSL_VERSION_NUMBER >= 0x10100000L && !defined(LIBRESSL_VERSION_NUMBER)
++#if (LIBRESSL_VERSION_NUMBER >= 0x3050000fL) || ((OPENSSL_VERSION_NUMBER >= 0x10100000L) && !defined(LIBRESSL_VERSION_NUMBER))
+ md_ctx = EVP_MD_CTX_new();
+ if (!md_ctx)
+ {
+diff --git a/src/lib/emile/emile_cipher_openssl.c b/src/lib/emile/emile_cipher_openssl.c
+index e5a1ed4135..7fed417d3f 100644
+--- a/src/lib/emile/emile_cipher_openssl.c
++++ b/src/lib/emile/emile_cipher_openssl.c
+@@ -45,12 +45,12 @@ struct _Emile_SSL
+ Eina_Bool
+ _emile_cipher_init(void)
+ {
+-#if OPENSSL_VERSION_NUMBER < 0x10100000L || defined(LIBRESSL_VERSION_NUMBER)
++#if (OPENSSL_VERSION_NUMBER < 0x10100000L) || (LIBRESSL_VERSION_NUMBER < 0x3050000fL)
+ ERR_load_crypto_strings();
+ SSL_library_init();
+ SSL_load_error_strings();
+ OpenSSL_add_all_algorithms();
+-#endif /* if OPENSSL_VERSION_NUMBER < 0x10100000L || defined(LIBRESSL_VERSION_NUMBER) */
++#endif /* if OPENSSL_VERSION_NUMBER < 0x10100000L || LIBRESSL_VERSION_NUMBER < 0x3050000fL */
+
+ return EINA_TRUE;
+ }
+@@ -73,7 +73,7 @@ emile_binbuf_sha1(const Eina_Binbuf * data, unsigned char digest[20])
+ {
+ const EVP_MD *md = EVP_sha1();
+ Eina_Slice slice = eina_binbuf_slice_get(data);
+-#if OPENSSL_VERSION_NUMBER >= 0x10100000L && !defined(LIBRESSL_VERSION_NUMBER)
++#if (LIBRESSL_VERSION_NUMBER >= 0x3050000fL) || ((OPENSSL_VERSION_NUMBER >= 0x10100000L) && !defined(LIBRESSL_VERSION_NUMBER))
+ EVP_MD_CTX *ctx = EVP_MD_CTX_new();
+ if (!ctx) return EINA_FALSE;
+
+@@ -196,7 +196,7 @@ on_error:
+ memset(ik, 0, sizeof (ik));
+
+ /* Openssl error */
+-#if OPENSSL_VERSION_NUMBER < 0x10100000L || defined(LIBRESSL_VERSION_NUMBER)
++#if (OPENSSL_VERSION_NUMBER < 0x10100000L) || (LIBRESSL_VERSION_NUMBER < 0x3050000fL)
+ if (ctx)
+ EVP_CIPHER_CTX_cleanup(ctx);
+ #else
+@@ -204,7 +204,7 @@ on_error:
+ EVP_CIPHER_CTX_cleanup(ctx);
+ EVP_CIPHER_CTX_free(ctx);
+ }
+-#endif /* if OPENSSL_VERSION_NUMBER < 0x10100000L || defined(LIBRESSL_VERSION_NUMBER) */
++#endif /* if OPENSSL_VERSION_NUMBER < 0x10100000L || LIBRESSL_VERSION_NUMBER < 0x3050000fL */
+
+
+ free(buffer);
+@@ -331,7 +331,7 @@ emile_cipher_server_listen(Emile_Cipher_Type t)
+ SSL_CTX_set_options(r->ssl_ctx,
+ options | SSL_OP_NO_SSLv2 | SSL_OP_SINGLE_DH_USE);
+ break;
+-#if OPENSSL_VERSION_NUMBER < 0x10100000L || defined(LIBRESSL_VERSION_NUMBER)
++#if (OPENSSL_VERSION_NUMBER < 0x10100000L) || (LIBRESSL_VERSION_NUMBER < 0x3050000fL)
+ case EMILE_TLSv1:
+ r->ssl_ctx = SSL_CTX_new(TLSv1_server_method());
+ break;
+@@ -780,7 +780,7 @@ emile_cipher_server_connect(Emile_Cipher_Type t)
+ options | SSL_OP_NO_SSLv2 | SSL_OP_SINGLE_DH_USE);
+ break;
+ case EMILE_TLSv1:
+-#if OPENSSL_VERSION_NUMBER < 0x10100000L || defined(LIBRESSL_VERSION_NUMBER)
++#if (OPENSSL_VERSION_NUMBER < 0x10100000L) || (LIBRESSL_VERSION_NUMBER < 0x3050000fL)
+ r->ssl_ctx = SSL_CTX_new(TLSv1_client_method());
+ break;
+ #endif
^ permalink raw reply related [flat|nested] 4+ messages in thread
* [gentoo-commits] repo/gentoo:master commit in: dev-libs/efl/files/, dev-libs/efl/
@ 2023-08-15 6:13 Joonas Niilola
0 siblings, 0 replies; 4+ messages in thread
From: Joonas Niilola @ 2023-08-15 6:13 UTC (permalink / raw
To: gentoo-commits
commit: fd3c09be674aeae592bea312b004c5e689c44173
Author: Joonas Niilola <juippis <AT> gentoo <DOT> org>
AuthorDate: Tue Aug 15 06:12:23 2023 +0000
Commit: Joonas Niilola <juippis <AT> gentoo <DOT> org>
CommitDate: Tue Aug 15 06:12:23 2023 +0000
URL: https://gitweb.gentoo.org/repo/gentoo.git/commit/?id=fd3c09be
dev-libs/efl: add upstream compatibility with gettext-0.22 patch
Closes: https://bugs.gentoo.org/909530
Signed-off-by: Joonas Niilola <juippis <AT> gentoo.org>
dev-libs/efl/efl-1.26.3-r2.ebuild | 3 +-
.../efl/files/efl-1.26.3-gettext-0.22-fix.patch | 38 ++++++++++++++++++++++
2 files changed, 40 insertions(+), 1 deletion(-)
diff --git a/dev-libs/efl/efl-1.26.3-r2.ebuild b/dev-libs/efl/efl-1.26.3-r2.ebuild
index 3926f8a65117..ca9fd1880009 100644
--- a/dev-libs/efl/efl-1.26.3-r2.ebuild
+++ b/dev-libs/efl/efl-1.26.3-r2.ebuild
@@ -128,12 +128,13 @@ DEPEND="${RDEPEND}
wayland? ( dev-libs/wayland-protocols )"
BDEPEND="${PYTHON_DEPS}
virtual/pkgconfig
- examples? ( <sys-devel/gettext-0.22 )
+ examples? ( sys-devel/gettext )
nls? ( sys-devel/gettext )
wayland? ( dev-util/wayland-scanner )"
PATCHES=(
"${FILESDIR}"/${PN}-1.26.3-libressl.patch #903001
+ "${FILESDIR}"/efl-1.26.3-gettext-0.22-fix.patch
)
pkg_setup() {
diff --git a/dev-libs/efl/files/efl-1.26.3-gettext-0.22-fix.patch b/dev-libs/efl/files/efl-1.26.3-gettext-0.22-fix.patch
new file mode 100644
index 000000000000..1bce74f76fec
--- /dev/null
+++ b/dev-libs/efl/files/efl-1.26.3-gettext-0.22-fix.patch
@@ -0,0 +1,38 @@
+From 155842cf9e726009e9eb4ec04d8a176cd990fdcb Mon Sep 17 00:00:00 2001
+From: dimmus <dmitri.chudinov@gmail.com>
+Date: Mon, 14 Aug 2023 21:39:05 +0500
+Subject: [PATCH] examples: edje - add charset header to po files.
+
+Solved compilation error with novel gettext-0.22.
+@fix
+---
+ src/examples/edje/en_IN/domain_name.po | 5 +++++
+ src/examples/edje/hi_IN/domain_name.po | 5 +++++
+ 2 files changed, 10 insertions(+)
+
+diff --git a/src/examples/edje/en_IN/domain_name.po b/src/examples/edje/en_IN/domain_name.po
+index f461123404..131579ee36 100644
+--- a/src/examples/edje/en_IN/domain_name.po
++++ b/src/examples/edje/en_IN/domain_name.po
+@@ -1,3 +1,8 @@
++msgid ""
++msgstr ""
++"Content-Type: text/plain; charset=UTF-8\n"
++"Content-Transfer-Encoding: UTF-8\n"
++
+ msgid "LOADING"
+ msgstr "Loading..."
+
+diff --git a/src/examples/edje/hi_IN/domain_name.po b/src/examples/edje/hi_IN/domain_name.po
+index 809cf6f399..fcb0e85d00 100644
+--- a/src/examples/edje/hi_IN/domain_name.po
++++ b/src/examples/edje/hi_IN/domain_name.po
+@@ -1,3 +1,8 @@
++msgid ""
++msgstr ""
++"Content-Type: text/plain; charset=UTF-8\n"
++"Content-Transfer-Encoding: UTF-8\n"
++
+ msgid "LOADING"
+ msgstr "लोड हो रहा है..."
+
^ permalink raw reply related [flat|nested] 4+ messages in thread
end of thread, other threads:[~2023-08-15 6:13 UTC | newest]
Thread overview: 4+ messages (download: mbox.gz follow: Atom feed
-- links below jump to the message on this page --
2018-12-05 8:40 [gentoo-commits] repo/gentoo:master commit in: dev-libs/efl/files/, dev-libs/efl/ Michał Górny
-- strict thread matches above, loose matches on Subject: below --
2023-08-15 6:13 Joonas Niilola
2023-05-01 8:05 Joonas Niilola
2017-03-04 0:37 Alon Bar-Lev
This is a public inbox, see mirroring instructions
for how to clone and mirror all data and code used for this inbox