[gentoo-commits] repo/gentoo:master commit in: dev-libs/wlroots/

["Aaron Bauman" <bman@gentoo.org>]

commit:     1fe0463be03afbf8e9a06a9ed0abc6a1a6fc0f17
Author:     Niccolò Scatena <speedjack95 <AT> gmail <DOT> com>
AuthorDate: Fri Nov 30 12:57:31 2018 +0000
Commit:     Aaron Bauman <bman <AT> gentoo <DOT> org>
CommitDate: Sat Dec  1 17:41:23 2018 +0000
URL:        https://gitweb.gentoo.org/repo/gentoo.git/commit/?id=1fe0463b

dev-libs/wlroots: version bump to 0.2

Signed-off-by: Niccolò Scatena <speedjack95 <AT> gmail.com>
Package-Manager: Portage-2.3.52, Repoman-2.3.12
Closes: https://github.com/gentoo/gentoo/pull/10527
Signed-off-by: Aaron Bauman <bman <AT> gentoo.org>

 dev-libs/wlroots/Manifest           |  1 +
 dev-libs/wlroots/wlroots-0.2.ebuild | 95 +++++++++++++++++++++++++++++++++++++
 2 files changed, 96 insertions(+)

diff --git a/dev-libs/wlroots/Manifest b/dev-libs/wlroots/Manifest
index 9ea97695e85..8ae2dd30dcd 100644
--- a/dev-libs/wlroots/Manifest
+++ b/dev-libs/wlroots/Manifest
@@ -1 +1,2 @@
 DIST wlroots-0.1.tar.gz 436459 BLAKE2B 8545adb7a9ffe1c4b071ddad1093472f45b24638b29b3c2898b4aa3629c364936be7bec348c9aac5a7d3ecda677df108361fbef08cda8fca9c6bb21639883c86 SHA512 43897ac5a512ea26ad9703182dab5de9c714a087449b108472f638148538a632a67cfc778edf3e77940fdd7bdba91d64a4dc4e4ed1903a150f13ca59237ce01e
+DIST wlroots-0.2.tar.gz 437638 BLAKE2B dd7ca737ba2dfc00e30c83e973616cefb77fccb793161794361422a2fcbdf7299aacea8d794b910fdf06c9a191a89f7f1530d312545d08d126a729be41eeb424 SHA512 b7727b29ed7e5188d5fa6099687f8e6f48b6b3f17f7a6e136956ad6b607054595de3779118bffd4b9730115eaca2f00c2d30d52f4915b2753a749432ec0c3f2a

diff --git a/dev-libs/wlroots/wlroots-0.2.ebuild b/dev-libs/wlroots/wlroots-0.2.ebuild
new file mode 100644
index 00000000000..c3bccd9f7fe
--- /dev/null
+++ b/dev-libs/wlroots/wlroots-0.2.ebuild
@@ -0,0 +1,95 @@
+# Copyright 1999-2018 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=7
+
+if [[ ${PV} == 9999 ]] ; then
+	EGIT_REPO_URI="https://github.com/swaywm/wlroots.git"
+	inherit git-r3
+else
+	SRC_URI="https://github.com/swaywm/wlroots/archive/${PV}.tar.gz -> ${P}.tar.gz"
+	KEYWORDS="~amd64 ~x86"
+fi
+
+inherit fcaps meson
+
+DESCRIPTION="Pluggable, composable, unopinionated modules for building a Wayland compositor"
+HOMEPAGE="https://github.com/swaywm/wlroots"
+
+LICENSE="MIT"
+SLOT="0"
+IUSE="elogind icccm rootston systemd x11-backend X"
+REQUIRED_USE="?? ( elogind systemd )"
+
+RDEPEND=">=dev-libs/libinput-1.7.0:0=
+	>=dev-libs/wayland-1.16.0
+	>=dev-libs/wayland-protocols-1.15
+	media-libs/mesa[egl,gles2,gbm]
+	virtual/libudev
+	x11-libs/libdrm
+	x11-libs/libxkbcommon
+	x11-libs/pixman
+	elogind? ( >=sys-auth/elogind-237 )
+	icccm? ( x11-libs/xcb-util-wm )
+	systemd? ( >=sys-apps/systemd-237 )
+	x11-backend? ( x11-libs/libxcb:0= )
+	X? (
+		x11-base/xorg-server[wayland]
+		x11-libs/libxcb:0=
+	)"
+DEPEND="${RDEPEND}"
+BDEPEND=">=dev-util/meson-0.48
+	virtual/pkgconfig"
+
+FILECAPS=( cap_sys_admin usr/bin/rootston )
+
+src_configure() {
+	# xcb-util-errors is not on Gentoo Repository (and upstream seems inactive?)
+	local emesonargs=(
+		"-Dxcb-errors=disabled"
+		-Dlibcap=$(usex filecaps enabled disabled)
+		-Dxcb-icccm=$(usex icccm enabled disabled)
+		-Dxwayland=$(usex X enabled disabled)
+		-Dx11-backend=$(usex x11-backend enabled disabled)
+		-Drootston=$(usex rootston true false)
+		"-Dexamples=false"
+		"-Dwerror=false"
+	)
+	if use systemd ; then
+		emesonargs+=("-Dlogind=enabled" "-Dlogind-provider=systemd")
+	elif use elogind ; then
+		emesonargs+=("-Dlogind=enabled" "-Dlogind-provider=elogind")
+	else
+		emesonargs+=("-Dlogind=disabled")
+	fi
+
+	meson_src_configure
+}
+
+src_install() {
+	if use rootston ; then
+		dobin "${BUILD_DIR}"/rootston/rootston
+		newdoc rootston/rootston.ini.example rootston.ini
+	fi
+
+	meson_src_install
+}
+
+pkg_postinst() {
+	elog "You must be in the input group to allow your compositor"
+	elog "to access input devices via libinput."
+	if use rootston ; then
+		elog ""
+		elog "You should copy (and decompress) the example configuration file"
+		elog "from ${EROOT:-${ROOT}}/usr/share/doc/${PF}/rootston.ini"
+		elog "to the working directory from where you launch rootston"
+		elog "(or pass the '-C path-to-config' option to rootston)."
+		if ! use systemd && ! use elogind ; then
+			elog ""
+			elog "If you use ConsoleKit2, remember to launch rootston using:"
+			elog "exec ck-launch-session rootston"
+
+			fcaps_pkg_postinst
+		fi
+	fi
+}