[gentoo-commits] repo/gentoo:master commit in: media-libs/fdk-aac/

["Lars Wendler" <polynomial-c@gentoo.org>]

commit:     5306b84076245b391af4e48facf065c4ab98bc15
Author:     Lars Wendler <polynomial-c <AT> gentoo <DOT> org>
AuthorDate: Thu Nov 29 11:58:20 2018 +0000
Commit:     Lars Wendler <polynomial-c <AT> gentoo <DOT> org>
CommitDate: Thu Nov 29 11:58:20 2018 +0000
URL:        https://gitweb.gentoo.org/repo/gentoo.git/commit/?id=5306b840

media-libs/fdk-aac: Bump to version 2.0.0

Package-Manager: Portage-2.3.52, Repoman-2.3.12
Signed-off-by: Lars Wendler <polynomial-c <AT> gentoo.org>

 media-libs/fdk-aac/Manifest             |  1 +
 media-libs/fdk-aac/fdk-aac-2.0.0.ebuild | 56 +++++++++++++++++++++++++++++++++
 2 files changed, 57 insertions(+)

diff --git a/media-libs/fdk-aac/Manifest b/media-libs/fdk-aac/Manifest
index e3a33ea6b3e..f21de7f2734 100644
--- a/media-libs/fdk-aac/Manifest
+++ b/media-libs/fdk-aac/Manifest
@@ -1,2 +1,3 @@
 DIST fdk-aac-0.1.5.tar.gz 2091081 BLAKE2B 16dd8606f87480fbf13d06b9628ff8c4fef418b5c55fbf99931d25ee9de6c1dd710760be8766af995d0d678e8c94b2d3b17aa6cd0f5b2512ae9d4478d985d72a SHA512 579e96dae5638cfe2d3d5e84ab24a72ed50ed3b5a9d3c6eb2f434d3a5f4c575877a2ecf6cd7cf7a528eb2811b2014a861eaaac9ea5fc617c6423587525766f00
 DIST fdk-aac-0.1.6.tar.gz 2091618 BLAKE2B e3036879e21677ea0ba6d6a030aff0568572e420217479b19312bc64daf0a4e94c1a0a6de561baa79f362186777f1414a4a1eb89bf80c1268767564f1a82708b SHA512 d4d14debeb6e424f4e2a1458ed7bebaa2c45ce54170c6e679286fd965f52286b6a6c1e944edbb4ea2302c3bb789c0f3cdab9c0d89618014ba4250b2f04d71d12
+DIST fdk-aac-2.0.0.tar.gz 2864593 BLAKE2B beaefd5186a6253496a656ccea514e764e6c6515b46ea0fa324f66985af8374f3813afddb29018da12d28d1672ebe10821f5e4e98d131ad4fb77a3d01ffab234 SHA512 40b02a9e42e17015fa6531c7b7eb51098ab43224c11c1c85e981d950642ffc6884146367cb423062b1da11679020ee5c5779dce5f4dc62175c8bf471831ed918

diff --git a/media-libs/fdk-aac/fdk-aac-2.0.0.ebuild b/media-libs/fdk-aac/fdk-aac-2.0.0.ebuild
new file mode 100644
index 00000000000..355c1bb0594
--- /dev/null
+++ b/media-libs/fdk-aac/fdk-aac-2.0.0.ebuild
@@ -0,0 +1,56 @@
+# Copyright 1999-2018 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=7
+
+inherit multilib-minimal
+
+if [[ ${PV} == *9999* ]]; then
+	EGIT_REPO_URI="https://github.com/mstorsjo/${PN}.git"
+	[[ ${PV%9999} != "" ]] && EGIT_BRANCH="release/${PV%.9999}"
+	inherit autotools git-r3
+else
+	KEYWORDS="~amd64 ~arm ~arm64 ~ppc ~ppc64 ~x86 ~amd64-fbsd ~x86-fbsd ~x64-macos"
+	if [[ ${PV%_p*} != ${PV} ]]; then # Gentoo snapshot
+		SRC_URI="mirror://gentoo/${P}.tar.xz"
+	else # Official release
+		SRC_URI="mirror://sourceforge/opencore-amr/${P}.tar.gz"
+	fi
+fi
+
+DESCRIPTION="Fraunhofer AAC codec library"
+HOMEPAGE="https://sourceforge.net/projects/opencore-amr/"
+LICENSE="FraunhoferFDK"
+# subslot == N where N is libfdk-aac.so.N
+SLOT="0/2"
+
+IUSE="static-libs examples"
+
+src_prepare() {
+	default
+	[[ ${PV} == *9999* ]] && eautoreconf
+}
+
+multilib_src_configure() {
+	local myeconfargs=(
+		--enable-shared
+		$(use_enable static-libs static)
+		$(use_enable examples example)
+	)
+	ECONF_SOURCE=${S} econf "${myeconfargs[@]}"
+}
+
+multilib_src_install_all() {
+	einstalldocs
+
+	if use examples; then
+		mv "${ED}/usr/bin/"{,fdk-}aac-enc || die
+	fi
+
+	# package provides .pc files
+	find "${ED}" -name '*.la' -delete || die
+}
+
+pkg_postinst() {
+	use examples && einfo "aac-enc was renamed to fdk-aac-enc to prevent file collision with other packages"
+}