From mboxrd@z Thu Jan 1 00:00:00 1970
Return-Path: <gentoo-commits+bounces-1058771-garchives=archives.gentoo.org@lists.gentoo.org>
Received: from lists.gentoo.org (pigeon.gentoo.org [208.92.234.80])
(using TLSv1.2 with cipher ECDHE-RSA-AES256-GCM-SHA384 (256/256 bits))
(No client certificate requested)
by finch.gentoo.org (Postfix) with ESMTPS id 636F2138334
for <garchives@archives.gentoo.org>; Sat, 24 Nov 2018 23:44:30 +0000 (UTC)
Received: from pigeon.gentoo.org (localhost [127.0.0.1])
by pigeon.gentoo.org (Postfix) with SMTP id 4984BE0B50;
Sat, 24 Nov 2018 23:44:29 +0000 (UTC)
Received: from smtp.gentoo.org (smtp.gentoo.org [140.211.166.183])
(using TLSv1.2 with cipher ECDHE-RSA-AES128-GCM-SHA256 (128/128 bits))
(No client certificate requested)
by pigeon.gentoo.org (Postfix) with ESMTPS id 148A9E0B50
for <gentoo-commits@lists.gentoo.org>; Sat, 24 Nov 2018 23:44:28 +0000 (UTC)
Received: from oystercatcher.gentoo.org (unknown [IPv6:2a01:4f8:202:4333:225:90ff:fed9:fc84])
(using TLSv1.2 with cipher ECDHE-RSA-AES128-GCM-SHA256 (128/128 bits))
(No client certificate requested)
by smtp.gentoo.org (Postfix) with ESMTPS id 64C8E335D42
for <gentoo-commits@lists.gentoo.org>; Sat, 24 Nov 2018 23:44:27 +0000 (UTC)
Received: from localhost.localdomain (localhost [IPv6:::1])
by oystercatcher.gentoo.org (Postfix) with ESMTP id 804DF4B5
for <gentoo-commits@lists.gentoo.org>; Sat, 24 Nov 2018 23:44:25 +0000 (UTC)
From: "Andreas Sturmlechner" <asturm@gentoo.org>
To: gentoo-commits@lists.gentoo.org
Content-Transfer-Encoding: 8bit
Content-type: text/plain; charset=UTF-8
Reply-To: gentoo-dev@lists.gentoo.org, "Andreas Sturmlechner" <asturm@gentoo.org>
Message-ID: <1543103034.f1b5892518d015a70e94656cdf0c22c75dc5176c.asturm@gentoo>
Subject: [gentoo-commits] repo/gentoo:master commit in: media-sound/audacious/
X-VCS-Repository: repo/gentoo
X-VCS-Files: media-sound/audacious/Manifest media-sound/audacious/audacious-3.9.ebuild media-sound/audacious/metadata.xml
X-VCS-Directories: media-sound/audacious/
X-VCS-Committer: asturm
X-VCS-Committer-Name: Andreas Sturmlechner
X-VCS-Revision: f1b5892518d015a70e94656cdf0c22c75dc5176c
X-VCS-Branch: master
Date: Sat, 24 Nov 2018 23:44:25 +0000 (UTC)
Precedence: bulk
List-Post: <mailto:gentoo-commits@lists.gentoo.org>
List-Help: <mailto:gentoo-commits+help@lists.gentoo.org>
List-Unsubscribe: <mailto:gentoo-commits+unsubscribe@lists.gentoo.org>
List-Subscribe: <mailto:gentoo-commits+subscribe@lists.gentoo.org>
List-Id: Gentoo Linux mail <gentoo-commits.gentoo.org>
X-BeenThere: gentoo-commits@lists.gentoo.org
X-Archives-Salt: 60da8ac9-55c1-4b63-a0a5-f0c56aa561b9
X-Archives-Hash: 5c5d675bf9b4648f19253a703318e8b2
commit: f1b5892518d015a70e94656cdf0c22c75dc5176c
Author: Andreas Sturmlechner <asturm <AT> gentoo <DOT> org>
AuthorDate: Sat Nov 24 23:42:20 2018 +0000
Commit: Andreas Sturmlechner <asturm <AT> gentoo <DOT> org>
CommitDate: Sat Nov 24 23:43:54 2018 +0000
URL: https://gitweb.gentoo.org/repo/gentoo.git/commit/?id=f1b58925
media-sound/audacious: Revert drop 3.9
Required by media-libs/freeverb3[audacious].
Signed-off-by: Andreas Sturmlechner <asturm <AT> gentoo.org>
media-sound/audacious/Manifest | 2 +
media-sound/audacious/audacious-3.9.ebuild | 94 ++++++++++++++++++++++++++++++
media-sound/audacious/metadata.xml | 1 +
3 files changed, 97 insertions(+)
diff --git a/media-sound/audacious/Manifest b/media-sound/audacious/Manifest
index 165a6870661..091c016fb12 100644
--- a/media-sound/audacious/Manifest
+++ b/media-sound/audacious/Manifest
@@ -1,2 +1,4 @@
DIST audacious-3.10.tar.bz2 563531 BLAKE2B cde59bd5aff8e0530f76f3bdde20b48f829592a0a67cc03e8b7c08a8892259e99e9de2b1608698ff28819b7a6d0341d5237491f7591c4380566512076a0889b9 SHA512 513d5f9608c1ebeae9cf9bb95128244e990e66c74bf49aff6570ec557d537809f3ebf93c400f5df2708ff61cf04ecc95da183b111f5a757735cef5a68dd9907f
+DIST audacious-3.9-gtk3.tar.bz2 600249 BLAKE2B 08559eafc85236e8e881d0cbe6f08e29c82baf0fc46b9209f1d3eee290460260bfa99e6e8f26940f8c6854f3782da24061226ebdb416b6249d10914093e16276 SHA512 6ff98d027c13b30ea9600a9aba914ec993c69826199b8dc303cb60cebdf2af06a7e3dd4af1d34a86343be5485848a57c8a29e48d2a45a33945585550de4e5f9c
+DIST audacious-3.9.tar.bz2 599488 BLAKE2B 2288fe6919c1770cd283af809629fda72186cc0b87a42821f5fb9b7a20c8e7cd5bc00611d10677a82877c5ebc8a1b5ad728626027b95cc875b66dda732b8747f SHA512 d8ef24c91c84bfa80831075cd9a12fc4bf02cec8bc96bcfa5a941254d194cccdc482482b1c015bc63e1142718c2221034c0f3a87e2cb6e4daf3b4cc428328aaa
DIST gentoo_ice-xmms-0.2.tar.bz2 51839 BLAKE2B d3bf8dbfee675dd588bc0258f1015c76877b6b0a3835813d8e9621d149b924aaa33544d07f7ad44a01c058d41d7480b3908b0773c124af33b6e020c376b13d54 SHA512 e863a8f86073007c47ce8c20739aae4bff22e22a7ddc11556b12ae6ebb68654cec7310fdc9d05f2c47f81cf2591fe601b2eb12a2fd911c0a6118c9f3cc524f05
diff --git a/media-sound/audacious/audacious-3.9.ebuild b/media-sound/audacious/audacious-3.9.ebuild
new file mode 100644
index 00000000000..dea37f7b001
--- /dev/null
+++ b/media-sound/audacious/audacious-3.9.ebuild
@@ -0,0 +1,94 @@
+# Copyright 1999-2018 Gentoo Foundation
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=6
+
+inherit gnome2-utils xdg-utils
+
+MY_P="${P/_/-}"
+S="${WORKDIR}/${MY_P}"
+
+DESCRIPTION="Audacious Player - Your music, your way, no exceptions"
+HOMEPAGE="https://audacious-media-player.org/"
+
+if [[ ${PV} == *9999 ]]; then
+ inherit autotools git-r3
+ EGIT_REPO_URI="https://github.com/audacious-media-player/audacious.git"
+else
+ SRC_URI="
+ !gtk3? ( https://distfiles.audacious-media-player.org/${MY_P}.tar.bz2 )
+ gtk3? ( https://distfiles.audacious-media-player.org/${MY_P}-gtk3.tar.bz2 )"
+ KEYWORDS="~amd64 ~x86"
+fi
+
+SRC_URI+=" mirror://gentoo/gentoo_ice-xmms-0.2.tar.bz2"
+
+LICENSE="BSD-2"
+SLOT="0"
+IUSE="gtk gtk3 nls qt5"
+REQUIRED_USE="^^ ( gtk gtk3 qt5 )"
+
+RDEPEND="
+ >=dev-libs/dbus-glib-0.60
+ >=dev-libs/glib-2.28
+ >=x11-libs/cairo-1.2.6
+ >=x11-libs/pango-1.8.0
+ virtual/freedesktop-icon-theme
+ gtk? ( x11-libs/gtk+:2 )
+ gtk3? ( x11-libs/gtk+:3 )
+ qt5? (
+ dev-qt/qtcore:5
+ dev-qt/qtgui:5
+ dev-qt/qtwidgets:5
+ )"
+DEPEND="${RDEPEND}
+ virtual/pkgconfig
+ nls? ( dev-util/intltool )"
+PDEPEND="~media-plugins/audacious-plugins-${PV}"
+
+src_unpack() {
+ default
+ if use gtk3; then
+ mv "${MY_P}"{-gtk3,} || die
+ fi
+ [[ ${PV} == *9999 ]] && git-r3_src_unpack
+}
+
+src_prepare() {
+ default
+ [[ ${PV} == *9999 ]] && eautoreconf
+}
+
+src_configure() {
+ # D-Bus is a mandatory dependency, remote control,
+ # session management and some plugins depend on this.
+ # Building without D-Bus is *unsupported* and a USE-flag
+ # will not be added due to the bug reports that will result.
+ # Bugs #197894, #199069, #207330, #208606
+ econf \
+ --disable-valgrind \
+ --enable-dbus \
+ $(use_enable $(usex gtk gtk gtk3) gtk) \
+ $(use_enable nls) \
+ $(use_enable qt5 qt)
+}
+
+src_install() {
+ default
+
+ # Gentoo_ice skin installation; bug #109772
+ insinto /usr/share/audacious/Skins/gentoo_ice
+ doins -r "${WORKDIR}"/gentoo_ice/.
+ docinto gentoo_ice
+ dodoc "${WORKDIR}"/README
+}
+
+pkg_postinst() {
+ xdg_desktop_database_update
+ gnome2_icon_cache_update
+}
+
+pkg_postrm() {
+ xdg_desktop_database_update
+ gnome2_icon_cache_update
+}
diff --git a/media-sound/audacious/metadata.xml b/media-sound/audacious/metadata.xml
index 56e2b754081..503c619ac00 100644
--- a/media-sound/audacious/metadata.xml
+++ b/media-sound/audacious/metadata.xml
@@ -10,6 +10,7 @@
<name>Gentoo Sound project</name>
</maintainer>
<use>
+ <flag name="gtk3">Link against version 3 of the GIMP Toolkit instead of version 2 (x11-libs/gtk+)</flag>
<flag name="qt5">Build with Qt5 interface instead Gtk+</flag>
</use>
</pkgmetadata>